purebasic.info

PureBasic forum
Текущее время: Пт окт 19, 2018 3:17 pm

Часовой пояс: UTC + 3 часа




Начать новую тему Ответить на тему  [ Сообщений: 3 ] 
Автор Сообщение
СообщениеДобавлено: Пт фев 21, 2014 6:58 pm 
Не в сети
ассистент

Зарегистрирован: Вт июн 21, 2011 12:17 pm
Сообщений: 20
Благодарил (а): 0 раз.
Поблагодарили: 0 раз.
Пункты репутации: 0
В данных примерах демонстрируется возможность создания кнопок произвольной формы на базе обычных кнопок в ОС Windows. Мной использована возможность назначать каждой отдельно взятой кнопке свой список изображений (ImageList_Create_ , ImageList_Add_ , #BCM_SETIMAGELIST),

а так же изменять её форму ( SetWindowRgn_ )
и влиять на процесс перерисовки ( ValidateRgn_ )
с помощью регионов ( CreateRectRgn_ , ExtCreateRegion_ , CombineRgn_ ).

Файл с рисунком кнопки может состоять из одного или нескольких изображений, каждое для своего состояния (1-5)
Код:
1
2
3
4
5
6
7
8
enum PUSHBUTTONSTATES {
        PBS_NORMAL = 1,
        PBS_HOT = 2,
        PBS_PRESSED = 3,
        PBS_DISABLED = 4,
        PBS_DEFAULTED = 5,
        PBS_STYLUSHOT = 6,
};


и быть предпочтительно в формате PNG, прозрачные пиксели исключаются тем самым определяя форму кнопки при её создании.
Для создания кнопки необходимо перетащить файл в окно программы при этом указав сколько у кнопки состояний.

Пример файла кнопки:
Изображение

Работа примера №1:
Изображение

Управление:
Левая Кнопка Мыши (ЛКМ или LButton)
Правая Кнопка Мыши (ПКМ или RButton)
Клавиша Ctrl

Ctrl + LButton в пределах 20 пикселей от края кнопки - меняем размер кнопки путём перемещения её края с помощью мыши, нажатием RButton завершаем действие.

Ctrl + LButton по кнопке включает перетаскивание,
повторный клик LButton фиксирует кнопку в новой позиции

Повторный клик LButton в окне прячет и показывает рамку вокруг кнопки (её фокус)

RButton на кнопке - удаление кнопки

Работа примера №2
Изображение

Поправил исходник первого примера и дополнил в связи с нововведениями в Purebasic 5.11
(исчезли функции SetWindowSubclass, RemoveWindowSubclass, DefSubclassProc, добавили "Native types can't be used with pointers", выражение a + (Not b) пришлось заменить на a + Bool(Not b)), а так же написал ещё один пример где были выявлены некоторые "особенности"


Пример №1 - Test FreeFormButton
Код:
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
XIncludeFile #PB_Compiler_Home+"Includes\gdiplus.pbi"
 
#DC_BRUSH=18
#BCM_SETIMAGELIST=2
#BCM_FIRST=$1600
#BUTTON_IMAGELIST_ALIGN_CENTER=4
 
#BCN_FIRST=-1250
#BCN_HOTITEMCHANGE=#BCN_FIRST+1
 
#BST_UNCHECKED=0
#BST_CHECKED=1
#BST_INDETERMINATE=2
#BST_PUSHED=4
#BST_FOCUS=8
 
Structure ButtonData
  nButton.l
  bt.RECT
  *image
  imagesize.l
  *rgn
  rgnsize.l
  himl.l
  margin.RECT
  uAlign.l
  hrgn.l[5]
  StateOwnRgn.b
  states.b
  text.s
  Flags.l
  ImageFilePath.s
EndStructure
 
#HICF_ENTERING=$10
#HICF_LEAVING=$20
 
Structure NMBCHOTITEM
  ndr.NMHDR
  Flags.l
EndStructure
;{
Declare FFBtnProc(hWnd,Msg,wParam,lParam,uIdSubclass,dwRefData)
Declare ButtonProc(*m.MSG,from)
Declare WndProc(hWnd,Msg,wParam,lParam)
Declare BitmapToRegion(*Bitmap,BitmapSize=0,ExcludeColor.q=$FFFFFFFF|$64000000<<32)
Declare FreeFormButton(nButton,bx,by,bw,bh,*ButtonStatesData,*ButtonRgnData,ImageDataSize=0,RgnDataSize=0,Text$="",states=5,StateOwnRgn=0,Flags=0)
Declare ReleaseFFBtnResources()
Declare ReleaseFFBtn(hbt)
Declare GdipCreateMatrix2Ex(ScaleX.f,ScaleY.f,Angle.f,TranslateX.f,TranslateY.f)
Declare SizedButtonPreview(hbt,*pt.POINT,Direction,hdc=0)
Declare DrawFrame(*r.RECT,thickness,byWM_PAINT=0)
Declare EraseFrame()
Declare SetButtonRect(hbt)
Declare PointInRect(*pt.POINT,*Rect.RECT)
Declare PointIn3x3Rect2(*pt.POINT,*Rect.RECT,inc)
Declare PointIn3x3Rect(*pt.POINT,*Rect.RECT,inc)
 
Global ProgramPath$=GetCurrentDirectory()
Global *AlphaBlend=GetProcAddress_(GetModuleHandle_("gdi32.dll"),"GdiAlphaBlend")
Global *DefSubclassProc=GetProcAddress_(GetModuleHandle_("comctl32.dll"),"DefSubclassProc")
Global *SetWindowSubclass=GetProcAddress_(GetModuleHandle_("comctl32.dll"),"SetWindowSubclass")
Global *RemoveWindowSubclass=GetProcAddress_(GetModuleHandle_("comctl32.dll"),"RemoveWindowSubclass")
 
Global NewMap FreeFormButtonsMap.ButtonData(),NewList ButtonsImages.s(),*bd.ButtonData
 
Global hgui,hud,htxt,hbt,hCurButton,hPrevButton,hHiddenButton,Sizing
Global nGadgets,states=1,PassToMain,ReturnFromButtonProc
Global hmdc,hbmp,hpbr,hrgn,mbmpw,mbmph,hurgn,hfpbr,EraseFrame
Global *token,*gfx,*image,*region
Global bi.BITMAPINFO,ButtonFrameRect.RECT,uRect.RECT
*token=Gdiplus_New()
;}
 
;{    
; s="BST_UNCHECKED "
; If r&#BST_CHECKED
;   s+" BST_CHECKED "
; EndIf
; If r&#BST_INDETERMINATE
;   s+" BST_INDETERMINATE "
; EndIf
; If r&#BST_PUSHED
;   s+" BST_PUSHED "
; EndIf
; If r&#BST_FOCUS
;   s+" BST_FOCUS "
; EndIf
; If r&#WM_MOUSEMOVE
;   s+" WM_MOUSEMOVE "
; EndIf
;}
 
Procedure FFBtnProc(hWnd,Msg,wParam,lParam,uIdSubclass,dwRefData)
  Static r,in,key$,hdc,hrgn
  key$=Str(hWnd)
  Select Msg
    Case #WM_PAINT
      ;r=SendMessage_(hWnd,#BM_GETSTATE,0,0)
      r=CallFunctionFast(*DefSubclassProc,hWnd,#BM_GETSTATE,0,0)
      If r&#BST_PUSHED
        in=2
      ElseIf r&#WM_MOUSEMOVE
        in=1
      ElseIf r&#BST_FOCUS
        in=4
      Else
        in=0
      EndIf
      If FreeFormButtonsMap(key$)\hrgn[in]<>0
        If in>0
          hdc=GetDCEx_(hWnd,0,#DCX_CACHE)
          FillRgn_(hdc,FreeFormButtonsMap(key$)\hrgn[in],hpbr)
          ReleaseDC_(hWnd,hdc)
        EndIf
        ValidateRgn_(hWnd,FreeFormButtonsMap(key$)\hrgn[in])
      ElseIf FreeFormButtonsMap(key$)\hrgn[0]<>0
        ValidateRgn_(hWnd,FreeFormButtonsMap(key$)\hrgn[0])
      EndIf
    Case #WM_UPDATEUISTATE
      ProcedureReturn 0
    Case #WM_MOUSEMOVE
      PassToMain=1
      ButtonProc(@hWnd,1)
    Default
      PassToMain=0
      If ButtonProc(@hWnd,1)
        ProcedureReturn ReturnFromButtonProc
      EndIf
  EndSelect
  ProcedureReturn CallFunctionFast(*DefSubclassProc,hWnd,Msg,wParam,lParam)
EndProcedure
 
Procedure ButtonProc(*m.MSG,from)
  Static mpt.POINT,key$,sc,DropedFile${#MAX_PATH},NewButton.ButtonData,WaitNoDestroy
  If PassToMain=0
    Select *m\message
      Case #WM_SETFOCUS
        If Sizing=0
          hCurButton=*m\hwnd : hPrevButton=*m\wParam
          key$=Str(hCurButton)
          SetButtonRect(hCurButton)
          DrawFrame(@FreeFormButtonsMap(key$)\bt,4)
        EndIf
        PostMessage_(*m\wParam,#BM_SETSTYLE,#BS_PUSHBUTTON,1)
        PostMessage_(*m\hwnd,#BM_SETSTYLE,#BS_DEFPUSHBUTTON,1)
      Case #WM_KILLFOCUS
        EraseFrame()
        PostMessage_(*m\hwnd,#BM_SETSTYLE,#BS_PUSHBUTTON,1)
      Case #WM_EXITSIZEMOVE
        SetButtonRect(*m\hwnd)
        hCurButton=*m\hwnd
        key$=Str(*m\hwnd)
        DrawFrame(@FreeFormButtonsMap(key$)\bt,4)
      Case #WM_LBUTTONUP
        If *m\wParam&#MK_CONTROL
          PostMessage_(*m\hwnd,#WM_SYSCOMMAND,$F009,lParam)
        EndIf
      Case #WM_RBUTTONUP
        If WaitNoDestroy=0 And Sizing=0
          EraseFrame()
          ReleaseFFBtn(*m\hwnd)
          DestroyWindow_(*m\hwnd)
          ReturnFromButtonProc=0
          ProcedureReturn 1
        EndIf
        WaitNoDestroy=0
    EndSelect
  Else
    Select *m\message
      Case #WM_PAINT
        If hCurButton
          DrawFrame(@FreeFormButtonsMap(key$)\bt,4,1)
        EndIf
      Case #WM_MOUSEMOVE
        mpt\x=*m\lParam&$ffff : mpt\y=*m\lParam>>16
        If from=1
          MapWindowPoints_(*m\hwnd,hgui,@mpt,1)
        EndIf
        If Sizing
          ;EraseFrame()
          DrawFrame(@FreeFormButtonsMap(key$)\bt,2)
          SizedButtonPreview(hCurButton,@mpt,sc)
          sc=PointIn3x3Rect2(@mpt,@ButtonFrameRect,20)
          If sc=0 And hHiddenButton=0
            ShowWindow_(hCurButton,#SW_HIDE)
            hHiddenButton=hCurButton
          EndIf
        EndIf
      Case #WM_LBUTTONDOWN
        If hHiddenButton
          ShowWindow_(hHiddenButton,#SW_SHOWNOACTIVATE)
          hHiddenButton=0
        EndIf
        If Sizing
          InvalidateRect_(hgui,@uRect,1)
          DrawFrame(@FreeFormButtonsMap(key$)\bt,4)
          Sizing=0
        EndIf
        If hCurButton And EraseFrame=0
          DrawFrame(@FreeFormButtonsMap(key$)\bt,4)
        Else
          EraseFrame()
        EndIf
      Case #WM_LBUTTONUP
        mpt\x=*m\lParam&$ffff : mpt\y=*m\lParam>>16
        If hCurButton
          Sizing=PointIn3x3Rect(@mpt,@ButtonFrameRect,20)
        EndIf
      Case #WM_RBUTTONDOWN
        If Sizing
          Sizing=0
          InvalidateRect_(hgui,@uRect,1) : key$=Str(hCurButton)
          NewButton=FreeFormButtonsMap(key$)
          ReleaseFFBtn(hCurButton) : hCurButton=0
          hCurButton=FreeFormButton(NewButton\nButton,uRect\left,uRect\top,uRect\right-uRect\left,uRect\bottom-uRect\top,NewButton\image,NewButton\rgn,NewButton\imagesize,NewButton\rgnsize,NewButton\text,NewButton\states,NewButton\StateOwnRgn,NewButton\Flags)
          If IsWindow_(hCurButton)
            nGadgets+1
            key$=Str(hCurButton)
            SetButtonRect(hCurButton)
            DrawFrame(@FreeFormButtonsMap(key$)\bt,4)
            WaitNoDestroy=1
          EndIf
        EndIf
      Case #WM_DROPFILES
        DragQueryFile_(*m\wParam,0,@DropedFile$,#MAX_PATH)
        If Right(DropedFile$,4)=".png"
          AddElement(ButtonsImages())
          ButtonsImages()=DropedFile$
          *image=PeekL(@ButtonsImages())
          hCurButton=FreeFormButton(nGadgets,mpt\x,mpt\y,0,0,*image,0,0,-1,"",states,1)
          If hCurButton
            nGadgets+1
            key$=Str(hCurButton)
            SetButtonRect(hCurButton)
            DrawFrame(@FreeFormButtonsMap(key$)\bt,4)
          EndIf
        EndIf
        DragFinish_(*m\wParam)
        ReturnFromButtonProc=0
        ProcedureReturn 1
    EndSelect
  EndIf
EndProcedure
 
Procedure WndProc(hWnd,Msg,wParam,lParam)
  Static *nmh.NMHDR,*bhi.NMBCHOTITEM,*uds.NM_UPDOWN
  Select Msg
    Case #WM_NOTIFY
      *nmh=lParam
      Select *nmh\code
        Case #UDN_DELTAPOS
          *uds=lParam
          If *uds\iPos+*uds\iDelta<6 And *uds\iPos+*uds\iDelta>0
            states=*uds\iPos+*uds\iDelta
            SetGadgetText(0,Str(states))
          EndIf
      EndSelect
    Default
      PassToMain=1
      If ButtonProc(@hwnd,0)
        ProcedureReturn ReturnFromButtonProc
      EndIf
  EndSelect
  ProcedureReturn #PB_ProcessPureBasicEvents
EndProcedure
 
Procedure BitmapToRegion(*Bitmap,BitmapSize=0,ExcludeColor.q=$FFFFFFFF|$64000000<<32)
  Structure Scan : x1.w : y1.w : x2.w : y2.w : EndStructure
  Structure PixClr : b.a : g.a : r.a : a.a : EndStructure
  Structure ClrLimit : hb.a : hg.a : hr.a : ha.a : lb.a : lg.a : lr.a : la.a : EndStructure
  Protected i,r,hbt,hdc,hbmp,hrgn,nRects,hGlobal,x1
  Protected bi.BITMAPINFO,Xform.XFORM
  Protected *stream.IStream,*mem,*gfx,*image,*BitmapBits,*r.Scan,*PixClr.PixClr,*cl.ClrLimit
  Protected Dim lp.Scan(2048),Dim lb.Scan(2048)
  Protected *rgndata.RGNDATAHEADER,*rgnrects.RECT
 
  If BitmapSize>0
    hGlobal=GlobalAlloc_(#GMEM_MOVEABLE,BitmapSize)
    *mem=GlobalLock_(hGlobal)
    CopyMemory(*Bitmap,*mem,BitmapSize)
    GlobalUnlock_(hGlobal)  
    If CreateStreamOnHGlobal_(hGlobal,#True,@*stream)=#S_OK
      r|GdipCreateBitmapFromStream(*stream,@*image)
    EndIf
    *stream\Release()
    GlobalFree_(*mem) : *mem=0
    r|GdipCreateHBITMAPFromBitmap(*image,@hbmp,0)
    GdipDisposeImage(*image)
  ElseIf BitmapSize=0
    r|GdipLoadimageFromFile(PeekS(*Bitmap),@*image)
    r|GdipCreateHBITMAPFromBitmap(*image,@hbmp,0)
    GdipDisposeImage(*image)
  ElseIf BitmapSize=-1
    hbmp=CopyImage_(*Bitmap,#IMAGE_BITMAP,0,0,#LR_COPYRETURNORG)
  EndIf
 
  If r<>0
    MessageRequester("BitmapToRegion Function - Error 1","Загрузка изображения для преоьразования его в регион не удалась!")
    ProcedureReturn 0
  EndIf
 
  hdc=GetDC_(0) : bi\bmiHeader\biSize=SizeOf(BITMAPINFOHEADER)
  If GetDIBits_(hdc,hbmp,0,0,0,@bi,#DIB_RGB_COLORS)=0
    ReleaseDC_(0,hdc) : DeleteObject_(hbmp)
    MessageRequester("BitmapToRegion Function - Error 3","Функция GetDIBits. Ошибка при получении данных заголовка изображения!")
    ProcedureReturn 0
  EndIf
 
  bmpw=bi\bmiHeader\biWidth : bmph=bi\bmiHeader\biHeight : BitmapSize=bmpw*bmph*4
  *mem=AllocateMemory((bmph+3)*bmpw*4)
 
  If *mem=0
    ReleaseDC_(0,hdc) : DeleteObject_(hbmp)
    MessageRequester("BitmapToRegion Function - Error 4","Не удалось выделить память для изображения!")
    ProcedureReturn 0
  EndIf
 
  If GetDIBits_(hdc,hbmp,0,bmph,*mem+2*bmpw*4,@bi,#DIB_RGB_COLORS)=0
    ReleaseDC_(0,hdc) : DeleteObject_(hbmp) : FreeMemory(*mem)
    MessageRequester("BitmapToRegion Function - Error 5","Функция GetDIBits. Ошибка при коприровании байтов изображения!")
  EndIf
 
  ReleaseDC_(0,hdc) : DeleteObject_(hbmp) : PokeL(*mem,$FFFFFFFF)
  *r=*mem+BitmapSize+2*bmpw*4 : x1=-1 : *cl=@ExcludeColor
  For oy=bmph+1 To 0 Step -1
    offset=oy*bmpw
    For ox=0 To bmpw-1
      *PixClr=*mem+(offset+ox)*4
      If *PixClr\a>=*cl\la And *PixClr\a<=*cl\ha And *PixClr\r>=*cl\lr And *PixClr\r<=*cl\hr And *PixClr\g>=*cl\lg And *PixClr\g<=*cl\hg And *PixClr\b>=*cl\lb And *PixClr\b<=*cl\hb
        If x1=-1
          x1=ox
          c+1
        EndIf
      ElseIf x1<>-1
        lp(c)\x1=x1
        lp(c)\x2=ox
        lp(c)\y1=bmph-oy+1
        x1=-1
      EndIf
    Next ox
   
    If x1<>-1
      lp(c)\x1=x1
      lp(c)\x2=bmpw
      lp(c)\y1=bmph-oy+1
      x1=-1
    EndIf
 
    If c
      If lb(0)\x1=0
        For i=1 To c
          lb(i)=lp(i)
        Next i
        lb(0)\x1=c
        c=0
        Continue
      ElseIf c<>lb(0)\x1
        If Height
          For i=1 To lb(0)\x1
            *r\x1=lb(i)\x1 : *r\x2=lb(i)\x2 : *r\y1=lb(i)\y1 : *r\y2=lb(i)\y1+Height+1 : *r-8 : nRects+1
            ; Debug "1 Rect 1 x1 "+Str(lb(i)\x1)+" x2 "+Str(lb(i)\x2)+" y1 "+Str(lb(i)\y1)+" y2 "+Str(lb(i)\y1+Height+1)+" Height "+Str(Height+1)
          Next i
          For i=1 To c
            *r\x1=lp(i)\x1 : *r\x2=lp(i)\x2 : *r\y1=lp(i)\y1 : *r\y2=lp(i)\y1+1 : *r-8 : nRects+1
            ; Debug "1 Line 2 x1 "+Str(lp(i)\x1)+" x2 "+Str(lp(i)\x2)+" y1 "+Str(lp(i)\y1)
          Next i
          lb(0)\x1=0
          Height=0
        Else
          For i=1 To lb(0)\x1
            *r\x1=lb(i)\x1 : *r\x2=lb(i)\x2 : *r\y1=lb(i)\y1 : *r\y2=lb(i)\y1+1 : *r-8 : nRects+1
            ; Debug "2 Line 1 x1 "+Str(lb(i)\x1)+" x2 "+Str(lb(i)\x2)+" y1 "+Str(lb(i)\y1)
          Next i
          For i=1 To c
            *r\x1=lp(i)\x1 : *r\x2=lp(i)\x2 : *r\y1=lp(i)\y1 : *r\y2=lp(i)\y1+1 : *r-8 : nRects+1
            ; Debug "2 Line 2 x1 "+Str(lp(i)\x1)+" x2 "+Str(lp(i)\x2)+" y1 "+Str(lp(i)\y1)
          Next i
          lb(0)\x1=0
        EndIf
      Else
        For i=1 To c
          If lp(i)\x1<>lb(i)\x1 Or lp(i)\x2<>lb(i)\x2 Or lb(i)\y1+Height+1<>lp(i)\y1
            i=0 : Break
          EndIf
        Next i
        If i
          Height+1
        ElseIf Height
          For i=1 To lb(0)\x1
            *r\x1=lb(i)\x1 : *r\x2=lb(i)\x2 : *r\y1=lb(i)\y1 : *r\y2=lb(i)\y1+Height+1 : *r-8 : nRects+1
            ; Debug "3 Rect 1 x1 "+Str(lb(i)\x1)+" x2 "+Str(lb(i)\x2)+" y1 "+Str(lb(i)\y1)+" y2 "+Str(lb(i)\y1+Height+1)+" Height "+Str(Height+1)
          Next i
          For i=1 To c
            *r\x1=lp(i)\x1 : *r\x2=lp(i)\x2 : *r\y1=lp(i)\y1 : *r\y2=lp(i)\y1+1 : *r-8 : nRects+1
            ; Debug "3 Line 2 x1 "+Str(lp(i)\x1)+" x2 "+Str(lp(i)\x2)+" y1 "+Str(lp(i)\y1)
          Next i
          lb(0)\x1=0
          Height=0
        Else
          For i=1 To lb(0)\x1
            *r\x1=lb(i)\x1 : *r\x2=lb(i)\x2 : *r\y1=lb(i)\y1 : *r\y2=lb(i)\y1+1 : *r-8 : nRects+1
            ; Debug "4 Line 1 x1 "+Str(lb(i)\x1)+" x2 "+Str(lb(i)\x2)+" y1 "+Str(lb(i)\y1)
          Next i
          For i=1 To c
            *r\x1=lp(i)\x1 : *r\x2=lp(i)\x2 : *r\y1=lp(i)\y1 : *r\y2=lp(i)\y1+1 : *r-8 : nRects+1
            ; Debug "4 Line 2 x1 "+Str(lp(i)\x1)+" x2 "+Str(lp(i)\x2)+" y1 "+Str(lp(i)\y1)
          Next i
          lb(0)\x1=0
        EndIf
      EndIf
      c=0
    EndIf
  Next oy
 
  If nRects
    nRects-Bool(Not lb(0)\x1)
    *r=*mem+BitmapSize+2*bmpw*4
    *rgndata=AllocateMemory(SizeOf(RGNDATAHEADER)+nRects*|!REG3XP3!>SizeOf(RECT))
    If *rgndata
      *rgnrects=*rgndata+SizeOf(RGNDATAHEADER)
      For i=1 To nRects
        *rgnrects\left=($ff00&*r\x1)|($ff&*r\x1)
        *rgnrects\top=($ff00&*r\y1)|($ff&*r\y1)
        *rgnrects\right=($ff00&*r\x2)|($ff&*r\x2)
        *rgnrects\bottom=($ff00&*r\y2)|($ff&*r\y2)
        *rgnrects+16 : *r-8
      Next i
      *rgndata\dwSize=SizeOf(RGNDATAHEADER)
      *rgndata\iType=1 : *rgndata\nCount=nRects
      *rgndata\nRgnSize=nRects*|!REG3XP3!>SizeOf(RECT)
      Xform\eM11=1.0 : Xform\eM22=1.0
      hrgn=ExtCreateRegion_(@Xform,*rgndata\dwSize+*rgndata\nRgnSize,*rgndata)
      FreeMemory(*mem)
      FreeMemory(*rgndata)
      If hrgn
        ProcedureReturn hrgn
      Else
        MessageRequester("BitmapToRegion Function - Error 6","Фунция ExtCreateRegion не вернула указатель. Создать регион не дуалось!")
        ProcedureReturn 0
      EndIf
    Else
      FreeMemory(*mem)
      MessageRequester("BitmapToRegion Function - Error 7","Не удалось выделить память для данных региона!")
      ProcedureReturn 0
    EndIf
  EndIf
  FreeMemory(*mem)
EndProcedure
 
Procedure FreeFormButton(nButton,bx,by,bw,bh,*ButtonStatesData,*ButtonRgnData,ImageDataSize=0,RgnDataSize=0,Text$="",states=5,StateOwnRgn=0,Flags=0)
  Protected i,r,hbt,hdc,hmdc,hbmp,hrgn,hvalidrgn,hrmdc,htbmp,hrbmp,hpbm,hpbm2,Dim Rgn.l(4),Resize
  Static hGlobal,*fmem,*mem,*gfx,*image,*BitmapBits
  Static bmpw,bmph,rw.f,rh.f
  Static *stream.IStream,bi.BITMAPINFO,Xform.XFORM
 
  If *ButtonStatesData=0
    MessageRequester("FreeFormButton Function - Error 1","Функции передано не достаточное число параметров."+#CRLF$+"Данных о изображении кнопки нет!")
    ProcedureReturn 0
  EndIf
 
  If ImageDataSize=-1
    r|GdipCreateBitmapFromHBITMAP(*ButtonStatesData,0,@*image)
  ElseIf ImageDataSize<>0
    hGlobal=GlobalAlloc_(#GMEM_MOVEABLE,ImageDataSize)
    *fmem=GlobalLock_(hGlobal)
    CopyMemory(*ButtonStatesData,*fmem,ImageDataSize)
    GlobalUnlock_(hGlobal)  
    If CreateStreamOnHGlobal_(hGlobal,#True,@*stream)=#S_OK
      r|GdipCreateBitmapFromStream(*stream,@*image)
    EndIf
    *stream\Release()
    GlobalFree_(*fmem)
  Else
    r|GdipLoadimageFromFile(PeekS(*ButtonStatesData),@*image)
  EndIf
 
  If r<>0
    MessageRequester("FreeFormButton Function - Error 2","Не удалось загрузить изображение!")
    ProcedureReturn 0
  Else
    GdipGetImageWidth(*image,@bmpw)
    GdipGetImageHeight(*image,@bmph)
    If bw=0 : bw=bmpw/states : EndIf
    If bh=0 : bh=bmph : EndIf
   
    rw.f=bw/(bmpw/states) : rh.f=bh/bmph : If rw<>1 Or rh<>1 : Resize=1 : EndIf
 
    If Resize
      hmdc=CreateCompatibleDC_(0)
      bi\bmiHeader\biSize=SizeOf(BITMAPINFOHEADER)
      bi\bmiHeader\biPlanes=1
      bi\bmiHeader\biBitCount=32
      bi\bmiHeader\biCompression=#BI_RGB
      bi\bmiHeader\biHeight=bh
      If states=1
        bi\bmiHeader\biWidth=bw
      Else
        bi\bmiHeader\biWidth=bw*5
      EndIf
      hbmp=CreateDIBSection_(hmdc,@bi,#DIB_RGB_COLORS,@*BitmapBits,0,0)
      hpbm=SelectObject_(hmdc,hbmp)
      GdipCreateFromHDC(hmdc,@*gfx)
      GdipSetInterpolationMode(*gfx,#InterpolationModeHighQualityBicubic)
      r|GdipDrawImageRectI(*gfx,*image,0,0,bw*states,bh)
      If states>1
        For i=states To 4
          BitBlt_(hmdc,bw*i,0,bw,bh,hmdc,0,0,#SRCCOPY)
        Next i
      EndIf    
      SelectObject_(hmdc,hpbm)
      DeleteDC_(hmdc)
      GdipDeleteGraphics(*gfx)
    Else
      r|GdipCreateHBITMAPFromBitmap(*image,@hbmp,0)
    EndIf
   
    If hbmp=0 Or r<>0
      GdipDisposeImage(*image)
      MessageRequester("FreeFormButton Function - Error 3","Не удалось создать Gdi Bitmap!")
      ProcedureReturn 0
    EndIf
   
    If RgnDataSize=-1 And *ButtonRgnData=0
      If Resize
        GdipCreateHBITMAPFromBitmap(*image,@htbmp,0)
        htbmp=CopyImage_(htbmp,#IMAGE_BITMAP,bw*states,bh,#LR_COPYDELETEORG)
      Else
        htbmp=hbmp
      EndIf
     
      If states>1
       
        hmdc=CreateCompatibleDC_(0)
        hpbm=SelectObject_(hmdc,htbmp)
        hrmdc=CreateCompatibleDC_(0)
        bi\bmiHeader\biSize=SizeOf(BITMAPINFOHEADER)
        bi\bmiHeader\biPlanes=1
        bi\bmiHeader\biBitCount=32
        bi\bmiHeader\biCompression=#BI_RGB
        bi\bmiHeader\biWidth=bw : bi\bmiHeader\biHeight=-bh
        hrbmp=CreateDIBSection_(hmdc,@bi,#DIB_RGB_COLORS,@*BitmapBits,0,0)
        hpbm2=SelectObject_(hrmdc,hrbmp)
        If StateOwnRgn=1
          For i=0 To states-1
            BitBlt_(hrmdc,0,0,bw,bh,hmdc,i*bw,0,#SRCCOPY)
            SelectObject_(hrmdc,hpbm2)
            Rgn(i)=BitmapToRegion(hrbmp,-1)
            hpbm2=SelectObject_(hrmdc,hrbmp)
          Next i
          SelectObject_(hrmdc,hpbm2)
          DeleteDC_(hrmdc)
          DeleteObject_(hrbmp)
          SelectObject_(hmdc, hpbm)
          DeleteDC_(hmdc)
        Else
          BitBlt_(hrmdc,0,0,bw,bh,hmdc,0,0,#SRCCOPY)
          SelectObject_(hrmdc,hpbm2)
          Rgn(0)=BitmapToRegion(hrbmp,-1)
          DeleteDC_(hrmdc)
          SelectObject_(hmdc, hpbm)
          DeleteDC_(hmdc)
        EndIf
      ElseIf Resize
        Rgn(0)=BitmapToRegion(htbmp,-1)
        DeleteObject_(htbmp)
      Else
        Rgn(0)=BitmapToRegion(hbmp,-1)
      EndIf
    EndIf
   
    GdipDisposeImage(*image)
   
    hbt=ButtonGadget(nButton,bx,by,bw,bh,Text$,Flags)
    If hbt
      *bd=AddMapElement(FreeFormButtonsMap(),Str(hbt),#PB_Map_NoElementCheck)
      *bd\nButton=nButton
      *bd\bt\left=bx : *bd\bt\top=by : *bd\bt\right=bw : *bd\bt\bottom=bh
      *bd\image=*ButtonStatesData : *bd\imagesize=ImageDataSize
      *bd\rgn=*ButtonRgnData : *bd\rgnsize=RgnDataSize : For i=0 To 4 : *bd\hrgn[i]=Rgn(i) : Next i
      *bd\states=states : *bd\StateOwnRgn=StateOwnRgn : *bd\text=Text$ : *bd\Flags=Flags
    Else
      DeleteObject_(hbmp)
      MessageRequester("FreeFormButton Function - Error 4","ButtonGadget FAIL - Кнопку создать не удалось!")
      ProcedureReturn 0
    EndIf
   
    If states=1
      himl=ImageList_Create_(bw,bh,#ILC_COLOR32,1,1)
    Else
      himl=ImageList_Create_(bw,bh,#ILC_COLOR32,1,5)
    EndIf
 
    If himl
      ImageList_Add_(himl,hbmp,0)
      DeleteObject_(hbmp)
      *bd\himl=himl : *bd\uAlign=#BUTTON_IMAGELIST_ALIGN_CENTER
      *bd\margin\top=1 : *bd\margin\bottom=1
      *bd\margin\left=1 : *bd\margin\right=1
      If PostMessage_(hbt,#BCM_SETIMAGELIST+#BCM_FIRST,0,*bd+OffsetOf(ButtonData\himl))<>1
        MessageRequester("FreeFormButton Function - Error 5","Новое изобажение для кнопки не установленно!")
      EndIf
    Else
      MessageRequester("FreeFormButton Function - Error 6","Создать список изображений для кнопки не удалось!")
      ProcedureReturn 0
    EndIf
  EndIf
 
  Xform\eM11=1.0 : Xform\eM22=1.0 : If Resize : Xform\eM11=rw : Xform\eM22=rh : EndIf
 
  If *ButtonRgnData=0 And RgnDataSize=-1
    If *bd\hrgn[0]
      hrgn=*bd\hrgn[0]
      hvalidrgn=CreateRectRgn_(0,0,bw,bh)
    EndIf
  ElseIf RgnDataSize>0
    hrgn=ExtCreateRegion_(@Xform,RgnDataSize,*ButtonRgnData)
    hvalidrgn=CreateRectRgn_(0,0,bw,bh)
  ElseIf RgnDataSize=-1
    RgnDataSize=GetRegionData_(*ButtonRgnData,0,0)
    If RgnDataSize
      *mem=AllocateMemory(RgnDataSize)
      If GetRegionData_(*ButtonRgnData,RgnDataSize,*mem)
        hrgn=ExtCreateRegion_(@Xform,RgnDataSize,*mem)
        hvalidrgn=CreateRectRgn_(0,0,bw,bh)
      Else
        MessageRequester("FreeFormButton Function - Error 7","Функция GetRegionData при получении данных региона вернула код ошибки!")
      EndIf
      FreeMemory(*mem)
    Else
      MessageRequester("FreeFormButton Function - Error 8","Функция GetRegionData при получении размера региона вернула код ошибки!")
    EndIf
  ElseIf RgnDataSize=0 And *ButtonRgnData
    If ReadFile(0,PeekS(*ButtonRgnData))
      RgnDataSize=FileSize(PeekS(*ButtonRgnData))
      *mem=AllocateMemory(RgnDataSize)
      ReadData(0,*mem,RgnDataSize)
      CloseFile(0)
      hrgn=ExtCreateRegion_(@Xform,RgnDataSize,*mem)
      hvalidrgn=CreateRectRgn_(0,0,bw,bh)
      FreeMemory(*mem)
    Else
      MessageRequester("FreeFormButton Function - Error 9","Не удалось открыть файл "+RgnFilePath$+"!")
      ProcedureReturn 0
    EndIf
  EndIf
 
  If hrgn And hvalidrgn
    CombineRgn_(hvalidrgn,hvalidrgn,hrgn,#RGN_AND)
    SetWindowRgn_(hbt,hvalidrgn,1)
    hvalidrgn=CreateRectRgn_(0,0,bw,bh)
    For i=0 To states-1
      If *bd\hrgn[i]
        CombineRgn_(*bd\hrgn[i],*bd\hrgn[i],hvalidrgn,#RGN_XOR)
      EndIf
    Next i
    DeleteObject_(hvalidrgn)
  ;Else
    ;MessageRequester("FreeFormButton Function - Error 10","Не удалось создать регион!")
    ;ProcedureReturn 0  
  EndIf
  If CallFunctionFast(*SetWindowSubclass,hbt,@FFBtnProc(),1,0)<>1
    MessageRequester("FreeFormButton Function - Error 11","Процедура перехвата сообщений кнопки не установленна!")
    ProcedureReturn 0
  EndIf
  ProcedureReturn hbt
EndProcedure
 
Procedure ReleaseFFBtnResources()
  Protected key$,i
  ForEach FreeFormButtonsMap()
    If FreeFormButtonsMap()\himl
      ImageList_Destroy_(FreeFormButtonsMap()\himl)
    EndIf
    For i=0 To 4
      If FreeFormButtonsMap()\hrgn[i]
        DeleteObject_(FreeFormButtonsMap()\hrgn[i])
      EndIf
    Next i
    key$=MapKey(FreeFormButtonsMap())
    CallFunctionFast(*RemoveWindowSubclass,Val(key$),@FFBtnProc(),1)
  Next
EndProcedure
 
Procedure ReleaseFFBtn(hbt)
  Protected key$,i
  key$=Str(hbt)
  If FreeFormButtonsMap(key$)\himl
    ImageList_Destroy_(FreeFormButtonsMap(key$)\himl)
  EndIf
  For i=0 To 4
    If FreeFormButtonsMap(key$)\hrgn[i]
      DeleteObject_(FreeFormButtonsMap(key$)\hrgn[i])
    EndIf
  Next i
  CallFunctionFast(*RemoveWindowSubclass,hbt,@FFBtnProc(),1)
  DeleteMapElement(FreeFormButtonsMap(),key$)
  hCurButton=0
EndProcedure
 
Procedure.i GdipCreateMatrix2Ex(ScaleX.f, ScaleY.f, Angle.f, TranslateX.f, TranslateY.f)
     Protected AngleRadian.f,*Localmatrix
     AngleRadian = #PI/180*Angle
     If GdipCreateMatrix2(ScaleX*|!REG3XP3!>Cos(AngleRadian), ScaleY*|!REG3XP3!>Sin(AngleRadian), ScaleX*(-Sin(AngleRadian)), ScaleY*|!REG3XP3!>Cos(AngleRadian), TranslateX, TranslateY, @*Localmatrix) = #Ok
          ProcedureReturn *Localmatrix
     Else
          ProcedureReturn 0
     EndIf
EndProcedure
 
Procedure SizedButtonPreview(hbt,*pt.POINT,Direction,hdc=0)
  Static nRect.RECT,oRect.RECT,key$,hPrevButton,orw,orh,AntiSmooth=-1
  ;Static *matrix
  key$=Str(hbt) : oRect=FreeFormButtonsMap(key$)\bt : nRect=oRect : orw=oRect\right-oRect\left : orh=oRect\bottom-oRect\top
  Select Direction
    Case 0
      nRect\right=*pt\x : nRect\bottom=*pt\y
      ;*matrix=GdipCreateMatrix2Ex((nRect\right-nRect\left)/orw,(nRect\bottom-nRect\top)/orh,0,oRect\left,oRect\top)
    Case 1
      nRect\left=*pt\x :
      ;*matrix=GdipCreateMatrix2Ex((nRect\right-nRect\left)/orw,1,0,*pt\x,oRect\top)
    Case 2
      nRect\right=*pt\x
      ;*matrix=GdipCreateMatrix2Ex((nRect\right-nRect\left)/orw,1,0,oRect\left,oRect\top)
    Case 3
      nRect\top=*pt\y
      ;*matrix=GdipCreateMatrix2Ex(1,(nRect\bottom-nRect\top)/orh,0,oRect\left,*pt\y)
    Case 4
      nRect\left=*pt\x : nRect\top=*pt\y
      ;*matrix=GdipCreateMatrix2Ex((nRect\right-nRect\left)/orw,(nRect\bottom-nRect\top)/orh,0,*pt\x,*pt\y)
    Case 5
      nRect\right=*pt\x : nRect\top=*pt\y
      ;*matrix=GdipCreateMatrix2Ex((nRect\right-nRect\left)/orw,(nRect\bottom-nRect\top)/orh,0,oRect\left,*pt\y)
    Case 6
      nRect\bottom=*pt\y
      ;*matrix=GdipCreateMatrix2Ex(1,(nRect\bottom-nRect\top)/orh,0,oRect\left,oRect\top)
    Case 7
      nRect\left=*pt\x : nRect\bottom=*pt\y
      ;*matrix=GdipCreateMatrix2Ex((nRect\right-nRect\left)/orw,(nRect\bottom-nRect\top)/orh,0,*pt\x,oRect\top)
    Case 8
      nRect\right=*pt\x : nRect\bottom=*pt\y
      ;*matrix=GdipCreateMatrix2Ex((nRect\right-nRect\left)/orw,(nRect\bottom-nRect\top)/orh,0,oRect\left,oRect\top)
  EndSelect
  If hPrevButton=hbt
;     GdipCreateRegionHrgn(FreeFormButtonsMap(key)\hrgn,@*region)
;     GdipTransformRegion(*region,*matrix)
;     GdipGetRegionHRgn(*region,*gfx,@hrgn)
;     GdipDeleteRegion(*region)
;     Gdiplus_DelMatrix(*matrix)
    GdipDrawImageRectRectI(*gfx,*image,0,0,nRect\right-nRect\left,nRect\bottom-nRect\top,0,mbmph,oRect\right-oRect\left+AntiSmooth,oRect\bottom-oRect\top+AntiSmooth,#UnitPixel,#Null,#Null,#Null)
    hdc=GetDC_(hgui)
    BitBlt_(hdc,nRect\left,nRect\top,nRect\right-nRect\left,nRect\bottom-nRect\top,hmdc,0,0,#SRCCOPY)
    ;StretchBlt_(hdc,nRect\left,nRect\top,nRect\right-nRect\left,nRect\bottom-nRect\top,hmdc,0,mbmph,oRect\right-oRect\left,oRect\bottom-oRect\top,#SRCCOPY)
    ExcludeClipRect_(hdc,nRect\left,nRect\top,nRect\right,nRect\bottom)
    FillRect_(hdc,@uRect,hpbr)
    ReleaseDC_(hgui,hdc)
;     DeleteObject_(hrgn)
    uRect=nRect
  Else
    GdipDisposeImage(*image)
    uRect=oRect : hPrevButton=hbt
    PatBlt_(hmdc,0,mbmph,oRect\right-oRect\left,oRect\bottom-oRect\top,#PATCOPY)
    ImageList_Draw_(FreeFormButtonsMap(key$)\himl,0,hmdc,0,mbmph,#ILD_NORMAL)
    GdipCreateBitmapFromHBITMAP(hbmp,0,@*image)
  EndIf
EndProcedure
 
Procedure DrawFrame(*r.RECT,thickness,byWM_PAINT=0)
  Static hrgn,hirgn,hdc,ps.PAINTSTRUCT
  If byWM_PAINT
    If EraseFrame
      hdc=BeginPaint_(hgui,@ps)
      FillRgn_(hdc,hrgn,hfpbr)
      EndPaint_(hgui,@ps)
    EndIf
  Else
    If EraseFrame
      EraseFrame()
    EndIf
    hrgn=CreateRoundRectRgn_(*r\left,*r\top,*r\right,*r\bottom,thickness*2,thickness*2)
    hirgn=CreateRoundRectRgn_(*r\left-thickness,*r\top-thickness,*r\right+thickness,*r\bottom+thickness,thickness*2-2,thickness*2-2)
    CombineRgn_(hrgn,hrgn,hirgn,#RGN_XOR)
    hdc=GetDC_(hgui)
    FillRgn_(hdc,hrgn,hfpbr)
    ReleaseDC_(hgui,hdc)
    DeleteObject_(hirgn)
    hurgn=hrgn : EraseFrame=1
  EndIf
EndProcedure
 
Procedure EraseFrame()
  Static hdc
  If EraseFrame=0
    ProcedureReturn 0
  EndIf
  hdc=GetDC_(hgui)
  FillRgn_(hdc,hurgn,hpbr)
  ReleaseDC_(hgui,hdc)
  DeleteObject_(hurgn)
  EraseFrame=0
EndProcedure
 
Procedure SetButtonRect(hbt)
  Static key$,inc=20
  key$=Str(hbt)
  GetWindowRect_(hbt,@FreeFormButtonsMap(key$)\bt)
  MapWindowPoints_(0,hgui,@FreeFormButtonsMap(key$)\bt,2)
  ButtonFrameRect=FreeFormButtonsMap(key$)\bt
  ButtonFrameRect\left-inc : ButtonFrameRect\right+inc : ButtonFrameRect\top-inc : ButtonFrameRect\bottom+inc
EndProcedure
 
;{
Procedure PointInRect(*pt.POINT,*Rect.RECT)
  If (*pt\x-*Rect\left)|(*Rect\right-*pt\x)|(*pt\y-*Rect\top)|(*Rect\bottom-*pt\y)>0
    ProcedureReturn 1
  EndIf
EndProcedure
 
; 4 _3_ 5
;  | 0 |
; 1|___|2
; 7  6  8
Procedure PointIn3x3Rect2(*pt.POINT,*Rect.RECT,inc)
    If *pt\x<*Rect\left+inc : sc=1 : ElseIf *pt\x>*Rect\right-inc : sc=2 : EndIf
    If *pt\y<*Rect\top+inc : sc+3 : ElseIf *pt\y>*Rect\bottom-inc : sc+6 : EndIf
  ProcedureReturn sc
EndProcedure
 
Procedure PointIn3x3Rect(*pt.POINT,*Rect.RECT,inc)
  If PointInRect(*pt.POINT,*Rect.RECT)
    ProcedureReturn PointIn3x3Rect2(*pt.POINT,*Rect.RECT,inc)
  EndIf
EndProcedure
;}
 
hgui=OpenWindow(0,0,0,320,240,"Кнопка произовльной формы",#WS_OVERLAPPEDWINDOW|#PB_Window_ScreenCentered|#WS_CLIPCHILDREN)
If hgui
  SetWindowColor(0,$cdebff)
  hud=SpinGadget(0,297,0,24,20,1,5)
  SetGadgetState (0,1) : SetGadgetText(0,"1")
 
  GdipLoadimageFromFile("frame_pattern.png",@*image)
  GdipCreateHBITMAPFromBitmap(*image,@hfpbmp,0)
  GdipDisposeImage(*image)
  hfpbr=CreatePatternBrush_(hfpbmp)
  DeleteObject_(hfpbmp)
 
  hdc=GetDC_(0)
  hmdc=CreateCompatibleDC_(hdc)
  GdipSetInterpolationMode(*gfx,#InterpolationModeHighQualityBicubic)
  bi\bmiHeader\biSize=SizeOf(BITMAPINFOHEADER) : bi\bmiHeader\biPlanes=1 : bi\bmiHeader\biBitCount=32 : bi\bmiHeader\biCompression=#BI_RGB
  bi\bmiHeader\biWidth=GetSystemMetrics_(#SM_CXMAXIMIZED) : bi\bmiHeader\biHeight=2*|!REG3XP3!>GetSystemMetrics_(#SM_CYMAXIMIZED)
  mbmpw=bi\bmiHeader\biWidth : mbmph=bi\bmiHeader\biHeight/2
  hbmp=CreateDIBSection_(hmdc,@bi,#DIB_RGB_COLORS,@*BitmapBits,0,0)
  ;hbmp=CreateCompatibleBitmap_(hdc,GetSystemMetrics_(#SM_CXMAXIMIZED),2*GetSystemMetrics_(#SM_CYMAXIMIZED))
  SelectObject_(hmdc,hbmp)
  GdipCreateFromHDC(hmdc,@*gfx)
  bits=$ffffebcd
  hpbmp=CreateBitmap_(1,1,1,32,@bits)
  hpbr=CreatePatternBrush_(hpbmp)
  DeleteObject_(hpbmp)
  SelectObject_(hmdc,hpbr)
  ReleaseDC_(hgui,hdc)
  htxt=TextGadget(1,0,0,296,20,"Перетащите в окно изображение кнопки c n-cостояний")
  nGadgets=2
  DragAcceptFiles_(hgui,1)
  SetWindowCallback(@WndProc(),0)
  Repeat
    Event=WaitWindowEvent()
    Select Event
      Case #PB_Event_CloseWindow
        ReleaseFFBtnResources()
        ClearList(ButtonsImages())
        DeleteObject_(hfpbr)
        DeleteObject_(hbmp)
        GdipDisposeImage(*image)
        Gdiplus_DelGraphics(*gfx)
        DeleteObject_(hpbr)
        DeleteDC_(hmdc)
        End
    EndSelect
  ForEver
EndIf



Пример №2 - Using FreeFormButton
Код:
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
XIncludeFile #PB_Compiler_Home+"Includes\gdiplus.pbi"
 
#DC_BRUSH=18
#BCM_SETIMAGELIST=2
#BCM_FIRST=$1600
#BUTTON_IMAGELIST_ALIGN_CENTER=4
 
#BST_UNCHECKED=0
#BST_CHECKED=1
#BST_INDETERMINATE=2
#BST_PUSHED=4
#BST_FOCUS=8
 
Structure ButtonData
  nButton.l
  bt.RECT
  *image
  imagesize.l
  *rgn
  rgnsize.l
  himl.l
  margin.RECT
  uAlign.l
  hrgn.l[5]
  StateOwnRgn.b
  states.b
  text.s
  Flags.l
  ImageFilePath.s
EndStructure
 
;{
Declare FFBtnProc(hWnd,Msg,wParam,lParam,uIdSubclass,dwRefData)
Declare BitmapToRegion(*Bitmap,BitmapSize=0,ExcludeColor.q=$FFFFFFFF|$64000000<<32)
Declare FreeFormButton(nButton,bx,by,bw,bh,*ButtonStatesData,*ButtonRgnData,ImageDataSize=0,RgnDataSize=0,Text$="",states=5,StateOwnRgn=0,Flags=0)
Declare ReleaseFFBtnResources()
Declare ReleaseFFBtn(hbt)
 
Global ProgramPath$=GetCurrentDirectory()
Global *AlphaBlend=GetProcAddress_(GetModuleHandle_("gdi32.dll"),"GdiAlphaBlend")
Global *DefSubclassProc=GetProcAddress_(GetModuleHandle_("comctl32.dll"),"DefSubclassProc")
Global *SetWindowSubclass=GetProcAddress_(GetModuleHandle_("comctl32.dll"),"SetWindowSubclass")
Global *RemoveWindowSubclass=GetProcAddress_(GetModuleHandle_("comctl32.dll"),"RemoveWindowSubclass")
;}
 
Global NewMap FreeFormButtonsMap.ButtonData()
Global hgui,hdc,hmdc,hbmp,hpbr,hbmp,mbmpw,mbmph,hfpbmp,hfpbr,*BitmapBits,bits
Global *token,*gfx,*image,bi.BITMAPINFO
 
*token=Gdiplus_New()
 
Procedure FFBtnProc(hWnd,Msg,wParam,lParam,uIdSubclass,dwRefData)
  Static r,in,key$,hdc
  key$=Str(hWnd)
  Select Msg
    Case #WM_ENABLE
      RedrawWindow_(hWnd,0,0,#RDW_INVALIDATE)
      ProcedureReturn 0
    Case #WM_SETTEXT
    Case #WM_PAINT
      r=CallFunctionFast(*DefSubclassProc,hWnd,#BM_GETSTATE,0,0)
      If r&#BST_PUSHED
        in=2
      ElseIf r&#WM_MOUSEMOVE
        in=1
      ElseIf r&#BST_FOCUS
        in=4
      Else
        in=0
      EndIf
      ; Если регион для данного состояния был создан выполняем
      If FreeFormButtonsMap(key$)\hrgn[in]<>0
        If in>0
          ; Получаем кешированный контекст устройства
          hdc=GetDCEx_(hWnd,0,#DCX_CACHE)
          ; Заливаем фон кнопки
          FillRgn_(hdc,FreeFormButtonsMap(key$)\hrgn[in],hpbr)
          ; Освобождаем контекст
          ReleaseDC_(hWnd,hdc)
        EndIf
        ; Делаем область вокруг кнопки обозначенную регионом действующей и не требующей перерисовки
        ValidateRgn_(hWnd,FreeFormButtonsMap(key$)\hrgn[in])
      ElseIf FreeFormButtonsMap(key$)\hrgn[0]<>0
        ValidateRgn_(hWnd,FreeFormButtonsMap(key$)\hrgn[0])
      EndIf
    Case #WM_SETFOCUS
      CallFunctionFast(*DefSubclassProc,wParam,#BM_SETSTYLE,#BS_PUSHBUTTON,0)
      CallFunctionFast(*DefSubclassProc,hWnd,#BM_SETSTYLE,#BS_DEFPUSHBUTTON,0)
    Case #WM_KILLFOCUS
      CallFunctionFast(*DefSubclassProc,hWnd,#BM_SETSTYLE,#BS_PUSHBUTTON,0)
    Case #WM_UPDATEUISTATE
      ; Отменяем обработку этого сообщения, она приводит к перерисовке всего прямоугольника кнопки
      ; В версии Purebasic 4.51 это сообщение не приходит вообще
      ProcedureReturn 0
  EndSelect
  ProcedureReturn CallFunctionFast(*DefSubclassProc,hWnd,Msg,wParam,lParam)
EndProcedure
 
Procedure BitmapToRegion(*Bitmap,BitmapSize=0,ExcludeColor.q=$FFFFFFFF|$64000000<<32)
  Structure Scan : x1.w : y1.w : x2.w : y2.w : EndStructure
  Structure PixClr : b.a : g.a : r.a : a.a : EndStructure
  Structure ClrLimit : hb.a : hg.a : hr.a : ha.a : lb.a : lg.a : lr.a : la.a : EndStructure
  Protected i,r,hbt,hdc,hbmp,hrgn,nRects,hGlobal,x1
  Protected bi.BITMAPINFO,Xform.XFORM
  Protected *stream.IStream,*mem,*image,*BitmapBits,*r.Scan,*PixClr.PixClr,*cl.ClrLimit
  Protected Dim lp.Scan(2048),Dim lb.Scan(2048)
  Protected *rgndata.RGNDATAHEADER,*rgnrects.RECT
 
  If BitmapSize>0
    hGlobal=GlobalAlloc_(#GMEM_MOVEABLE,BitmapSize)
    *mem=GlobalLock_(hGlobal)
    CopyMemory(*Bitmap,*mem,BitmapSize)
    GlobalUnlock_(hGlobal)  
    If CreateStreamOnHGlobal_(hGlobal,#True,@*stream)=#S_OK
      r|GdipCreateBitmapFromStream(*stream,@*image)
    EndIf
    *stream\Release()
    GlobalFree_(*mem) : *mem=0
    r|GdipCreateHBITMAPFromBitmap(*image,@hbmp,0)
    GdipDisposeImage(*image)
  ElseIf BitmapSize=0
    r|GdipLoadimageFromFile(PeekS(*Bitmap),@*image)
    r|GdipCreateHBITMAPFromBitmap(*image,@hbmp,0)
    GdipDisposeImage(*image)
  ElseIf BitmapSize=-1
    hbmp=CopyImage_(*Bitmap,#IMAGE_BITMAP,0,0,#LR_COPYRETURNORG)
  EndIf
 
  If r<>0
    MessageRequester("BitmapToRegion Function - Error 1","Загрузка изображения для преоьразования его в регион не удалась!")
    ProcedureReturn 0
  EndIf
 
  hdc=GetDC_(0) : bi\bmiHeader\biSize=SizeOf(BITMAPINFOHEADER)
  If GetDIBits_(hdc,hbmp,0,0,0,@bi,#DIB_RGB_COLORS)=0
    ReleaseDC_(0,hdc) : DeleteObject_(hbmp)
    MessageRequester("BitmapToRegion Function - Error 3","Функция GetDIBits. Ошибка при получении данных заголовка изображения!")
    ProcedureReturn 0
  EndIf
 
  bmpw=bi\bmiHeader\biWidth : bmph=bi\bmiHeader\biHeight : BitmapSize=bmpw*bmph*4
  *mem=AllocateMemory((bmph+3)*bmpw*4)
 
  If *mem=0
    ReleaseDC_(0,hdc) : DeleteObject_(hbmp)
    MessageRequester("BitmapToRegion Function - Error 4","Не удалось выделить память для изображения!")
    ProcedureReturn 0
  EndIf
 
  If GetDIBits_(hdc,hbmp,0,bmph,*mem+2*bmpw*4,@bi,#DIB_RGB_COLORS)=0
    ReleaseDC_(0,hdc) : DeleteObject_(hbmp) : FreeMemory(*mem)
    MessageRequester("BitmapToRegion Function - Error 5","Функция GetDIBits. Ошибка при коприровании байтов изображения!")
  EndIf
 
  ReleaseDC_(0,hdc) : DeleteObject_(hbmp) : PokeL(*mem,$FFFFFFFF)
  *r=*mem+BitmapSize+2*bmpw*4 : x1=-1 : *cl=@ExcludeColor
  For oy=bmph+1 To 0 Step -1
    offset=oy*bmpw
    For ox=0 To bmpw-1
      *PixClr=*mem+(offset+ox)*4
      If *PixClr\a>=*cl\la And *PixClr\a<=*cl\ha And *PixClr\r>=*cl\lr And *PixClr\r<=*cl\hr And *PixClr\g>=*cl\lg And *PixClr\g<=*cl\hg And *PixClr\b>=*cl\lb And *PixClr\b<=*cl\hb
        If x1=-1
          x1=ox
          c+1
        EndIf
      ElseIf x1<>-1
        lp(c)\x1=x1
        lp(c)\x2=ox
        lp(c)\y1=bmph-oy+1
        x1=-1
      EndIf
    Next ox
   
    If x1<>-1
      lp(c)\x1=x1
      lp(c)\x2=bmpw
      lp(c)\y1=bmph-oy+1
      x1=-1
    EndIf
   
    If c
      If lb(0)\x1=0
        For i=1 To c
          lb(i)=lp(i)
        Next i
        lb(0)\x1=c
        c=0
        Continue
      ElseIf c<>lb(0)\x1
        If Height
          For i=1 To lb(0)\x1
            *r\x1=lb(i)\x1 : *r\x2=lb(i)\x2 : *r\y1=lb(i)\y1 : *r\y2=lb(i)\y1+Height+1 : *r-8 : nRects+1
            ; Debug "1 Rect 1 x1 "+Str(lb(i)\x1)+" x2 "+Str(lb(i)\x2)+" y1 "+Str(lb(i)\y1)+" y2 "+Str(lb(i)\y1+Height+1)+" Height "+Str(Height+1)
          Next i
          For i=1 To c
            *r\x1=lp(i)\x1 : *r\x2=lp(i)\x2 : *r\y1=lp(i)\y1 : *r\y2=lp(i)\y1+1 : *r-8 : nRects+1
            ; Debug "1 Line 2 x1 "+Str(lp(i)\x1)+" x2 "+Str(lp(i)\x2)+" y1 "+Str(lp(i)\y1)
          Next i
          lb(0)\x1=0
          Height=0
        Else
          For i=1 To lb(0)\x1
            *r\x1=lb(i)\x1 : *r\x2=lb(i)\x2 : *r\y1=lb(i)\y1 : *r\y2=lb(i)\y1+1 : *r-8 : nRects+1
            ; Debug "2 Line 1 x1 "+Str(lb(i)\x1)+" x2 "+Str(lb(i)\x2)+" y1 "+Str(lb(i)\y1)
          Next i
          For i=1 To c
            *r\x1=lp(i)\x1 : *r\x2=lp(i)\x2 : *r\y1=lp(i)\y1 : *r\y2=lp(i)\y1+1 : *r-8 : nRects+1
            ; Debug "2 Line 2 x1 "+Str(lp(i)\x1)+" x2 "+Str(lp(i)\x2)+" y1 "+Str(lp(i)\y1)
          Next i
          lb(0)\x1=0
        EndIf
      Else
        For i=1 To c
          If lp(i)\x1<>lb(i)\x1 Or lp(i)\x2<>lb(i)\x2 Or lb(i)\y1+Height+1<>lp(i)\y1
            i=0 : Break
          EndIf
        Next i
        If i
          Height+1
        ElseIf Height
          For i=1 To lb(0)\x1
            *r\x1=lb(i)\x1 : *r\x2=lb(i)\x2 : *r\y1=lb(i)\y1 : *r\y2=lb(i)\y1+Height+1 : *r-8 : nRects+1
            ; Debug "3 Rect 1 x1 "+Str(lb(i)\x1)+" x2 "+Str(lb(i)\x2)+" y1 "+Str(lb(i)\y1)+" y2 "+Str(lb(i)\y1+Height+1)+" Height "+Str(Height+1)
          Next i
          For i=1 To c
            *r\x1=lp(i)\x1 : *r\x2=lp(i)\x2 : *r\y1=lp(i)\y1 : *r\y2=lp(i)\y1+1 : *r-8 : nRects+1
            ; Debug "3 Line 2 x1 "+Str(lp(i)\x1)+" x2 "+Str(lp(i)\x2)+" y1 "+Str(lp(i)\y1)
          Next i
          lb(0)\x1=0
          Height=0
        Else
          For i=1 To lb(0)\x1
            *r\x1=lb(i)\x1 : *r\x2=lb(i)\x2 : *r\y1=lb(i)\y1 : *r\y2=lb(i)\y1+1 : *r-8 : nRects+1
            ; Debug "4 Line 1 x1 "+Str(lb(i)\x1)+" x2 "+Str(lb(i)\x2)+" y1 "+Str(lb(i)\y1)
          Next i
          For i=1 To c
            *r\x1=lp(i)\x1 : *r\x2=lp(i)\x2 : *r\y1=lp(i)\y1 : *r\y2=lp(i)\y1+1 : *r-8 : nRects+1
            ; Debug "4 Line 2 x1 "+Str(lp(i)\x1)+" x2 "+Str(lp(i)\x2)+" y1 "+Str(lp(i)\y1)
          Next i
          lb(0)\x1=0
        EndIf
      EndIf
      c=0
    EndIf
  Next oy
 
  If nRects
    nRects-Bool(Not lb(0)\x1)
    *r=*mem+BitmapSize+2*bmpw*4
    *rgndata=AllocateMemory(SizeOf(RGNDATAHEADER)+nRects*|!REG3XP3!>SizeOf(RECT))
    If *rgndata
      *rgnrects=*rgndata+SizeOf(RGNDATAHEADER)
      For i=1 To nRects
        *rgnrects\left=($ff00&*r\x1)|($ff&*r\x1)
        *rgnrects\top=($ff00&*r\y1)|($ff&*r\y1)
        *rgnrects\right=($ff00&*r\x2)|($ff&*r\x2)
        *rgnrects\bottom=($ff00&*r\y2)|($ff&*r\y2)
        *rgnrects+16 : *r-8
      Next i
      *rgndata\dwSize=SizeOf(RGNDATAHEADER)
      *rgndata\iType=1 : *rgndata\nCount=nRects
      *rgndata\nRgnSize=nRects*|!REG3XP3!>SizeOf(RECT)
      Xform\eM11=1.0 : Xform\eM22=1.0
      hrgn=ExtCreateRegion_(@Xform,*rgndata\dwSize+*rgndata\nRgnSize,*rgndata)
      FreeMemory(*mem)
      FreeMemory(*rgndata)
      If hrgn
        ProcedureReturn hrgn
      Else
        MessageRequester("BitmapToRegion Function - Error 6","Фунция ExtCreateRegion не вернула указатель. Создать регион не дуалось!")
        ProcedureReturn 0
      EndIf
    Else
      FreeMemory(*mem)
      MessageRequester("BitmapToRegion Function - Error 7","Не удалось выделить память для данных региона!")
      ProcedureReturn 0
    EndIf
  EndIf
  FreeMemory(*mem)
EndProcedure
 
Procedure FreeFormButton(nButton,bx,by,bw,bh,*ButtonStatesData,*ButtonRgnData,ImageDataSize=0,RgnDataSize=0,Text$="",states=5,StateOwnRgn=0,Flags=0)
  Protected i,r,hbt,hdc,hmdc,hbmp,hrgn,hvalidrgn,hrmdc,htbmp,hrbmp,hpbm,hpbm2,Dim Rgn.l(4),Resize
  Static hGlobal,*fmem,*mem,*gfx,*image,*BitmapBits,*bd.ButtonData
  Static bmpw,bmph,rw.f,rh.f
  Static *stream.IStream,bi.BITMAPINFO,Xform.XFORM
 
  If *ButtonStatesData=0
    MessageRequester("FreeFormButton Function - Error 1","Функции передано не достаточное число параметров."+#CRLF$+"Данных о изображении кнопки нет!")
    ProcedureReturn 0
  EndIf
 
  If ImageDataSize=-1
    r|GdipCreateBitmapFromHBITMAP(*ButtonStatesData,0,@*image)
  ElseIf ImageDataSize<>0
    hGlobal=GlobalAlloc_(#GMEM_MOVEABLE,ImageDataSize)
    *fmem=GlobalLock_(hGlobal)
    CopyMemory(*ButtonStatesData,*fmem,ImageDataSize)
    GlobalUnlock_(hGlobal)  
    If CreateStreamOnHGlobal_(hGlobal,#True,@*stream)=#S_OK
      r|GdipCreateBitmapFromStream(*stream,@*image)
    EndIf
    *stream\Release()
    GlobalFree_(*fmem)
  Else
    r|GdipLoadimageFromFile(PeekS(*ButtonStatesData),@*image)
  EndIf
 
  If r<>0
    MessageRequester("FreeFormButton Function - Error 2","Не удалось загрузить изображение!")
    ProcedureReturn 0
  Else
    GdipGetImageWidth(*image,@bmpw)
    GdipGetImageHeight(*image,@bmph)
    If bw=0 : bw=bmpw/states : EndIf
    If bh=0 : bh=bmph : EndIf
   
    rw.f=bw/(bmpw/states) : rh.f=bh/bmph : If rw<>1 Or rh<>1 : Resize=1 : EndIf
   
    If Resize
      hmdc=CreateCompatibleDC_(0)
      bi\bmiHeader\biSize=SizeOf(BITMAPINFOHEADER)
      bi\bmiHeader\biPlanes=1
      bi\bmiHeader\biBitCount=32
      bi\bmiHeader\biCompression=#BI_RGB
      bi\bmiHeader\biHeight=bh
      If states=1
        bi\bmiHeader\biWidth=bw
      Else
        bi\bmiHeader\biWidth=bw*5
      EndIf
      hbmp=CreateDIBSection_(hmdc,@bi,#DIB_RGB_COLORS,@*BitmapBits,0,0)
      hpbm=SelectObject_(hmdc,hbmp)
      GdipCreateFromHDC(hmdc,@*gfx)
      GdipSetInterpolationMode(*gfx,#InterpolationModeHighQualityBicubic)
      r|GdipDrawImageRectI(*gfx,*image,0,0,bw*states,bh)
      If states>1
        For i=states To 4
          BitBlt_(hmdc,bw*i,0,bw,bh,hmdc,0,0,#SRCCOPY)
        Next i
      EndIf    
      SelectObject_(hmdc,hpbm)
      DeleteDC_(hmdc)
      GdipDeleteGraphics(*gfx)
    Else
      r|GdipCreateHBITMAPFromBitmap(*image,@hbmp,0)
    EndIf
   
    If hbmp=0 Or r<>0
      GdipDisposeImage(*image)
      MessageRequester("FreeFormButton Function - Error 3","Не удалось создать Gdi Bitmap!")
      ProcedureReturn 0
    EndIf
   
    If RgnDataSize=-1 And *ButtonRgnData=0
      If Resize
        GdipCreateHBITMAPFromBitmap(*image,@htbmp,0)
        htbmp=CopyImage_(htbmp,#IMAGE_BITMAP,bw*states,bh,#LR_COPYDELETEORG)
      Else
        htbmp=hbmp
      EndIf
     
      If states>1
       
        hmdc=CreateCompatibleDC_(0)
        hpbm=SelectObject_(hmdc,htbmp)
        hrmdc=CreateCompatibleDC_(0)
        bi\bmiHeader\biSize=SizeOf(BITMAPINFOHEADER)
        bi\bmiHeader\biPlanes=1
        bi\bmiHeader\biBitCount=32
        bi\bmiHeader\biCompression=#BI_RGB
        bi\bmiHeader\biWidth=bw : bi\bmiHeader\biHeight=-bh
        hrbmp=CreateDIBSection_(hmdc,@bi,#DIB_RGB_COLORS,@*BitmapBits,0,0)
        hpbm2=SelectObject_(hrmdc,hrbmp)
        If StateOwnRgn=1
          For i=0 To states-1
            BitBlt_(hrmdc,0,0,bw,bh,hmdc,i*bw,0,#SRCCOPY)
            SelectObject_(hrmdc,hpbm2)
            Rgn(i)=BitmapToRegion(hrbmp,-1)
            hpbm2=SelectObject_(hrmdc,hrbmp)
          Next i
          SelectObject_(hrmdc,hpbm2)
          DeleteDC_(hrmdc)
          DeleteObject_(hrbmp)
          SelectObject_(hmdc, hpbm)
          DeleteDC_(hmdc)
        Else
          BitBlt_(hrmdc,0,0,bw,bh,hmdc,0,0,#SRCCOPY)
          SelectObject_(hrmdc,hpbm2)
          Rgn(0)=BitmapToRegion(hrbmp,-1)
          DeleteDC_(hrmdc)
          SelectObject_(hmdc, hpbm)
          DeleteDC_(hmdc)
        EndIf
      ElseIf Resize
        Rgn(0)=BitmapToRegion(htbmp,-1)
        DeleteObject_(htbmp)
      Else
        Rgn(0)=BitmapToRegion(hbmp,-1)
      EndIf
    EndIf
   
    GdipDisposeImage(*image)
   
    hbt=ButtonGadget(nButton,bx,by,bw,bh,Text$,Flags)
    If hbt
      *bd=AddMapElement(FreeFormButtonsMap(),Str(hbt),#PB_Map_NoElementCheck)
      *bd\nButton=nButton
      *bd\bt\left=bx : *bd\bt\top=by : *bd\bt\right=bw : *bd\bt\bottom=bh
      *bd\image=*ButtonStatesData : *bd\imagesize=ImageDataSize
      *bd\rgn=*ButtonRgnData : *bd\rgnsize=RgnDataSize : For i=0 To 4 : *bd\hrgn[i]=Rgn(i) : Next i
      *bd\states=states : *bd\StateOwnRgn=StateOwnRgn : *bd\text=Text$ : *bd\Flags=Flags
    Else
      DeleteObject_(hbmp)
      MessageRequester("FreeFormButton Function - Error 4","ButtonGadget FAIL - Кнопку создать не удалось!")
      ProcedureReturn 0
    EndIf
   
    If states=1
      himl=ImageList_Create_(bw,bh,#ILC_COLOR32,1,1)
    Else
      himl=ImageList_Create_(bw,bh,#ILC_COLOR32,1,5)
    EndIf
   
    If himl
      ImageList_Add_(himl,hbmp,0)
      DeleteObject_(hbmp)
      *bd\himl=himl : *bd\uAlign=#BUTTON_IMAGELIST_ALIGN_CENTER
      *bd\margin\top=1 : *bd\margin\bottom=1
      *bd\margin\left=1 : *bd\margin\right=1
      If PostMessage_(hbt,#BCM_SETIMAGELIST+#BCM_FIRST,0,*bd+OffsetOf(ButtonData\himl))<>1
        MessageRequester("FreeFormButton Function - Error 5","Новое изобажение для кнопки не установленно!")
      EndIf
    Else
      MessageRequester("FreeFormButton Function - Error 6","Создать список изображений для кнопки не удалось!")
      ProcedureReturn 0
    EndIf
  EndIf
 
  Xform\eM11=1.0 : Xform\eM22=1.0 : If Resize : Xform\eM11=rw : Xform\eM22=rh : EndIf
 
  If *ButtonRgnData=0 And RgnDataSize=-1
    If *bd\hrgn[0]
      hrgn=*bd\hrgn[0]
      hvalidrgn=CreateRectRgn_(0,0,bw,bh)
    EndIf
  ElseIf RgnDataSize>0
    hrgn=ExtCreateRegion_(@Xform,RgnDataSize,*ButtonRgnData)
    hvalidrgn=CreateRectRgn_(0,0,bw,bh)
  ElseIf RgnDataSize=-1
    RgnDataSize=GetRegionData_(*ButtonRgnData,0,0)
    If RgnDataSize
      *mem=AllocateMemory(RgnDataSize)
      If GetRegionData_(*ButtonRgnData,RgnDataSize,*mem)
        hrgn=ExtCreateRegion_(@Xform,RgnDataSize,*mem)
        hvalidrgn=CreateRectRgn_(0,0,bw,bh)
      Else
        MessageRequester("FreeFormButton Function - Error 7","Функция GetRegionData при получении данных региона вернула код ошибки!")
      EndIf
      FreeMemory(*mem)
    Else
      MessageRequester("FreeFormButton Function - Error 8","Функция GetRegionData при получении размера региона вернула код ошибки!")
    EndIf
  ElseIf RgnDataSize=0 And *ButtonRgnData
    If ReadFile(0,PeekS(*ButtonRgnData))
      RgnDataSize=FileSize(PeekS(*ButtonRgnData))
      *mem=AllocateMemory(RgnDataSize)
      ReadData(0,*mem,RgnDataSize)
      CloseFile(0)
      hrgn=ExtCreateRegion_(@Xform,RgnDataSize,*mem)
      hvalidrgn=CreateRectRgn_(0,0,bw,bh)
      FreeMemory(*mem)
    Else
      MessageRequester("FreeFormButton Function - Error 9","Не удалось открыть файл "+RgnFilePath$+"!")
      ProcedureReturn 0
    EndIf
  EndIf
 
  If hrgn And hvalidrgn
    CombineRgn_(hvalidrgn,hvalidrgn,hrgn,#RGN_AND)
    SetWindowRgn_(hbt,hvalidrgn,1)
    hvalidrgn=CreateRectRgn_(0,0,bw,bh)
    For i=0 To states-1
      If *bd\hrgn[i]
        CombineRgn_(*bd\hrgn[i],*bd\hrgn[i],hvalidrgn,#RGN_XOR)
      EndIf
    Next i
    DeleteObject_(hvalidrgn)
    ;Else
    ;MessageRequester("FreeFormButton Function - Error 10","Не удалось создать регион!")
    ;ProcedureReturn 0  
  EndIf
  If CallFunctionFast(*SetWindowSubclass,hbt,@FFBtnProc(),1,0)<>1
    MessageRequester("FreeFormButton Function - Error 11","Процедура перехвата сообщений кнопки не установленна!")
    ProcedureReturn 0
  EndIf
  ProcedureReturn hbt
EndProcedure
 
Procedure ReleaseFFBtnResources()
  Protected key$,i
  ForEach FreeFormButtonsMap()
    If FreeFormButtonsMap()\himl
      ImageList_Destroy_(FreeFormButtonsMap()\himl)
    EndIf
    For i=0 To 4
      If FreeFormButtonsMap()\hrgn[i]
        DeleteObject_(FreeFormButtonsMap()\hrgn[i])
      EndIf
    Next i
    key$=MapKey(FreeFormButtonsMap())
    CallFunctionFast(*RemoveWindowSubclass,Val(key$),@FFBtnProc(),1)
  Next
EndProcedure
 
Procedure ReleaseFFBtn(hbt)
  Protected key$,i
  key$=Str(hbt)
  If FreeFormButtonsMap(key$)\himl
    ImageList_Destroy_(FreeFormButtonsMap(key$)\himl)
  EndIf
  For i=0 To 4
    If FreeFormButtonsMap(key$)\hrgn[i]
      DeleteObject_(FreeFormButtonsMap(key$)\hrgn[i])
    EndIf
  Next i
  CallFunctionFast(*RemoveWindowSubclass,hbt,@FFBtnProc(),1)
  DeleteMapElement(FreeFormButtonsMap(),key$)
  hCurButton=0
EndProcedure
 
hgui=OpenWindow(0,0,0,320,412,"Пример использования кнопок произовльной формы",#WS_OVERLAPPEDWINDOW|#PB_Window_ScreenCentered|#WS_CLIPCHILDREN)
If hgui
  ;Установим цвет фона окна
  SetWindowColor(0,$cdebff)
 
  GdipLoadimageFromFile("frame_pattern.png",@*image)
  GdipCreateHBITMAPFromBitmap(*image,@hfpbmp,0)
  GdipDisposeImage(*image)
  hfpbr=CreatePatternBrush_(hfpbmp)
  DeleteObject_(hfpbmp)
 
  hdc=GetDC_(0)
  hmdc=CreateCompatibleDC_(hdc)
  bi\bmiHeader\biSize=SizeOf(BITMAPINFOHEADER) : bi\bmiHeader\biPlanes=1 : bi\bmiHeader\biBitCount=32 : bi\bmiHeader\biCompression=#BI_RGB
  bi\bmiHeader\biWidth=GetSystemMetrics_(#SM_CXMAXIMIZED) : bi\bmiHeader\biHeight=2*|!REG3XP3!>GetSystemMetrics_(#SM_CYMAXIMIZED)
  mbmpw=bi\bmiHeader\biWidth : mbmph=bi\bmiHeader\biHeight/2
  hbmp=CreateDIBSection_(hmdc,@bi,#DIB_RGB_COLORS,@*BitmapBits,0,0)
  ;hbmp=CreateCompatibleBitmap_(hdc,GetSystemMetrics_(#SM_CXMAXIMIZED),2*GetSystemMetrics_(#SM_CYMAXIMIZED))
  SelectObject_(hmdc,hbmp)
  GdipCreateFromHDC(hmdc,@*gfx)
  GdipSetInterpolationMode(*gfx,#InterpolationModeHighQualityBicubic)
  bits=$ffffebcd ;Установим цвет фона для кнопок
  hpbmp=CreateBitmap_(1,1,1,32,@bits)
  hpbr=CreatePatternBrush_(hpbmp)
  DeleteObject_(hpbmp)
  SelectObject_(hmdc,hpbr)
  ReleaseDC_(hgui,hdc)
 
  FreeFormButton(0,8,5,303,60,@"FreeFormButton_States.png",0,0,-1,"",5,0)
  FreeFormButton(1,8,75,303,60,@"Button States.png",0,0,-1,"",5,0)
  FreeFormButton(2,8,140,303,60,@"Button States.png",0,0,-1,"",5,0)
  FreeFormButton(3,8,205,303,60,@"Button States Own Rgn Test.png",0,0,-1,"",5,1)
  For i=1 To 5
    FreeFormButton(i+3,i*11*(i-1),385-i*10,i*20,i*15,@"Windows_Button_States.png",0,0,-1,"",5,0)
  Next i
  hDisableBtn=FreeFormButton(9,8,270,303,60,@"Button 1.png",0,0,-1,"Disable",5,0)
  PostMessage_(hDisableBtn,#WM_SETFONT,LoadFont (0,"Comic Sans MS",40,#PB_Font_Bold),0)
 
  Repeat
    Event=WaitWindowEvent()
    Select Event
      Case #PB_Event_Gadget
        If EventGadget()=9
          If Disabled=0
            For i=0 To 8
              DisableGadget(i,1)
            Next i
            Disabled=1
            SetGadgetText(9,"Enable")
            UpdateWindow_(hDisableBtn)
          Else
            For i=0 To 8
              DisableGadget(i,0)
            Next i
            Disabled=0
            SetGadgetText(9,"Disable")
          EndIf
        EndIf
      Case #PB_Event_CloseWindow
        ReleaseFFBtnResources()
        DeleteObject_(hfpbr)
        DeleteObject_(hbmp)
        GdipDisposeImage(*image)
        Gdiplus_DelGraphics(*gfx)
        DeleteObject_(hpbr)
        DeleteDC_(hmdc)
        FreeFont(0)
        End
    EndSelect
  ForEver
EndIf
 



Процедура BitmapToRegion создаёт gdi регион на основе переданного ей изображения
*Bitmap - может быть хендл Gdi битмапа, адрес строки с именем файла или адрес буфера с изображением;

BitmapSize=0 - загружаем изображение из файла;
BitmapSize=-1 - изображение загружено, передан его хендл;
BitmapSize>0 - указывает размер изображения в буфере, передан его адрес;

ExcludeColor - пиксели с прозрачностью <= чем в ExcludeColor будут отсекаться;


Процедура FreeFormButton создаёт кнопку руководствуясь переданными ей параметрами и устанавливает процедуру перехвата сообщений кнопок FFBtnProc, основной задачей которой является отмена рисования Windows за пределами нового региона кнопки, бех этих мер ОС обновляет весь прямоугольник.

Параметры FreeFormButton:

nButton - номер гаджета; bx, by - координаты кнопки в окне; bw, bh - ширина и высота кнопки;

*ButtonStatesData - данные об изображении для кнопки (имя файла, адрес буфера, хендл битмапа);

ImageDataSize - указываем размер данных изображения, когда в *ButtonStatesData указатель на буфер;
-1, если в *ButtonStatesData хендл на gdi битмап;
0, если *ButtonStatesData адрес строки файла с изображением;

Процедура масштабирует регион в процессе создания с учётом изменения размера кнопки.

*ButtonRgnData - данные указывающие на регион для кнопки; RgnDataSize - размер данных региона;

если RgnDataSize=-1 и *ButtonRgnData=0, регион будет получен из изображения, прозрачные пиксели будут исключены;

если *ButtonRgnData - адрес на буфер с данными, а RgnDataSize - размер данных региона, то регион будет создан из памяти;

если RgnDataSize=-1, то в *ButtonRgnData передаём хендл региона из данных которого будет создан новый;

если RgnDataSize=0, то *ButtonRgnData адрес строки с файлом данных региона

Text$ - текст кнопки, шрифт и размер текста может быть изменён с помощью сообщения WM_SETFONT;

states - количество состояний у кнопки, если 1, то для отображения каждого из состояний кнопки будет использоваться одно и то же изображение,
Цитата:
Each value is an index to the appropriate image in the image list. If only one image is present, it is used for all states. If the image list contains more than one image, each index corresponds to one state of the button. If an image is not provided for each state, nothing is drawn for those states without images.


StateOwnRgn=1 - разрешаем использовать для каждого из состояний собственный регион, регион для нормального состояния кнопки присваевается окну кнопки, остальные регионы не должны выходить за его границы, площадь получаемая вычитанием региона другого состояния кнопки из нормального, будет закрашена фоновой кистью или любой другой на ваше усмотрение;

StateOwnRgn=0 - один и тот же регион будет использован для всех состояний кнопки;

Flags - обычные флаги, требуемые при создании кнопки в Purebasic;


В коде используется библиотека Gdi+ 1.0 замеченные изменения которые необходимо сделать в библиотеке:

строка 129 убрать тип у строковых указателей в структуре ImageCodecInfo;

строка 558 сменить тип у указателя *resultCount.l на *resultCount.long;

строка 852 сменить совпадающее имя процедуры с Alpha к примеру на _Alpha.


Вложения:
FreeFormButton.zip [644.76 KiB]
Скачиваний: 201
Окно программы 2.png [261 KiB]
Скачиваний: 0
Вернуться наверх
 Профиль  
 
СообщениеДобавлено: Пт май 23, 2014 8:45 am 
Не в сети
профессор

Зарегистрирован: Вт май 13, 2014 4:12 am
Сообщений: 684
Благодарил (а): 75 раз.
Поблагодарили: 20 раз.
Пункты репутации: 5
Вложения не качаются, браузер матом на них ругается, и отказывается качать.


Вернуться наверх
 Профиль  
 
СообщениеДобавлено: Пт май 23, 2014 1:12 pm 
Не в сети
PureBasic Coder
Аватар пользователя

Зарегистрирован: Чт ноя 10, 2011 10:50 am
Сообщений: 4049
Откуда: Ростов-на-Дону
Благодарил (а): 70 раз.
Поблагодарили: 81 раз.
Пункты репутации: 24
На exe ругается
https://www.virustotal.com/ru/file/a237 ... 400839758/
https://www.virustotal.com/ru/file/6ab6 ... 400839844/

_________________
Пурик - лучший язык программирования


Вернуться наверх
 Профиль  
 
Показать сообщения за:  Сортировать по:  
Начать новую тему Ответить на тему  [ Сообщений: 3 ] 

Часовой пояс: UTC + 3 часа


Кто сейчас на форуме

Сейчас этот форум просматривают: нет зарегистрированных пользователей и гости: 4


Вы не можете начинать темы
Вы не можете отвечать на сообщения
Вы не можете редактировать свои сообщения
Вы не можете удалять свои сообщения
Вы не можете добавлять вложения

Найти:
Перейти:  
Создано на основе phpBB® Forum Software © phpBB Group (блог о phpBB)
Сборка создана CMSart Studio
Русская поддержка phpBB