purebasic.info

PureBasic forum
Текущее время: Ср окт 24, 2018 3:58 am

Часовой пояс: UTC + 3 часа




Начать новую тему Ответить на тему  [ Сообщений: 7 ] 
Автор Сообщение
 Заголовок сообщения: Windows служба
СообщениеДобавлено: Чт сен 24, 2015 12:14 pm 
Не в сети
профессор
Аватар пользователя

Зарегистрирован: Пн июл 04, 2011 7:38 am
Сообщений: 749
Откуда: Россия
Благодарил (а): 29 раз.
Поблагодарили: 9 раз.
Пункты репутации: 0
Пример службы в виде модуля

v1.0
Код:
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
 
EnableExplicit
 
DeclareModule Service
  Declare.b Install(ServiceName.s, DisplayName.s, Description.s)
  Declare.b Uninstall(ServiceName.s)
  Declare.b Run(ServiceName.s, *lpMainProc, *lpErrorProc)
  Declare.b IsRunning()
  Declare Logs(Message.s)
EndDeclareModule  
 
Module Service
 
  Structure SERVICE_PARAMS
    ServiceName.s
    *MainProc
    *ErrorProc
    CtrlStatus.l
  EndStructure  
 
  Enumeration
    #Log
  EndEnumeration
 
  Global ServiceParams.SERVICE_PARAMS
  Global ServiceStatus.SERVICE_STATUS
 
  Procedure Handler(fdwControl.l)
    Select fdwControl
      Case #SERVICE_CONTROL_INTERROGATE
      Case #SERVICE_CONTROL_STOP
        With ServiceStatus
          \dwWin32ExitCode = 0
          \dwCurrentState = #SERVICE_STOPPED
        EndWith
      Case #SERVICE_CONTROL_SHUTDOWN
        With ServiceStatus
          \dwWin32ExitCode = 0
          \dwCurrentState = #SERVICE_STOPPED
        EndWith
    EndSelect
    If (Not SetServiceStatus_(ServiceParams\CtrlStatus, @ServiceStatus))
      If (ServiceParams\ErrorProc)
        CallFunctionFast(ServiceParams\ErrorProc, GetLastError_())
      EndIf
    EndIf  
  EndProcedure  
 
  Procedure Loop()
   
    ServiceParams\CtrlStatus = RegisterServiceCtrlHandler_(@ServiceParams\ServiceName, @Handler())
    If (Not ServiceParams\CtrlStatus)
      If (ServiceParams\ErrorProc)
        CallFunctionFast(ServiceParams\ErrorProc, GetLastError_())
      EndIf
      ProcedureReturn
    EndIf
   
    ServiceStatus\dwCurrentState = #SERVICE_START_PENDING
    If (Not SetServiceStatus_(ServiceParams\CtrlStatus, @ServiceStatus))
      If (ServiceParams\ErrorProc)
        CallFunctionFast(ServiceParams\ErrorProc, GetLastError_())
      EndIf
    EndIf  
   
    ServiceStatus\dwCurrentState = #SERVICE_RUNNING
    If (Not SetServiceStatus_(ServiceParams\CtrlStatus, @ServiceStatus))
      If (ServiceParams\ErrorProc)
        CallFunctionFast(ServiceParams\ErrorProc, GetLastError_())
      EndIf
    EndIf  
   
    If (ServiceParams\MainProc)
      CallFunctionFast(ServiceParams\MainProc)
    EndIf
 
    ServiceStatus\dwCurrentState = #SERVICE_STOP_PENDING
    If (Not SetServiceStatus_(ServiceParams\CtrlStatus, @ServiceStatus))
      If (ServiceParams\ErrorProc)
        CallFunctionFast(ServiceParams\ErrorProc, GetLastError_())
      EndIf
    EndIf  
 
    ServiceStatus\dwCurrentState = #SERVICE_STOPPED
    If (Not SetServiceStatus_(ServiceParams\CtrlStatus, @ServiceStatus))
      If (ServiceParams\ErrorProc)
        CallFunctionFast(ServiceParams\ErrorProc, GetLastError_())
      EndIf
    EndIf  
   
  EndProcedure  
 
  Procedure.b Install(ServiceName.s, DisplayName.s, Description.s)
    Protected Result.b, hManager.l, hService.l, tSd.SERVICE_DESCRIPTION, BytesNeeded.l
 
    hManager = OpenSCManager_(#Null, #Null, #SC_MANAGER_ALL_ACCESS)
    If hManager
      Define App.s = ProgramFilename()
      hService = CreateService_(hManager, @ServiceName, @DisplayName, #SERVICE_ALL_ACCESS, #SERVICE_WIN32_OWN_PROCESS|#SERVICE_INTERACTIVE_PROCESS, #SERVICE_AUTO_START, #SERVICE_ERROR_NORMAL, @App, #Null, #Null, #Null, #Null, #Null)
      If hService
        tSd\lpDescription = @Description
        If ChangeServiceConfig2_(hService, #SERVICE_CONFIG_DESCRIPTION, @tSd)
          Result = StartService_(hService, #Null, #Null)
          If (GetLastError_() = #ERROR_SERVICE_ALREADY_RUNNING)
            Result = 1
          EndIf
          If (Not Result)
            QueryServiceConfig_(hService, #Null, 0, @BytesNeeded)
            If (GetLastError_() = #ERROR_INSUFFICIENT_BUFFER)
              Define *ServiceConfig.QUERY_SERVICE_CONFIG = AllocateMemory(BytesNeeded)
              If *ServiceConfig
                If QueryServiceConfig_(hService, *ServiceConfig, BytesNeeded, @BytesNeeded)
                  Select *ServiceConfig\dwStartType
                    Case #SERVICE_AUTO_START, #SERVICE_DEMAND_START, #SERVICE_DISABLED
                      If ChangeServiceConfig_(hService, #SERVICE_NO_CHANGE, #SERVICE_DISABLED, #SERVICE_NO_CHANGE, #Null, #Null, #Null, #Null, #Null, #Null, #Null)
                        DeleteService_(hService)
                      EndIf  
                  EndSelect
                EndIf
                FreeMemory(*ServiceConfig)
              EndIf
            EndIf
          EndIf  
        EndIf  
        CloseServiceHandle_(hService)
      EndIf
      CloseServiceHandle_(hManager)
    EndIf
   
    ProcedureReturn Result
 
  EndProcedure
 
  Procedure.b Uninstall(ServiceName.s)
    Protected Result.b, hManager.l, hService.l, lpServiceStatus.SERVICE_STATUS, dService, ServicesReturned.l, BytesNeeded.l
 
    hManager = OpenSCManager_(#Null, #Null, #SC_MANAGER_ALL_ACCESS)
    If hManager
      hService = OpenService_(hManager, @ServiceName, #SERVICE_ALL_ACCESS)
      If hService
       
        ControlService_(hService, #SERVICE_CONTROL_STOP, @lpServiceStatus)
       
        Select GetLastError_()
          Case #ERROR_DEPENDENT_SERVICES_RUNNING
            EnumDependentServices_(hService, #SERVICE_ACTIVE, #Null, 0, @BytesNeeded, @ServicesReturned)
            If GetLastError_() = #ERROR_MORE_DATA
              Dim Services.ENUM_SERVICE_STATUS((BytesNeeded / SizeOf(ENUM_SERVICE_STATUS)) + 1)
              If EnumDependentServices_(hService, #SERVICE_ACTIVE, @Services(0), SizeOf(ENUM_SERVICE_STATUS) * ArraySize(Services()), @BytesNeeded, @ServicesReturned)
                While ServicesReturned
                  If Services(ServicesReturned - 1)\lpServiceName
                    dService = OpenService_(hManager, Services(ServicesReturned - 1)\lpServiceName, #SERVICE_ALL_ACCESS)
                    If dService
                      ControlService_(dService, #SERVICE_CONTROL_STOP, @lpServiceStatus)
                      CloseServiceHandle_(dService)
                    EndIf
                  EndIf
                  ServicesReturned - 1
                Wend
                Delay(1000)
                Result = ControlService_(hService, #SERVICE_CONTROL_STOP, @lpServiceStatus)
              EndIf
              FreeArray(Services())
            EndIf
        EndSelect
       
        QueryServiceConfig_(hService, #Null, 0, @BytesNeeded)
       
        If (GetLastError_() = #ERROR_INSUFFICIENT_BUFFER)
          Define *ServiceConfig.QUERY_SERVICE_CONFIG = AllocateMemory(BytesNeeded)
          If *ServiceConfig
            If QueryServiceConfig_(hService, *ServiceConfig, BytesNeeded, @BytesNeeded)
              Select *ServiceConfig\dwStartType
                Case #SERVICE_AUTO_START, #SERVICE_DEMAND_START, #SERVICE_DISABLED
                  Result = ChangeServiceConfig_(hService, #SERVICE_NO_CHANGE, #SERVICE_DISABLED, #SERVICE_NO_CHANGE, #Null, #Null, #Null, #Null, #Null, #Null, #Null)
              EndSelect
            EndIf
            FreeMemory(*ServiceConfig)
          EndIf
        EndIf
       
        Result = DeleteService_(hService)
       
        CloseServiceHandle_(hService)
      EndIf
      CloseServiceHandle_(hManager)
    EndIf
 
    ProcedureReturn Result
 
  EndProcedure
 
  Procedure.b Run(ServiceName.s, *lpMainProc, *lpErrorProc)
   
    Protected Result.b, Table.SERVICE_TABLE_ENTRY
   
    With ServiceParams
      \ServiceName = ServiceName
      \MainProc = *lpMainProc
      \ErrorProc = *lpErrorProc
    EndWith
   
    With Table
      \lpServiceName = @ServiceName
      \lpServiceProc = @Loop()
    EndWith
   
    With ServiceStatus
      \dwServiceType = #SERVICE_WIN32_OWN_PROCESS|#SERVICE_INTERACTIVE_PROCESS
      \dwControlsAccepted = #SERVICE_ACCEPT_STOP|#SERVICE_ACCEPT_SHUTDOWN
      \dwWin32ExitCode = 0
      \dwServiceSpecificExitCode = 0
      \dwCheckPoint = 0
      \dwWaitHint = 0
    EndWith
   
    Result = StartServiceCtrlDispatcher_(@Table)
    If (Result = #ERROR_SUCCESS)
      If (ServiceParams\ErrorProc)
        CallFunctionFast(ServiceParams\ErrorProc, GetLastError_())
      EndIf
    EndIf
   
    ProcedureReturn Result
   
  EndProcedure
 
  Procedure.b IsRunning()
    If (ServiceStatus\dwCurrentState = #SERVICE_RUNNING)
      ProcedureReturn #True
    EndIf
    ProcedureReturn #False
  EndProcedure
 
  Procedure Logs(Message.s)
    If OpenFile(#Log, ProgramFilename() + ".log")
      FileSeek(#Log, Lof(#Log))
      WriteStringN(#Log, FormatDate("%yyyy/%mm/%dd %hh:%ii:%ss", Date()) + " [" + Str(GetCurrentProcessId_()) + "] >> " + Message)
      CloseFile(#Log)
    EndIf
  EndProcedure
 
EndModule
 
Global ServiceName.s = "pbService"
Global DisplayName.s = "pbService"
Global Description.s = "Тестирование службы на PureBasic"
 
Procedure ServiceMain()
 
  Define flag.b = #True
 
  While Service::IsRunning()
    If flag
      Service::Logs("CPU Name: " + CPUName())
      Service::Logs("CPU Count: " + Str(CountCPUs(#PB_System_CPUs)))
      Service::Logs("Computer name: " + ComputerName())
      Service::Logs("User name: " + UserName())
      flag = #False
    EndIf
    Delay(1000)
  Wend
 
EndProcedure
 
Procedure ServiceError(Code.l)
  Service::Logs("Error code service: " + StrU(Code, #PB_Word))
EndProcedure
 
Select ProgramParameter(0)
  Case "-i"
    If (Not Service::Install(ServiceName, DisplayName, Description))
      Service::Logs("Service error install")
    EndIf  
  Case "-d"
    If (Not Service::Uninstall(ServiceName))
      Service::Logs("Service error removed")
    EndIf  
  Default
    If (Not Service::Run(ServiceName, @ServiceMain(), @ServiceError()))
      Service::Logs("Service error started")
    EndIf  
EndSelect
 



v2.0
Код:
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
 
EnableExplicit
 
DeclareModule Service
 
  Enumeration
    #RUNNING
    #PAUSED
    #STOPPED
  EndEnumeration  
 
  Declare.b Initialize(ServiceName.s, DisplayName.s, Description.s)
  Declare.b Install()
  Declare.b Uninstall()
  Declare.b Run(*lpMainProc)
  Declare.l Event()
  Declare Logs(Message.s)
 
EndDeclareModule
 
Module Service
 
  Structure SERVICE
    ServiceName.s
    DisplayName.s
    Description.s
    Initialize.b
    CtrlHandler.l
    *MainProc
  EndStructure
 
  ;- Глобальные переменные
 
  Global App.s = ProgramFilename()
 
  Global service.SERVICE
  Global status.SERVICE_STATUS
 
  Procedure ControlHandler(Control.l)
    Select Control
      Case #SERVICE_CONTROL_INTERROGATE
      Case #SERVICE_CONTROL_CONTINUE
        With status
          \dwWin32ExitCode = 0
          \dwCurrentState = #SERVICE_RUNNING
        EndWith    
      Case #SERVICE_CONTROL_PAUSE
        With status
          \dwWin32ExitCode = 0
          \dwCurrentState = #SERVICE_PAUSED
        EndWith  
      Case #SERVICE_CONTROL_STOP
        With status
          \dwWin32ExitCode = 0
          \dwCurrentState = #SERVICE_STOPPED
        EndWith
      Case #SERVICE_CONTROL_SHUTDOWN
        With status
          \dwWin32ExitCode = 0
          \dwCurrentState = #SERVICE_STOPPED
        EndWith
    EndSelect
    SetServiceStatus_(service\CtrlHandler, @status)
  EndProcedure
 
  Procedure MainHandler()
   
    service\CtrlHandler = RegisterServiceCtrlHandler_(@service\ServiceName, @ControlHandler())
    If (service\CtrlHandler)
      status\dwCurrentState = #SERVICE_START_PENDING
      SetServiceStatus_(service\CtrlHandler, @status)
      status\dwCurrentState = #SERVICE_RUNNING
      SetServiceStatus_(service\CtrlHandler, @status)
      If service\MainProc
        CallFunctionFast(service\MainProc)
      EndIf  
      status\dwCurrentState = #SERVICE_STOP_PENDING
      SetServiceStatus_(service\CtrlHandler, @status)
      status\dwCurrentState = #SERVICE_STOPPED
      SetServiceStatus_(service\CtrlHandler, @status)
    EndIf
   
  EndProcedure  
 
  Procedure.b Initialize(ServiceName.s, DisplayName.s, Description.s)
    If (Len(ServiceName) And Len(DisplayName) And Len(Description))
      With service
        \ServiceName = ServiceName
        \DisplayName = DisplayName
        \Description = Description
        \Initialize = #True
      EndWith
    EndIf
    ProcedureReturn service\Initialize
  EndProcedure  
 
  Procedure.b Install()
   
    Protected bResult.b, hManager.l, hService.l, description.SERVICE_DESCRIPTION, Bytes.l
   
    If (service\Initialize)
      hManager = OpenSCManager_(#Null, #Null, #SC_MANAGER_ALL_ACCESS)
      If hManager
        hService = CreateService_(hManager, @service\ServiceName, @service\DisplayName, #SERVICE_ALL_ACCESS, #SERVICE_WIN32_OWN_PROCESS|#SERVICE_INTERACTIVE_PROCESS, #SERVICE_AUTO_START, #SERVICE_ERROR_NORMAL, @App, #Null, #Null, #Null, #Null, #Null)
        If hService
          description\lpDescription = @service\Description
          If ChangeServiceConfig2_(hService, #SERVICE_CONFIG_DESCRIPTION, @description)
            bResult = StartService_(hService, #Null, #Null)
            If (bResult Or (GetLastError_() = #ERROR_SERVICE_ALREADY_RUNNING))
              bResult = #True
            Else
             
              ;~ Удаление
              QueryServiceConfig_(hService, #Null, 0, @Bytes)
              If (GetLastError_() = #ERROR_INSUFFICIENT_BUFFER)
                Define *config.QUERY_SERVICE_CONFIG = AllocateMemory(Bytes)
                If *config
                  If QueryServiceConfig_(hService, *config, Bytes, @Bytes)
                    Select *config\dwStartType
                      Case #SERVICE_AUTO_START, #SERVICE_DEMAND_START, #SERVICE_DISABLED
                        If ChangeServiceConfig_(hService, #SERVICE_NO_CHANGE, #SERVICE_DISABLED, #SERVICE_NO_CHANGE, #Null, #Null, #Null, #Null, #Null, #Null, #Null)
                          DeleteService_(hService)
                        EndIf  
                    EndSelect    
                  EndIf  
                  FreeMemory(*config)
                EndIf  
              EndIf  
             
            EndIf
          EndIf  
          CloseServiceHandle_(hService)
        EndIf  
        CloseServiceHandle_(hManager)
      EndIf  
    EndIf
    ProcedureReturn bResult
   
  EndProcedure  
 
  Procedure.b Uninstall()
   
    Protected bResult.b, hManager.l, hService.l, status.SERVICE_STATUS, Bytes.l, Returned.l, hOpen.l
   
    If service\Initialize
      hManager = OpenSCManager_(#Null, #Null, #SC_MANAGER_ALL_ACCESS)
      If hManager
        hService = OpenService_(hManager, @service\ServiceName, #SERVICE_ALL_ACCESS)
        If hService
         
          ;~ Остановка сервиса перед удалением, если он запущен
          ControlService_(hService, #SERVICE_CONTROL_STOP, @status)
          Select GetLastError_()
            Case #ERROR_DEPENDENT_SERVICES_RUNNING
              EnumDependentServices_(hService, #SERVICE_ACTIVE, #Null, 0, @Bytes, @Returned)
              If (GetLastError_() = #ERROR_MORE_DATA)
                Dim services.ENUM_SERVICE_STATUS((Bytes / SizeOf(ENUM_SERVICE_STATUS)) + 1)
                If EnumDependentServices_(hService, #SERVICE_ACTIVE, @services(0), (SizeOf(ENUM_SERVICE_STATUS) * ArraySize(Services())), @Bytes, @Returned)
                  While Returned
                    If services(Returned - 1)\lpServiceName
                      hOpen = OpenService_(hManager, Services(Returned - 1)\lpServiceName, #SERVICE_ALL_ACCESS)
                      If hOpen
                        ControlService_(hOpen, #SERVICE_CONTROL_STOP, @status)
                        CloseServiceHandle_(hOpen)
                      EndIf
                    EndIf  
                  Wend
                EndIf
                FreeArray(services())
              EndIf  
          EndSelect
         
          ;~ Удаление из автозагрузки
          QueryServiceConfig_(hService, #Null, 0, @Bytes)
          If (GetLastError_() = #ERROR_INSUFFICIENT_BUFFER)
            Define *config.QUERY_SERVICE_CONFIG = AllocateMemory(Bytes)
            If *config
              If QueryServiceConfig_(hService, *config, Bytes, @Bytes)
                Select *config\dwStartType
                  Case #SERVICE_AUTO_START, #SERVICE_DEMAND_START, #SERVICE_DISABLED
                    bResult = ChangeServiceConfig_(hService, #SERVICE_NO_CHANGE, #SERVICE_DISABLED, #SERVICE_NO_CHANGE, #Null, #Null, #Null, #Null, #Null, #Null, #Null)
                EndSelect    
              EndIf
              FreeMemory(*config)
            EndIf  
          EndIf  
         
          bResult = DeleteService_(hService)
         
          CloseServiceHandle_(hService)
        EndIf  
        CloseServiceHandle_(hManager)
      EndIf  
    EndIf  
    ProcedureReturn bResult
   
  EndProcedure  
 
  Procedure.b Run(*lpMainProc)
   
    Protected bResult.b, table.SERVICE_TABLE_ENTRY
   
    If (service\Initialize)
     
      service\MainProc = *lpMainProc
     
      With table
        \lpServiceName = @service\ServiceName
        \lpServiceProc = @MainHandler()
      EndWith
     
      With status
        \dwServiceType = #SERVICE_WIN32_OWN_PROCESS|#SERVICE_INTERACTIVE_PROCESS
        \dwControlsAccepted = #SERVICE_ACCEPT_PAUSE_CONTINUE|#SERVICE_ACCEPT_STOP|#SERVICE_ACCEPT_SHUTDOWN
        \dwWin32ExitCode = 0
        \dwServiceSpecificExitCode = 0
        \dwCheckPoint = 0
        \dwWaitHint = 0
      EndWith
     
      bResult = StartServiceCtrlDispatcher_(@table)
     
    EndIf  
   
    ProcedureReturn bResult
   
  EndProcedure  
 
  Procedure.l Event()
   
    Protected Result.l
   
    Select status\dwCurrentState
      Case #SERVICE_RUNNING
        Result = #RUNNING
      Case #SERVICE_PAUSED
        Result = #PAUSED
      Case #SERVICE_STOPPED
        Result = #STOPPED
      Default
        Result = status\dwCurrentState
    EndSelect    
   
    ProcedureReturn Result
   
  EndProcedure  
 
  Procedure Logs(Message.s)
   
    Protected hFile.l = OpenFile(#PB_Any, App + ".log")
   
    If hFile
      FileSeek(hFile, Lof(hFile))
      WriteStringN(hFile, FormatDate("%yyyy/%mm/%dd %hh:%ii:%ss", Date()) + " [" + Str(GetCurrentProcessId_()) + "] >> " + Message)
      CloseFile(hFile)
    EndIf
  EndProcedure
 
EndModule
 
 
Procedure ServiceMain()
 
  Define flag = #True
 
  Repeat
    Select Service::Event()
      Case Service::#RUNNING
        If (flag)
          Service::Logs("Service start")
          flag = #False
        EndIf  
      Case Service::#PAUSED
        Service::Logs("Service pause")
      Case Service::#STOPPED
        Service::Logs("Service stop")
        Break
    EndSelect
  ForEver
 
EndProcedure  
 
If Service::Initialize("pbService", "pbService", "Тестирование службы на PureBasic")
  Select ProgramParameter(0)
    Case "-i"
      If (Not Service::Install())
        Service::Logs("Service error install")
      EndIf  
    Case "-d"
      If (Not Service::Uninstall())
        Service::Logs("Service error removed")
      EndIf
    Default
      If (Not Service::Run(@ServiceMain()))
        Service::Logs("Service error started")
      EndIf
  EndSelect    
EndIf  
 




Установка/Удаление
Скомпилировать код, запустить полученный exe от имени администратора с параметром "-i" для установки (запуск сервиса произойдет автоматически при успешной установке), открыть диспетчер задач, перейти на вкладку "Службы", должна появиться служба с именем pbService. Для удаления службы, запустить полученный exe от имени администратора с параметром "-d"


Если есть какие - то замечания и комментарии, пишите, я очень мало знаю про службы :D

_________________
medium.com/@afonichev.dev


Последний раз редактировалось SergeyA Пт сен 25, 2015 9:59 pm, всего редактировалось 6 раз(а).

Вернуться наверх
 Профиль  
 
 Заголовок сообщения: Re: Windows служба
СообщениеДобавлено: Пт сен 25, 2015 6:52 pm 
Не в сети
профессор
Аватар пользователя

Зарегистрирован: Пн июл 04, 2011 7:38 am
Сообщений: 749
Откуда: Россия
Благодарил (а): 29 раз.
Поблагодарили: 9 раз.
Пункты репутации: 0
Может кто знает, как сделать общение службы с внешним миром, про файлы и пайпы знаю, как ещё можно?

_________________
medium.com/@afonichev.dev


Вернуться наверх
 Профиль  
 
 Заголовок сообщения: Re: Windows служба
СообщениеДобавлено: Пт сен 25, 2015 7:05 pm 
Не в сети
доцент
Аватар пользователя

Зарегистрирован: Сб сен 20, 2014 7:08 pm
Сообщений: 37
Благодарил (а): 2 раз.
Поблагодарили: 3 раз.
Пункты репутации: 0
Как проверить работу службы, как ее запустить?


Вернуться наверх
 Профиль  
 
 Заголовок сообщения: Re: Windows служба
СообщениеДобавлено: Пт сен 25, 2015 7:15 pm 
Не в сети
профессор
Аватар пользователя

Зарегистрирован: Пн июл 04, 2011 7:38 am
Сообщений: 749
Откуда: Россия
Благодарил (а): 29 раз.
Поблагодарили: 9 раз.
Пункты репутации: 0
Скомпилировать код, запустить полученный exe от имени администратора с параметром "-i" для установки, открыть диспетчер задач, перейти на вкладку "Службы", должна появиться служба с именем pbService, рядом с exe появится файл с данными

Код:
1
2
3
4
5
6
 
Service::Logs("CPU Name: " + CPUName())
Service::Logs("CPU Count: " + Str(CountCPUs(#PB_System_CPUs)))
Service::Logs("Computer name: " + ComputerName())
Service::Logs("User name: " + UserName())
 



Для удаления службы, запустить полученный exe от имени администратора с параметром "-d"

_________________
medium.com/@afonichev.dev


Вернуться наверх
 Профиль  
 
 Заголовок сообщения: Re: Windows служба
СообщениеДобавлено: Пт сен 25, 2015 7:18 pm 
Не в сети
профессор
Аватар пользователя

Зарегистрирован: Пн июл 04, 2011 7:38 am
Сообщений: 749
Откуда: Россия
Благодарил (а): 29 раз.
Поблагодарили: 9 раз.
Пункты репутации: 0
В принципе можно организовать обмен данными через стандартную PureBasic библиотеку Network по локале.

_________________
medium.com/@afonichev.dev


Вернуться наверх
 Профиль  
 
 Заголовок сообщения: Re: Windows служба
СообщениеДобавлено: Пт сен 25, 2015 7:20 pm 
Не в сети
доцент
Аватар пользователя

Зарегистрирован: Сб сен 20, 2014 7:08 pm
Сообщений: 37
Благодарил (а): 2 раз.
Поблагодарили: 3 раз.
Пункты репутации: 0
Спасибо. Работает. Полезный пост!


Вернуться наверх
 Профиль  
 
 Заголовок сообщения: Re: Windows служба
СообщениеДобавлено: Пт сен 25, 2015 10:01 pm 
Не в сети
профессор
Аватар пользователя

Зарегистрирован: Пн июл 04, 2011 7:38 am
Сообщений: 749
Откуда: Россия
Благодарил (а): 29 раз.
Поблагодарили: 9 раз.
Пункты репутации: 0
Добавил v2.0 с отловом статуса службы

P.S. статус PAUSED сработает в случае если Вы явно отправите команду SERVICE_CONTROL_PAUSE через WinAPI функцию ControlService, события RUNNING и STOPPED можно получить, если в диспетчере задач на вкладке "Службы" запустить или остановить свою службу, или так же через ControlService, помимо этого через ControlService с помощью флага SERVICE_USER_DEFINED_CONTROL можно отправлять пользовательские коды в интервале от 128 до 255, тем самым управляя работой службы.

_________________
medium.com/@afonichev.dev


Вернуться наверх
 Профиль  
 
Показать сообщения за:  Сортировать по:  
Начать новую тему Ответить на тему  [ Сообщений: 7 ] 

Часовой пояс: UTC + 3 часа


Кто сейчас на форуме

Сейчас этот форум просматривают: нет зарегистрированных пользователей и гости: 4


Вы не можете начинать темы
Вы не можете отвечать на сообщения
Вы не можете редактировать свои сообщения
Вы не можете удалять свои сообщения
Вы не можете добавлять вложения

Найти:
Перейти:  
Создано на основе phpBB® Forum Software © phpBB Group (блог о phpBB)
Сборка создана CMSart Studio
Русская поддержка phpBB