purebasic.info

PureBasic forum
Текущее время: Чт янв 18, 2018 12:46 am

Часовой пояс: UTC + 3 часа




Начать новую тему Ответить на тему  [ 1 сообщение ] 
Автор Сообщение
 Заголовок сообщения: Построение графиков
СообщениеДобавлено: Пт май 23, 2008 12:09 pm 
Не в сети
док
Аватар пользователя

Зарегистрирован: Ср апр 04, 2007 6:21 pm
Сообщений: 126
Откуда: Челябинская обл.
Благодарил (а): 0 раз.
Поблагодарили: 0 раз.
Пункты репутации: 0
Давно ещё написал, да забросил.
У всех знакомых она так без дела и валяется, в осн. на раб. столе.

Код:
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
FontID1 = LoadFont(0, "Verdana", 10)
FontID2 = LoadFont(1, "Verdana", 7)
CreateImage(0,640,480)
Structure sp_
   x.l
   y.l
EndStructure
Global cb.l=RGB(0,0,0)
Global ca.l=RGB(0,192,192)
Global cg.l=RGB(0,0,192)
Global cl.l=RGB(255,255,63)
Global wi=640, he=480
pp.s=Chr(10)+Chr(13)
SetThreadPriority_(GetCurrentThread_(),255)
Global x1.d, x2.d, y1.d, y2.d, x3.d, y3.d
#e=2.71828182846
 
Enumeration ; window 1
   #Text_0
   #Input_1
   #Frame3D_0
   #Text_1
   #Input_2
   #Text_3
   #Input_4
   #Text_9
   #Input_10
   #Text_5
   #Input_6
   #Text_6
   #Input_7
   #Text_11
   #Input_12
   #Frame3D_1
   #Button_0
   #Button_1
   #Button_2
   #Button_3
   #Button_4
   #Button_5
   #Button_6
   #img
   #check1
   #check2
EndEnumeration
Procedure.d integer(x.d)
   If x>=0: ProcedureReturn Int(x) : Else: ProcedureReturn Int(x)-1: EndIf
EndProcedure
Procedure.d flo(x.d)
   ProcedureReturn x-integer(x)
EndProcedure
Procedure.d Compute(line.s)
   Protected w.b=0, u.s=" ", q.l
   Restore again
   For q=1 To 7
      Read u
      If u="-" Or u="+"
         If FindString(line, u, 2)>0
            If Mid(line,FindString(line, u, 2)-1,1)<>"e"
               w=1
            EndIf
         EndIf
      Else
         If FindString(line, u, 1)>0: w=1: EndIf
      EndIf
   Next
   If w=0 ; it's just a number
      ProcedureReturn ValD(line)
   Else ; we'll compute it
      w=0 ; now it will be number of brackets
      For q=Len(line) To 1 Step -1 ; FROM RIGHT TO LEFT! For correct recursive calculation.
         u=Mid(line,q,1) ; it is a current symbol
         If u=")": w+1: EndIf
         If u="(": w-1: EndIf
         If w=0 ; if we are between two blocks
            If u="+" And Mid(line,q-1,1)<>"e"
               ProcedureReturn Compute(Left(line,q-1))+compute(Right(line,Len(line)-q))
            EndIf
            If u="-" And Mid(line,q-1,1)<>"e"
               ProcedureReturn Compute(Left(line,q-1))-compute(Right(line,Len(line)-q))
            EndIf
         EndIf
      Next
      For q=Len(line) To 1 Step -1
         u=Mid(line,q,1) ; it is a current symbol
         If u=")": w+1: EndIf
         If u="(": w-1: EndIf
         If w=0 ; if we are between two blocks
            If u="*"
               ProcedureReturn Compute(Left(line,q-1))*|!REG3XP3!>compute(Right(line,Len(line)-q))
            EndIf
            If u="/"
               ProcedureReturn Compute(Left(line,q-1))/compute(Right(line,Len(line)-q))
            EndIf
         EndIf
      Next
      For q=1 To Len(line)
         u=Mid(line,q,1) ; it is a current symbol
         If u="(": w+1: EndIf
         If u=")": w-1: EndIf
         If w=0 ; if we are between two blocks
            If u="^"
               ProcedureReturn Pow(Compute(Left(line,q-1)),compute(Right(line,Len(line)-q)))
            EndIf
         EndIf
      Next
      ; nothing found
      If Left(line,1)="(" And Right(line,1)=")": ProcedureReturn compute(Mid(line,2,Len(line)-2)): EndIf
      If Left(line,2)="-(" And Right(line,1)=")": ProcedureReturn compute(Mid(line,3,Len(line)-3)): EndIf
     
      If Left(line,4)="sin(" And Right(line,1)=")": ProcedureReturn Sin(compute(Mid(line,5,Len(line)-5))): EndIf
      If Left(line,4)="cos(" And Right(line,1)=")": ProcedureReturn Cos(compute(Mid(line,5,Len(line)-5))): EndIf
      If Left(line,3)="tg(" And Right(line,1)=")": ProcedureReturn Tan(compute(Mid(line,4,Len(line)-4))): EndIf
      If Left(line,4)="ctg(" And Right(line,1)=")": ProcedureReturn 1/Tan(compute(Mid(line,5,Len(line)-5))): EndIf
 
      If Left(line,7)="arcsin(" And Right(line,1)=")": ProcedureReturn ASin(compute(Mid(line,8,Len(line)-8))): EndIf
      If Left(line,7)="arccos(" And Right(line,1)=")": ProcedureReturn ACos(compute(Mid(line,8,Len(line)-8))): EndIf
      If Left(line,6)="arctg(" And Right(line,1)=")": ProcedureReturn ATan(compute(Mid(line,7,Len(line)-7))): EndIf
      If Left(line,7)="arcctg(" And Right(line,1)=")": ProcedureReturn #PI/2-ATan(compute(Mid(line,8,Len(line)-8))): EndIf
 
      If Left(line,4)="sqr(" And Right(line,1)=")": ProcedureReturn Sqr(compute(Mid(line,5,Len(line)-5))): EndIf
      If Left(line,4)="abs(" And Right(line,1)=")": ProcedureReturn Abs(compute(Mid(line,5,Len(line)-5))): EndIf
      If Left(line,3)="ln(" And Right(line,1)=")": ProcedureReturn Log(compute(Mid(line,4,Len(line)-4))): EndIf
      If Left(line,3)="lg(" And Right(line,1)=")": ProcedureReturn Log10(compute(Mid(line,4,Len(line)-4))): EndIf
      If Left(line,4)="int(" And Right(line,1)=")": ProcedureReturn integer(compute(Mid(line,5,Len(line)-5))): EndIf
      If Left(line,6)="float(" And Right(line,1)=")": ProcedureReturn flo(compute(Mid(line,7,Len(line)-7))): EndIf
      ;MessageRequester("Ошибка!","Проверьте корректность выражения:"+Chr(10)+Chr(13)+line,#MB_ICONEXCLAMATION)
   EndIf
EndProcedure
DataSection ; symbols
   again:
  Data.s "+", "-", "*", "/", "(", ")", "^"
EndDataSection
Procedure paintwin()
   SetGadgetColor(#button_0,#PB_Gadget_BackColor,cb)
   SetGadgetColor(#button_1,#PB_Gadget_BackColor,ca)
   SetGadgetColor(#button_2,#PB_Gadget_BackColor,cg)
   SetGadgetColor(#button_3,#PB_Gadget_BackColor,cl)
EndProcedure
Procedure.d scrx(x.d)
   ProcedureReturn (x-x1)*(wi-20)/(x2-x1)+10
EndProcedure
Procedure.d scry(y.d)
   ProcedureReturn (y-y2)*(he-20)/(y1-y2)+10
EndProcedure
Procedure.s tostr(s.d)
   Protected l.s
   l=StrD(s)
   While Right(l,1)="0"
      l=Left(l,Len(l)-1)
   Wend
   If l="":l="0":EndIf
   If Right(l,1)=".": l=Left(l,Len(l)-1): EndIf
   ;Debug l
   ProcedureReturn l
EndProcedure
Procedure trace()
   Protected q.d, f.s, x.d, y.d, p1.sp_, p2.sp_, w.b
   x1=ValD(ReplaceString(GetGadgetText(#input_2),",","."))
   x2=ValD(ReplaceString(GetGadgetText(#input_4),",","."))
   y1=ValD(ReplaceString(GetGadgetText(#input_6),",","."))
   y2=ValD(ReplaceString(GetGadgetText(#input_7),",","."))
   x3=ValD(ReplaceString(GetGadgetText(#input_10),",","."))
   y3=ValD(ReplaceString(GetGadgetText(#input_12),",","."))
   f=GetGadgetText(#input_1)
   f=ReplaceString(f,"eu","2.71828182846")
   f=ReplaceString(f,"pi","3.141592653589793")
   
   If GetGadgetState(#check2)=0: w=1: Else: w=3: EndIf
   
   StartDrawing(ImageOutput(0))
      If GetGadgetState(#check1)=0
         Box(0,0,wi,he,cb)
         FrontColor(cg)
         If x3>0
            q=0
            Repeat
               q+x3
               Line(scrx(q),0,0,he)
            Until q>x2
            q=0
            Repeat
               q-x3
               Line(scrx(q),0,0,he)
            Until q<x1
         EndIf
         If y3>0
            q=0
            Repeat
               q+y3
               Line(0,scry(q),wi,0)
            Until q>y2
            q=0
            Repeat
               q-y3
               Line(0,scry(q),wi,0)
            Until q<y1
         EndIf
         FrontColor(ca)
         Line(scrx(0),0,0,he)
         Line(0,scry(0),wi,0)
         DrawingMode(#PB_2DDrawing_Transparent)
         If x3>0
            q=0
            Repeat
               DrawText(scrx(q)+1,scry(0),tostr(q))
               q+x3
            Until q>x2
            q=0
            Repeat
               q-x3
               DrawText(scrx(q)+1,scry(0),tostr(q))
            Until q<x1
         EndIf
         If y3>0
            q=0
            Repeat
               DrawText(scrx(0)+1,scry(q),tostr(q))
               q+y3
            Until q>y2
            q=0
            Repeat
               q-y3
               DrawText(scrx(0)+1,scry(q),tostr(q))
            Until q<y1
         EndIf
      EndIf
      FrontColor(cl)
      q=x1
      While q<=x2 And f<>""
         p2\x=scrx(q)
         p2\y=scry(compute(ReplaceString(f,"x","("+StrD(q)+")")))
         If (p1\x>0 And p1\x<wi And p1\y>0 And p1\y<he) Or (p2\x>0 And p2\x<wi And p2\y>0 And p2\y<he)
            Select w
            Case 1
               If q=x1: Plot(p2\x,p2\y): Else: LineXY(p1\x,p1\y,p2\x,p2\y): EndIf
            Case 3
               If q=x1: Plot(p2\x,p2\y): Else: LineXY(p1\x,p1\y,p2\x,p2\y): EndIf
               If q=x1: Plot(p2\x+1,p2\y): Else: LineXY(p1\x+1,p1\y,p2\x+1,p2\y): EndIf
               If q=x1: Plot(p2\x=1,p2\y): Else: LineXY(p1\x=1,p1\y,p2\x=1,p2\y): EndIf
               If q=x1: Plot(p2\x,p2\y+1): Else: LineXY(p1\x,p1\y+1,p2\x,p2\y+1): EndIf
               If q=x1: Plot(p2\x,p2\y-1): Else: LineXY(p1\x,p1\y-1,p2\x,p2\y-1): EndIf
            EndSelect                  
         EndIf
         p1\x=p2\x
         p1\y=p2\y
         q+1/wi*(x2-x1)
      Wend
      ;Debug 3/we*(x2-x1)
   StopDrawing()
   SetGadgetState(#img,ImageID(0))  
EndProcedure
 
 
OpenWindow(0,100,100,wi,he,"График",#PB_Window_MinimizeGadget|#PB_Window_MaximizeGadget|#PB_Window_SizeGadget)
CreateGadgetList(WindowID(0))
ImageGadget(#img,0,0,wi,he,ImageID(0))
OpenWindow(1,354,359,635,241,"Построение графиков",#PB_Window_MinimizeGadget)
;{ ; its gadgets
   CreateGadgetList(WindowID(1))
   TextGadget(#Text_0, 10, 10, 130, 20, "&Выражение:  f(x) =")
   SetGadgetFont(#Text_0, FontID1)
   StringGadget(#Input_1, 150, 7, 365, 24, "")
   SetGadgetFont(#Input_1, FontID1)
   Frame3DGadget(#Frame3D_0, 10, 40, 505, 100, "Область графика")
   SetGadgetFont(#Frame3D_0, FontID1)
   TextGadget(#Text_1, 25, 68, 40, 20, "X: &от")
   SetGadgetFont(#Text_1, FontID1)
   StringGadget(#Input_2, 70, 65, 110, 24, "-12")
   SetGadgetFont(#Input_2, FontID1)
   TextGadget(#Text_3, 188, 68, 20, 20, "&до")
   SetGadgetFont(#Text_3, FontID1)
   StringGadget(#Input_4, 212, 65, 110, 24, "12")
   SetGadgetFont(#Input_4, FontID1)
   TextGadget(#Text_9, 330, 68, 75, 20, "&шаг сетки")
   SetGadgetFont(#Text_9, FontID1)
   StringGadget(#Input_10, 407, 65, 95, 24, "1")
   SetGadgetFont(#Input_10, FontID1)
   TextGadget(#Text_5, 25, 103, 40, 20, "Y: &от")
   SetGadgetFont(#Text_5, FontID1)
   StringGadget(#Input_6, 70, 100, 110, 24, "-9")
   SetGadgetFont(#Input_6, FontID1)
   TextGadget(#Text_6, 188, 103, 20, 20, "&до")
   SetGadgetFont(#Text_6, FontID1)
   StringGadget(#Input_7, 212, 100, 110, 24, "9")
   SetGadgetFont(#Input_7, FontID1)
   TextGadget(#Text_11, 330, 103, 70, 20, "&шаг сетки")
   SetGadgetFont(#Text_11, FontID1)
   StringGadget(#Input_12, 407, 100, 95, 24, "1")
   SetGadgetFont(#Input_12, FontID1)
   Frame3DGadget(#Frame3D_1, 10, 150, 505, 75, "Вид")
   SetGadgetFont(#Frame3D_1, FontID1)
   ButtonGadget(#Button_0, 30, 175, 95, 30, "Цвет &фона")
   SetGadgetFont(#Button_0, FontID1)
   ButtonGadget(#Button_1, 145, 175, 95, 30, "Цвет о&сей")
   SetGadgetFont(#Button_1, FontID1)
   ButtonGadget(#Button_2, 260, 175, 100, 30, "Цвет се&тки")
   SetGadgetFont(#Button_2, FontID1)
   ButtonGadget(#Button_3, 380, 175, 115, 25, "Цвет &графика")
   SetGadgetFont(#Button_3, FontID1)
   CheckBoxGadget(#check2,390,200,100,20,"Толстая &линия")
   SetGadgetFont(#check2, FontID2)
   ButtonGadget(#Button_4, 530, 155, 95, 30, "Спр&авка")
   SetGadgetFont(#Button_4, FontID1)
   ButtonGadget(#Button_5, 530, 15, 95, 30, "&Построить")
   SetGadgetFont(#Button_5, FontID1)
   CheckBoxGadget(#check1,527,45,100,30,"Пов&ерх старого")
   SetGadgetFont(#check1, FontID2)
   ButtonGadget(#Button_6, 530, 77, 95, 30, "Вы&ход")
   SetGadgetFont(#Button_6, FontID1)
;}
paintwin()
;StickyWindow(1,1)
;ShowWindow_(WindowID(1), #SW_HIDE)
;SetWindowLong_(WindowID(1), #GWL_EXSTYLE, #WS_EX_TOOLWINDOW)
;ShowWindow_(WindowID(1), #SW_SHOW)
 
 
Repeat
   e=WindowEvent()
   If e=#PB_Event_SizeWindow
      SetGadgetState(#check1,0)
      wi=WindowWidth(0)
      he=WindowHeight(0)
      If he<10: he=25: ResizeWindow(0,#PB_Ignore,#PB_Ignore,#PB_Ignore,he): EndIf
      If WindowHeight(0)>24
         CreateImage(0,wi,he)
         trace()
      EndIf
   ElseIf e=#PB_Event_Gadget
      ew=EventWindow()
      eg=EventGadget()
      et=EventType()
     
      If et=#PB_EventType_LeftClick
         If eg=#button_6: End: EndIf
         If eg=#button_0
            c=ColorRequester(cb)
            If c>=0: cb=c: EndIf
            paintwin()
         EndIf
         If eg=#button_1
            c=ColorRequester(ca)
            If c>=0: ca=c: EndIf
            paintwin()
         EndIf
         If eg=#button_2
            c=ColorRequester(cg)
            If c>=0: cg=c: EndIf
            paintwin()
         EndIf
         If eg=#button_3
            c=ColorRequester(cl)
            If c>=0: cl=c: EndIf
            paintwin()
         EndIf
         If eg=#button_4
            MessageRequester("Синтаксис","Поддерживаются алгебраические выражения практически любой сложности."+pp+"Дробные числа можно писать через точку или запятую."+pp+"Ввод порядка через латинскую «e»: 6.02e23;  7,412e-64"+pp+"Отрицательные числа желательно писать в скобках."+pp+pp+"Арифметические действия:"+pp+"+ — сложение"+pp+Chr(150)+" — вычитание"+pp+"* — умножение"+pp+"/ — деление"+pp+"^ — возведение в степень"+pp+pp+"Математические функции:"+pp+"(аргумент обязательно в скобках)"+pp+"sin(x)"+pp+"cos(x)"+pp+"tg(x)"+pp+"ctg(x)"+pp+"arcsin(x)"+pp+"arccos(x)"+pp+"arctg(x)"+pp+"arcctg(x)"+pp+"sqr(x) — квадратный корень"+pp+"abs(x) — модуль"+pp+"ln(x)"+pp+"lg(x)"+pp+"int(x) — целая часть"+pp+"float(x) — дробная часть"+pp+pp+"Можно использовать число «пи» (pi) и число «e» (eu)")
         EndIf
         If eg=#button_5
            trace()
         EndIf
      EndIf
   EndIf
   ;If GetActiveWindow_()=WindowID(0) Or GetActiveWindow_()=WindowID(1): act.b=1: Else: act=0: EndIf
   ;If act=0
   ;   ShowWindow_(WindowID(1), #SW_HIDE)
   ;Else
   ;   ShowWindow_(WindowID(1), #SW_SHOW)
   ;EndIf
   If GetWindowState(0)=#PB_Window_Minimize
      ;HideWindow(1,1)
      SetWindowState(1,#PB_Window_Minimize)
   Else
      ;If GetWindowState(1)<>#PB_Window_Minimize
      ;   HideWindow(1,0)
      ;EndIf
   EndIf
Until e=#PB_Event_CloseWindow
 



Кстати, команда GetActiveWindow_() всегда возвращает 0.

_________________
Loading... 99%


Вернуться наверх
 Профиль  
 
Показать сообщения за:  Сортировать по:  
Начать новую тему Ответить на тему  [ 1 сообщение ] 

Часовой пояс: UTC + 3 часа


Кто сейчас на форуме

Сейчас этот форум просматривают: нет зарегистрированных пользователей и гости: 1


Вы не можете начинать темы
Вы не можете отвечать на сообщения
Вы не можете редактировать свои сообщения
Вы не можете удалять свои сообщения
Вы не можете добавлять вложения

Найти:
Перейти:  
Создано на основе phpBB® Forum Software © phpBB Group (блог о phpBB)
Сборка создана CMSart Studio
Русская поддержка phpBB