purebasic.info

PureBasic forum
Текущее время: Пт окт 19, 2018 8:00 am

Часовой пояс: UTC + 3 часа




Начать новую тему Ответить на тему  [ Сообщений: 23 ]  На страницу Пред.  1, 2
Автор Сообщение
 Заголовок сообщения: Screenshot активного окна
СообщениеДобавлено: Пн фев 06, 2012 8:03 pm 
Не в сети
МОДЕРАТОР

Зарегистрирован: Вт дек 05, 2006 8:46 am
Сообщений: 6384
Благодарил (а): 20 раз.
Поблагодарили: 198 раз.
Пункты репутации: 48
Screenshot активного окна

Код:
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
UseJPEGImageEncoder()
 
Procedure MakeScreenshotForegroundWindow()
    hWnd=GetForegroundWindow_()
    GetWindowRect_(hWnd, WindowSize.RECT)
    Width=WindowSize\Right - WindowSize\Left
    Height=WindowSize\Bottom - WindowSize\Top
    hImage = CreateImage(#PB_Any,Width,Height)
    hDC    = StartDrawing(ImageOutput(hImage))
    WndDC  = GetWindowDC_(hWnd)
    BitBlt_(hDC,0,0,Width,Height,WndDC,0,0,#SRCCOPY)
    StopDrawing()
    ReleaseDC_(hWnd,WndDC)
    ProcedureReturn hImage
  EndProcedure
 
 
SaveImage(MakeScreenshotForegroundWindow(), "C:\image0.jpg",#PB_ImagePlugin_JPEG )
 



При помощи Droopy:
Код:
1
2
CaptureWindow(GetForegroundWindow_())
   SaveCapture("C:\image0.jpg",#PB_ImagePlugin_JPEG,8)


_________________
read-only


Вернуться наверх
 Профиль  
 
 Заголовок сообщения:
СообщениеДобавлено: Чт май 03, 2012 9:23 am 
Не в сети
МОДЕРАТОР

Зарегистрирован: Вт дек 05, 2006 8:46 am
Сообщений: 6384
Благодарил (а): 20 раз.
Поблагодарили: 198 раз.
Пункты репутации: 48
Получаем сведения о гаджетах
Код:
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Procedure ListWindows(hwnd,Param)
  Protected String$
  Protected String2$
  String$ = Space(250)
  String2$ = Space(1024)
  GetWindowText_(hwnd,String$,250)
  GetClassName_(hwnd,@String2$,Len(String2$))
  Debug "Handle Gadget: "+Str(hwnd)
  Debug "PureBasic-Number Gadget: "+Str(GetProp_(hwnd, "PB_ID"))
  Debug "ClassName Gadget: "+String2$
  Debug "Text on Gadget: "+String$
  Debug "--------------------------------------------------------------------"
  ProcedureReturn #True
EndProcedure
 
If OpenWindow(0,0,0,500,400,"Window",#PB_Window_SystemMenu|#PB_Window_ScreenCentered)
  ButtonGadget(1,10,10,100,20,"Hallo Button",0)
  StringGadget(2,120,10,100,20,"Hallo Edit",0)
  ListViewGadget(3,10,40,100,100,0)
  EnumChildWindows_(WindowID(0),@ListWindows(),0)
  Repeat
    EventID=WaitWindowEvent()
    If EventID = #PB_Event_CloseWindow
      End
    EndIf
  ForEver
EndIf
 



Узнаем путь до собственного исполняемого файла
Код:
1
2
3
4
5
6
7
 
Define lpBuffer = AllocateMemory(255)
If OpenWindow(0,0,0,500,400,"Window",#PB_Window_SystemMenu|#PB_Window_ScreenCentered)
  GetWindowModuleFileName_(WindowID(0),lpBuffer,255)
  MessageRequester("","Pfad: "+PeekS(lpBuffer),0)
Repeat : Until WaitWindowEvent() = #PB_Event_CloseWindow
EndIf



Активируем Драг энд Дроп

Код:
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
 
Buffer = AllocateMemory(1000)
If OpenWindow(0,0,0,500,250,"Window",#PB_Window_SystemMenu|#PB_Window_ScreenCentered)
DragAcceptFiles_(WindowID(0),#True)
Repeat
EventID=WaitWindowEvent()
Select EventID
  Case #WM_DROPFILES
    DragQueryFile_(EventwParam(),0,Buffer,1000)
    Debug PeekS(Buffer)
EndSelect
If EventID=#PB_Event_CloseWindow
  Quit=1
EndIf
Until Quit=1
EndIf




Узнаем скрыто окно или нет

Код:
1
2
3
4
5
6
7
8
9
10
 
If OpenWindow(0,0,0,500,250,"Window",#PB_Window_SystemMenu|#PB_Window_ScreenCentered)
  HideWindow(0,0)
  If IsWindowVisible_(WindowID(0))=1
    MessageRequester("","Окно не скрыто.",0)
  Else
    MessageRequester("","Окно скрыто.",0)
  EndIf
Repeat : Until WaitWindowEvent() = #PB_Event_CloseWindow
EndIf



Узнаем, есть ли у окна рамка

Код:
1
2
3
4
5
6
7
8
9
10
11
 
;If OpenWindow(0,0,0,500,250,"Window",#PB_Window_SystemMenu|#PB_Window_ScreenCentered)
If OpenWindow(0,0,0,500,250,"Window",#PB_Window_BorderLess|#PB_Window_ScreenCentered)
  If GetWindowLongPtr_(WindowID(0),#GWL_STYLE)&#WS_BORDER
    MessageRequester("","Рамка: Есть",0)
  Else
    MessageRequester("","Рамка: Нет",0)
  EndIf
  End
Repeat : Until WaitWindowEvent() = #PB_Event_CloseWindow
EndIf



Позиция и размер окна. Сохранить и восстановить

Код:
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
 
Define hWndPM.WINDOWPLACEMENT
If OpenWindow(0,0,0,500,400,"Window",#PB_Window_SystemMenu|#PB_Window_ScreenCentered|#PB_Window_MinimizeGadget|#PB_Window_MaximizeGadget|#PB_Window_SizeGadget)
  ButtonGadget(1,10,10,200,20, "1. Запомнить позицию и размер окна",0)
  TextGadget(2,10,40,480,20,   "2. Измените позицию и размер окна.",0)
  ButtonGadget(3,10,60,200,20, "3. Восстановить позицию и размер окна",0)
  Repeat
    EventID=WaitWindowEvent()
    If EventID=#PB_Event_Gadget
      Select EventGadget()
        Case 1
          GetWindowPlacement_(WindowID(0),hWndPM)
        Case 3
          SetWindowPlacement_(WindowID(0),hWndPM)
      EndSelect
    EndIf
    If EventID = #PB_Event_CloseWindow
      End
    EndIf
  ForEver
EndIf
 



Окно без рамок
Код:
1
2
3
4
5
6
7
 
 
If OpenWindow(0,0,0,500,250,"Window",#PB_Window_SystemMenu|#PB_Window_ScreenCentered)
  SetWindowLongPtr_(WindowID(0),#GWL_STYLE,GetWindowLongPtr_(WindowID(0),#GWL_STYLE)&~#WS_DLGFRAME)
Repeat : Until WaitWindowEvent() = #PB_Event_CloseWindow
EndIf
 



Установить картинку фоном окна

Код:
1
2
3
4
5
6
7
8
 
bgimage = LoadImage(#PB_Any,"C:\Картинка.bmp")   ; Изменить!!!
If OpenWindow(0,0,0,500,250,"Window",#PB_Window_SystemMenu|#PB_Window_ScreenCentered)
  hBrush = CreatePatternBrush_(ImageID(bgimage))
  SetClassLong_(WindowID(0), #GCL_HBRBACKGROUND, hBrush)
  InvalidateRect_(WindowID(0), #Null, #True)
Repeat : Until WaitWindowEvent() = #PB_Event_CloseWindow
EndIf



Окно в стиле славных Win 95

Код:
1
2
3
4
5
6
 
SetThemeAppProperties_(0)
If OpenWindow(0,0,0,500,250,"Window",#PB_Window_SystemMenu|#PB_Window_ScreenCentered)
   Repeat : Until WaitWindowEvent() = #PB_Event_CloseWindow
EndIf
 



Не пускаем курсор за пределы окна
Код:
1
2
3
4
5
6
7
 
If OpenWindow(0,0,0,500,250,"Window",#PB_Window_SystemMenu|#PB_Window_ScreenCentered)
  GetWindowRect_(WindowID(0),r.rect)
  ClipCursor_(r)
Repeat : Until WaitWindowEvent() = #PB_Event_CloseWindow
EndIf
 



Дезактивировать кнопку Maximize

Код:
1
2
3
4
5
6
7
 
If OpenWindow(0,0,0,500,250,"Window",#PB_Window_SystemMenu|#PB_Window_MinimizeGadget|#PB_Window_MaximizeGadget|#PB_Window_ScreenCentered|#PB_Window_Invisible)
  SetWindowLongPtr_(WindowID(0),#GWL_STYLE,GetWindowLongPtr_(WindowID(0),#GWL_STYLE)!#WS_MAXIMIZEBOX)
  HideWindow(0,0)
Repeat : Until WaitWindowEvent() = #PB_Event_CloseWindow
EndIf
 



Удалить кнопку Maximize

Код:
1
2
3
4
5
6
 
If OpenWindow(0,0,0,500,250,"Window",#PB_Window_SystemMenu|#PB_Window_ScreenCentered|#PB_Window_MaximizeGadget)
  SetWindowLongPtr_(WindowID(0),#GWL_STYLE,GetWindowLongPtr_(WindowID(0),#GWL_STYLE)&(#WS_MAXIMIZEBOX!-1))
  SetWindowPos_(WindowID(0),0,0,0,0,0,#SWP_NOSIZE|#SWP_NOMOVE|#SWP_NOZORDER|#SWP_FRAMECHANGED)
Repeat : Until WaitWindowEvent() = #PB_Event_CloseWindow
EndIf



Добавить кнопку Maximize\Minimize

Код:
1
2
3
4
5
6
7
 
If OpenWindow(0,0,0,500,250,"Window",#PB_Window_SystemMenu|#PB_Window_ScreenCentered)
  SetWindowLongPtr_(WindowID(0),#GWL_STYLE,GetWindowLongPtr_(WindowID(0),#GWL_STYLE)|#WS_MAXIMIZEBOX)
  SetWindowPos_(WindowID(0),0,0,0,0,0,#SWP_NOSIZE|#SWP_NOMOVE|#SWP_NOZORDER|#SWP_FRAMECHANGED)
Repeat : Until WaitWindowEvent() = #PB_Event_CloseWindow
EndIf
 



Узнаем PID своего процесса


Код:
1
2
3
4
5
6
7
Define PID
If OpenWindow(0,0,0,500,250,"Window",#PB_Window_SystemMenu|#PB_Window_ScreenCentered)
  GetWindowThreadProcessId_(WindowID(0),@PID)
  MessageRequester("","PID: "+Str(PID),0)
Repeat : Until WaitWindowEvent() = #PB_Event_CloseWindow
EndIf
 



Ещё один способ
Код:
1
Debug GetCurrentProcessId_()



Добавляем пункт в SystemMenu

Код:
1
2
3
4
5
 
If OpenWindow(0,0,0,500,250,"Window",#PB_Window_SystemMenu|#PB_Window_ScreenCentered)
  AppendMenu_(GetSystemMenu_(WindowID(0),#False),#MF_STRING,1,"Teststing")
Repeat : Until WaitWindowEvent() = #PB_Event_CloseWindow
EndIf



Удаляем кнопку программы с панели задач


Код:
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
Procedure HideFromTaskBar(hWnd.l, Flag.l)
  Protected TBL.ITaskbarList
  CoInitialize_(0)
  If CoCreateInstance_(?CLSID_TaskBarList, 0, 1, ?IID_ITaskBarList, @TBL) = #S_OK
    TBL\HrInit()
    If Flag
      TBL\DeleteTab(hWnd)
    Else
      TBL\AddTab(hWnd)
    EndIf
    TBL\Release()
  EndIf
  CoUninitialize_()
 
  DataSection
    CLSID_TaskBarList:
   Data.l $56FDF344
    Data.w $FD6D, $11D0
    Data.b $95, $8A, $00, $60, $97, $C9, $A0, $90
    IID_ITaskBarList:
   Data.l $56FDF342
    Data.w $FD6D, $11D0
    Data.b $95, $8A, $00, $60, $97, $C9, $A0, $90
  EndDataSection
EndProcedure
If OpenWindow(0,0,0,500,250,"Window",#PB_Window_SystemMenu|#PB_Window_ScreenCentered)
  HideFromTaskBar(WindowID(0),1)
Repeat : Until WaitWindowEvent() = #PB_Event_CloseWindow
EndIf
 



Из SystemMenu удаляем пункт "Выход"

Код:
1
2
3
4
5
6
7
8
9
10
11
12
13
If OpenWindow(0,0,0,500,250,"Window",#PB_Window_SystemMenu|#PB_Window_ScreenCentered|#PB_Window_Invisible)
   DeleteMenu_(GetSystemMenu_(WindowID(0),#False),6,#MF_BYPOSITION)
  HideWindow(0,0)
 
 
;TOOLWINDOW
If OpenWindow(0,0,0,500,250,"Window",#PB_Window_SystemMenu|#PB_Window_ScreenCentered|#PB_Window_Invisible)
  SetWindowLongPtr_(WindowID(0),-20,GetWindowLongPtr_(WindowID(0),-20)|#WS_EX_TOOLWINDOW)
  HideWindow(0, 0)
Repeat : Until WaitWindowEvent() = #PB_Event_CloseWindow
EndIf
Repeat : Until WaitWindowEvent() = #PB_Event_CloseWindow
EndIf



Запрещаем таскать окно за заголовок
Код:
1
2
3
4
5
 
If OpenWindow(0,0,0,500,250,"Window",#PB_Window_SystemMenu|#PB_Window_ScreenCentered)
  DeleteMenu_(GetSystemMenu_(WindowID(0),#False),1,#MF_BYPOSITION)
Repeat : Until WaitWindowEvent() = #PB_Event_CloseWindow
EndIf



Материал предоставил pablov

_________________
read-only


Последний раз редактировалось kvitaliy Вт сен 04, 2012 8:09 pm, всего редактировалось 1 раз.

Вернуться наверх
 Профиль  
 
СообщениеДобавлено: Вс авг 12, 2012 5:32 pm 
Не в сети
МОДЕРАТОР

Зарегистрирован: Вт дек 05, 2006 8:46 am
Сообщений: 6384
Благодарил (а): 20 раз.
Поблагодарили: 198 раз.
Пункты репутации: 48
Восстановление иконки в трее после перезапуска explorer.exe

Код:
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
EnableExplicit
 
Enumeration
  #window
  #icon
  #icon_image
EndEnumeration
 
#window_w = 320
#window_h = 60
#window_title = "My Window"
 
#icon_file = "path_to_ico.ico"
 
Define taskbarrestart.i
 
Procedure MyWindowCallback(WindowID, Message, wParam, lParam)
  Shared taskbarrestart
  If Message = taskbarrestart
      AddSysTrayIcon(#icon, WindowID(#window), ImageID(#icon_image))
  EndIf
  ProcedureReturn #PB_ProcessPureBasicEvents
EndProcedure
 
If OpenWindow(#window, #PB_Ignore, #PB_Ignore, #window_w, #window_h, #window_title, #PB_Window_ScreenCentered | #PB_Window_SystemMenu) And LoadImage(#icon_image, #icon_file)
 
  taskbarrestart = RegisterWindowMessage_("TaskbarCreated")
  AddSysTrayIcon(#icon, WindowID(#window), ImageID(#icon_image))
  SetWindowCallback(@MyWindowCallback(), #window)
 
  Repeat
    Select WaitWindowEvent()
      Case #PB_Event_CloseWindow
        Break
    EndSelect
  ForEver
EndIf



Предоставил qpAHToMAS

_________________
read-only


Последний раз редактировалось kvitaliy Пн дек 10, 2012 7:05 am, всего редактировалось 1 раз.

Вернуться наверх
 Профиль  
 
СообщениеДобавлено: Пт авг 17, 2012 12:22 pm 
Не в сети
МОДЕРАТОР

Зарегистрирован: Вт дек 05, 2006 8:46 am
Сообщений: 6384
Благодарил (а): 20 раз.
Поблагодарили: 198 раз.
Пункты репутации: 48
Отключить стиль XP для нужного гаджета (контрола)
Код:
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
If OpenWindow(0, 0, 0, 222, 80, "ButtonGadgets", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
   hFB1 = ButtonGadget(0, 10, 10, 200, 25, "FLAT Button 1")
   hFB2 = ButtonGadget(1, 10, 40, 200, 25, "FLAT Button 2")
   
   SetWindowLong_(hFB1, #GWL_EXSTYLE, GetWindowLong_(hFB1, #GWL_EXSTYLE) | #WS_EX_CLIENTEDGE)
   SetWindowPos_(hFB1, 0, 0, 0, 0, 0, #SWP_NOMOVE | #SWP_NOSIZE | #SWP_NOZORDER | #SWP_FRAMECHANGED)
   
   SetWindowLong_(hFB2, #GWL_EXSTYLE, GetWindowLong_(hFB2, #GWL_EXSTYLE) | #WS_EX_CLIENTEDGE)
   SetWindowPos_(hFB2, 0, 0, 0, 0, 0, #SWP_NOMOVE | #SWP_NOSIZE | #SWP_NOZORDER | #SWP_FRAMECHANGED)
   ;**************************************
   SetWindowTheme_(GadgetID(0), @"", @"") ; отключаем тему у кнопки
   SetWindowTheme_(GadgetID(1), @"", @"") ; отключаем тему у кнопки
   ;**************************************
   Repeat : Until WaitWindowEvent() = #PB_Event_CloseWindow
 EndIf


_________________
read-only


Вернуться наверх
 Профиль  
 
 Заголовок сообщения: ToolBar
СообщениеДобавлено: Сб дек 08, 2012 6:34 pm 
Не в сети
МОДЕРАТОР

Зарегистрирован: Вт дек 05, 2006 8:46 am
Сообщений: 6384
Благодарил (а): 20 раз.
Поблагодарили: 198 раз.
Пункты репутации: 48
Сборник кодов по ToolBar

Установить размер кнопок
Код:
1
2
SendMessage_(ToolBarID(1),#TB_SETBUTTONSIZE,0,64 | 32 << 16) 
SendMessage_(ToolBarID(1),#TB_AUTOSIZE,0,0)



Справка: в этом коде размеры устанавливаются в 4 параметре функции SendMessage_(). Ширина - число до знака "ИЛИ" ("|"), высота - после знака "ИЛИ" ("|") и перед <<

Изменить расположение тулбара в окне

Код:
1
2
SetWindowLongPtr_(ToolBarID(0),#GWL_STYLE,#WS_CHILD | #WS_VISIBLE | #CCS_NORESIZE | #CCS_NODIVIDER | #TBSTYLE_WRAPABLE) 
MoveWindow_(ToolBarID(0),50,50,400,45,1)


Координаты - X,Y,ширина,высота. Последний параметр не изменяется.

Установить ширину указанной кнопки
Код:
1
2
3
4
5
6
binf.TBBUTTONINFO 
binf\cbSize         = SizeOf(TBBUTTONINFO)
binf\dwMask       = #TBIF_SIZE
binf\cx               = 200
binf\idCommand = 1
SendMessage_(ToolBarID(1), #TB_SETBUTTONINFO, 1, binf)


Третий параметр функции SendMessage_() - #ButtonID

Установить размер иконок (если есть с большим разрешением, стандартное - 16 на 16)
Код:
1
2
3
4
TBID = SendMessage_(ToolBarID(0),#TB_GETIMAGELIST,0,0) 
ImageList_SetIconSize_(TBID,32,32)
SendMessage_(ToolBarID(0),#TB_SETIMAGELIST,0,TBID)
SendMessage_(ToolBarID(0),#TB_AUTOSIZE,0,0)




Установить текст справа от иконок
Код:
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Procedure ToolBarText(hwnd,ButtonID,Text.s) 
   tbi.TBBUTTONINFO
   tbi\cbSize = SizeOf(TBBUTTONINFO)
   tbi\dwMask = #TBIF_TEXT | #TBIF_STYLE
   tbi\fsStyle = #BTNS_BUTTON | #BTNS_AUTOSIZE
   tbi\pszText = @Text
   SendMessage_(hwnd,#TB_SETBUTTONINFO,ButtonID,tbi)
EndProcedure
 
If OpenWindow(0,0,0,500,250,"Window",#PB_Window_SystemMenu|#PB_Window_ScreenCentered)
  If CreateToolBar(0,WindowID(0))
    SetWindowLongPtr_(ToolBarID(0), #GWL_STYLE, GetWindowLongPtr_(ToolBarID(0), #GWL_STYLE) | #TBSTYLE_LIST)
    ToolBarStandardButton(0,#PB_ToolBarIcon_New)
    ToolBarStandardButton(1,#PB_ToolBarIcon_Open)
    ToolBarStandardButton(2,#PB_ToolBarIcon_Save)
   
    ToolBarText(ToolBarID(0),0,"New")
    ToolBarText(ToolBarID(0),1,"Open")
    ToolBarText(ToolBarID(0),2,"Save")
  EndIf
 
Repeat : Until WaitWindowEvent() = #PB_Event_CloseWindow
EndIf




Установить текст под иконками

Код:
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
EnableExplicit 
 
Define EventID
 
Procedure.l SetToolbarItemText(Toolbar.l, TolbarItem.l, Text.s)
  Protected i.l, hdc.l, hToolbar.l, ButtonInfo.TBBUTTONINFO, Size.SIZE , hFont.l, hFontOld.l
  Static *FakeButtonStrings
  If *FakeButtonStrings = #Null
    *FakeButtonStrings = AllocateMemory(256) ; should be enough [127 icons]
    If *FakeButtonStrings
      For i = 0 To 254 Step 2
        PokeB(*FakeButtonStrings + i, 32)
      Next
    EndIf
  EndIf
  hToolbar = ToolBarID(Toolbar)
  If hToolbar
    ButtonInfo\cbSize = SizeOf(TBBUTTONINFO)
    ButtonInfo\dwMask = #TBIF_TEXT | #TBIF_COMMAND |#TBIF_SIZE
    ButtonInfo\pszText = @Text
    ButtonInfo\idCommand = TolbarItem
    hdc = GetDC_(hToolbar)
    If hdc
      hFont = SendMessage_(hToolbar, #WM_GETFONT, 0, 0)
      hFontOld = SelectObject_(hdc, hFont)
      GetTextExtentPoint32_(hdc, Text, Len(Text), @Size)
      ButtonInfo\cx = Size\cx + 10
      SelectObject_(hdc, hFontOld)
      ReleaseDC_(hToolbar, hdc)
    EndIf
    If *FakeButtonStrings
      SendMessage_(hToolbar, #TB_ADDSTRING, 0, *FakeButtonStrings)
    EndIf
    SendMessage_(hToolbar, #TB_SETBUTTONINFO, TolbarItem, @ButtonInfo)
    SendMessage_(hToolbar, #TB_AUTOSIZE, 0, 0)
  EndIf
EndProcedure
 
If OpenWindow(0,0,0,500,400,"Window",#PB_Window_SystemMenu|#PB_Window_ScreenCentered)
  If CreateToolBar(1,WindowID(0))
    ToolBarStandardButton(0, #PB_ToolBarIcon_New)
    ToolBarStandardButton(1, #PB_ToolBarIcon_Open)
    ToolBarStandardButton(2, #PB_ToolBarIcon_Save)
   
    SetToolbarItemText(1, 0, "t1hk")
    SetToolbarItemText(1, 1, "t2hjkhk")
    SetToolbarItemText(1, 2, "thjkhk3")
   
  EndIf
 
  Repeat
    EventID=WaitWindowEvent()
    If EventID = #PB_Event_CloseWindow
      End
    EndIf
  ForEver
EndIf




Установить отступ тулбара от левого края окна

SendMessage_(ToolBarID(0),#TB_SETINDENT,50,0)


Тулбар внизу окна

Код:
1
SetWindowLongPtr_(ToolBarID(0),#GWL_STYLE,#WS_CHILD|#WS_VISIBLE)




Спрятать тулбар

Код:
1
ShowWindow_(ToolBarID(0),#SW_HIDE)




Показать тулбар

Код:
1
ShowWindow_(ToolBarID(0),#SW_SHOW)




Вертикальный тулбар (помещаем в ContainerGadget)

Код:
1
2
3
4
5
6
7
8
9
10
11
12
13
If OpenWindow(0,0,0,500,250,"Window",#PB_Window_SystemMenu|#PB_Window_ScreenCentered) 
  ContainerGadget(1,0, 0,20,200,#PB_Container_BorderLess)
 
  CreateToolBar(0,GadgetID(1))
  SetWindowLongPtr_(ToolBarID(0),#GWL_STYLE,GetWindowLongPtr_(ToolBarID(0),#GWL_STYLE)|#TBSTYLE_WRAPABLE)
  ToolBarStandardButton(1, #PB_ToolBarIcon_New)
  ToolBarStandardButton(2, #PB_ToolBarIcon_Open)
  ToolBarStandardButton(3, #PB_ToolBarIcon_Save)
  ToolBarStandardButton(4, #PB_ToolBarIcon_Print)
  ToolBarStandardButton(5, #PB_ToolBarIcon_Find)
 
Repeat : Until WaitWindowEvent() = #PB_Event_CloseWindow
EndIf



Любезно предоставлено Никитой Однороб

_________________
read-only


Вернуться наверх
 Профиль  
 
 Заголовок сообщения: MsgBox в заданном месте экрана
СообщениеДобавлено: Ср июн 05, 2013 5:50 am 
Не в сети
МОДЕРАТОР

Зарегистрирован: Вт дек 05, 2006 8:46 am
Сообщений: 6384
Благодарил (а): 20 раз.
Поблагодарили: 198 раз.
Пункты репутации: 48
MsgBox в заданном месте экрана

Код:
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
 
DisableASM
EnableExplicit
 
Structure MSGBOX
  m_Hook.i
  m_Left.i
  m_Top.i
EndStructure
 
Global msgbox.MSGBOX
 
#SWVB_DEFAULT   = $FFFFFFFF
 
 
 
Procedure.i MsgBoxHook(nCode.i, wParam.i, lParam.i)
;
  Protected x.l
  Protected y.l
  Protected nSize.i
  Protected tmpHook.i
  Protected sBuffer.s
  Protected Height.i
  Protected Width.i
  Protected fHeight.i
  Protected fWidth.i
  Protected wndRect.rect
 
  tmpHook = CallNextHookEx_(msgbox\m_Hook, nCode, wParam, lParam)
  If nCode = #HCBT_ACTIVATE
    sBuffer = Space(32)
    nSize   = GetClassName_(wParam, sBuffer, 32)
    If Left(sBuffer, nSize) <> "#32770"
      ProcedureReturn #False
    EndIf
    GetWindowRect_(wParam, wndRect)
    Height  = (wndRect\bottom - wndRect\top) / 2
    Width   = (wndRect\right - wndRect\left) / 2
    GetWindowRect_(GetParent_(wParam), wndRect)
    fHeight = wndRect\top + (wndRect\bottom - wndRect\top)  / 2
    fWidth  = wndRect\left + (wndRect\right - wndRect\left) / 2
    If msgbox\m_Left = #SWVB_DEFAULT
        x = fWidth - width
    Else
        x = msgbox\m_Left
    EndIf
    If msgbox\m_Top = #SWVB_DEFAULT
        y = fHeight - height
    Else
        y = msgbox\m_Top
    EndIf
    SetWindowPos_(wParam, #HWND_TOP, x, y, 0, 0, #SWP_NOSIZE + #SWP_NOZORDER + #SWP_NOACTIVATE)
    UnhookWindowsHookEx_(msgbox\m_Hook)
    ProcedureReturn tmpHook
  EndIf
 
EndProcedure
 
Procedure.i MessageResquestBOX(spromp.s, button.l, stitle.s, left.l, top.l)
;
  Protected hInst.i
  Protected thread.i
  Protected hInstance.i
  Protected wndRect.rect
 
  hInstance = GetModuleHandle_(0)
  thread    = GetCurrentThreadId_()
  With msgbox
    \m_Hook = SetWindowsHookEx_(#WH_CBT, @MsgBoxHook(), hInst, thread)
    \m_Left = left
    \m_Top  = top
  EndWith
  ProcedureReturn MessageRequester(stitle, spromp, button)
 
EndProcedure
 
 
Debug MessageResquestBOX("Вам понравилось это сообщение?", #PB_MessageRequester_YesNoCancel, "Ваша программа", 100, 100)
 
End


_________________
read-only


Вернуться наверх
 Профиль  
 
 Заголовок сообщения: ProgressBar
СообщениеДобавлено: Чт авг 22, 2013 6:01 am 
Не в сети
МОДЕРАТОР

Зарегистрирован: Вт дек 05, 2006 8:46 am
Сообщений: 6384
Благодарил (а): 20 раз.
Поблагодарили: 198 раз.
Пункты репутации: 48
1. Увеличить значение на определённый шаг:
Код:
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
 
Procedure ProgressBarStep(Gadget, StepValue)
  SendMessage_(GadgetID(Gadget), #PBM_SETSTEP, StepValue, 0)
  SendMessage_(GadgetID(Gadget), #PBM_STEPIT, 0, 0)
EndProcedure
 
If OpenWindow(0, 0, 0, 500, 400, "Window", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
  ProgressBarGadget(1, 10, 10, 200, 20, 0, 100, 0)
  ButtonGadget(2, 220, 10, 100, 20, "Schritt weiter", 0)
 
  Repeat
    EventID = WaitWindowEvent()
    If EventID = #PB_Event_Gadget
      Select EventGadget()
        Case 2
          ProgressBarStep(1, 20) ;Увеличиваем значение на 20
      EndSelect
    EndIf
    If EventID = #PB_Event_CloseWindow
      End
    EndIf
  ForEver
EndIf
 



2. Установить цвет ProgressBar (обычный, ошибка или пауза)
Код:
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
 
#PBM_SETSTATE = $410
#PBST_NORMAL = $0001 ;Обычный, зелёный
#PBST_ERROR = $0002  ;Красый
#PBST_PAUSED = $0003 ;Жёлтый
If OpenWindow(0, 0, 0, 500, 400, "Window", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
  ProgressBarGadget(1, 10, 10, 200, 20, 0, 100, 0)
  SetGadgetState(1, 50)
 
  SendMessage_(GadgetID(1), #PBM_SETSTATE, #PBST_ERROR, 0)
 
  Repeat
    EventID = WaitWindowEvent()
    If EventID = #PB_Event_CloseWindow
      End
    EndIf
  ForEver
EndIf




3. Бегающее состояние
Код:
1
2
3
4
5
6
7
8
 
If OpenWindow(0,0,0,500,250,"Window",#PB_Window_SystemMenu|#PB_Window_ScreenCentered)
  ProgressBarGadget(1,10,10,480,20,0,100,8)
 
  SendMessage_(GadgetID(1),#WM_USER+10,1,50)
 
Repeat : Until WaitWindowEvent() = #PB_Event_CloseWindow
EndIf




4. Бегающее состояние в обратную сторону

Код:
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
If OpenWindow(0,0,0,500,400,"Window",#PB_Window_SystemMenu|#PB_Window_ScreenCentered)
  ProgressBarGadget(1,10,10,480,20,0,100,8)
 
  SendMessage_(GadgetID(1),#WM_USER+10,1,0)
 
  SetWindowLongPtr_(GadgetID(1), #GWL_EXSTYLE, GetWindowLongPtr_(GadgetID(1), #GWL_EXSTYLE) | #WS_EX_LAYOUTRTL)
 
  Repeat
    EventID=WaitWindowEvent()
    If EventID = #PB_Event_CloseWindow
      End
    EndIf
  ForEver
EndIf
 
 




Прислал Никита Однороб

_________________
read-only


Вернуться наверх
 Профиль  
 
 Заголовок сообщения: PanelGadget
СообщениеДобавлено: Пн окт 07, 2013 6:19 am 
Не в сети
МОДЕРАТОР

Зарегистрирован: Вт дек 05, 2006 8:46 am
Сообщений: 6384
Благодарил (а): 20 раз.
Поблагодарили: 198 раз.
Пункты репутации: 48
1. Вкладки - кнопки


Код:
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
  EnableExplicit
 
    Define EventID
 
    If OpenWindow(0, 0, 0, 500, 400, "Window", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
      If PanelGadget(1, 10, 10, WindowWidth(0)-20, WindowHeight(0)-20)
        AddGadgetItem(1, -1, "Item 1", 0, 0)
        ButtonGadget(2, 100, 100, 100, 20, "Button 1", 0)
        AddGadgetItem(1, -1, "Item 2", 0, 0)
        ButtonGadget(3, 100, 50, 100, 20, "Button 2", 0)
        AddGadgetItem(1, -1, "Item 3", 0, 0)
        ButtonGadget(4, 50, 100, 100, 20, "Button 3", 0)
       
        CloseGadgetList()
      EndIf
     
      SetWindowLongPtr_(GadgetID(1), #GWL_STYLE, GetWindowLongPtr_(GadgetID(1), #GWL_STYLE) | #TCS_BUTTONS)
     
      Repeat
        EventID = WaitWindowEvent()
        If EventID = #PB_Event_CloseWindow
          End
        EndIf
      ForEver
    EndIf





2. Вкладки - кнопки (плоские)


Код:
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
 EnableExplicit
 
    Define EventID
 
    #TCS_EX_FLATSEPARATORS = $1
 
    If OpenWindow(0, 0, 0, 500, 400, "Window", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
      If PanelGadget(1, 10, 10, WindowWidth(0)-20, WindowHeight(0)-20)
        AddGadgetItem(1, -1, "Item 1", 0, 0)
        ButtonGadget(2, 100, 100, 100, 20, "Button 1", 0)
        AddGadgetItem(1, -1, "Item 2", 0, 0)
        ButtonGadget(3, 100, 50, 100, 20, "Button 2", 0)
        AddGadgetItem(1, -1, "Item 3", 0, 0)
        ButtonGadget(4, 50, 100, 100, 20, "Button 3", 0)
       
        CloseGadgetList()
      EndIf
     
      SetWindowLongPtr_(GadgetID(1), #GWL_STYLE, GetWindowLongPtr_(GadgetID(1), #GWL_STYLE) | #TCS_BUTTONS | #TCS_FLATBUTTONS)
      SendMessage_(GadgetID(1), #TCM_SETEXTENDEDSTYLE, #Null, #TCS_EX_FLATSEPARATORS)
     
      Repeat
        EventID = WaitWindowEvent()
        If EventID = #PB_Event_CloseWindow
          End
        EndIf
      ForEver
    EndIf
 
 



3. Вкладки на правой стороне


Код:
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
 EnableExplicit
 
    Define EventID
 
    If OpenWindow(0,0,0,500,400,"Window",#PB_Window_SystemMenu|#PB_Window_ScreenCentered)
      PanelGadget(1,10,10,WindowWidth(0)-20,WindowHeight(0)-20)
      AddGadgetItem(1,0,"Item 1",0,0)
      AddGadgetItem(1,0,"Item 2",0,0)
      AddGadgetItem(1,0,"Item 3",0,0)
      AddGadgetItem(1,0,"Item 4",0,0)
      AddGadgetItem(1,0,"Item 5",0,0)
      CloseGadgetList()
     
      SetWindowLongPtr_(GadgetID(1), #GWL_EXSTYLE, GetWindowLongPtr_(GadgetID(1), #GWL_EXSTYLE) | #WS_EX_LAYOUTRTL)
     
      Repeat
        EventID=WaitWindowEvent()
        If EventID = #PB_Event_CloseWindow
          End
        EndIf
      ForEver
    EndIf
 




4. Вкладки в несколько строк (если не помещаются)


Код:
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
  EnableExplicit
 
    Define a
 
    If OpenWindow(0,0,0,500,250,"Window",#PB_Window_SystemMenu|#PB_Window_ScreenCentered)
      PanelGadget(1,10,10,480,230)
        For a=1 To 15
          AddGadgetItem(1,-1,"Paneltab "+Str(a),0,0)
        Next
      CloseGadgetList()
      SetWindowLongPtr_(GadgetID(1),#GWL_STYLE,GetWindowLongPtr_(GadgetID(1),#GWL_STYLE)|#TCS_MULTILINE)
      SetGadgetState(1,0)
     
    Repeat : Until WaitWindowEvent() = #PB_Event_CloseWindow
    EndIf
 
 



5. Получить номер вкладки под курсором (начинается с 0)


Код:
1
  SendMessage_(GadgetID(1),#TCM_GETCURSEL,0,0)





6. Фиксированная ширина вкладок

Код:
1
2
3
4
5
6
7
8
9
10
11
12
 
    If OpenWindow(0,0,0,500,250,"Window",#PB_Window_SystemMenu|#PB_Window_ScreenCentered)
      PanelGadget(1,10,10,480,230)
        For a=1 To 5
          AddGadgetItem(1,-1,"Paneltab "+Str(a),0,0)
        Next
      CloseGadgetList()
     
      SetWindowLongPtr_(GadgetID(1),#GWL_STYLE,GetWindowLongPtr_(GadgetID(1),#GWL_STYLE)|#TCS_FIXEDWIDTH)
      SendMessage_(GadgetID(1),#TCM_SETITEMSIZE,0,200)
    Repeat : Until WaitWindowEvent() = #PB_Event_CloseWindow
    EndIf





7. Получить текст всех вкладок


Код:
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
 EnableExplicit
 
    Define EventID
    Define String$=Space(255)
    Define TC_ITEM.TC_ITEM
    Define ItemTotal
    Define a
 
    If OpenWindow(0,0,0,500,400,"Window",#PB_Window_SystemMenu|#PB_Window_ScreenCentered)
      PanelGadget(1,0,0,500,400)
      AddGadgetItem(1,-1,"123 Test ABC",0,0)
      AddGadgetItem(1,-1,"ABC 123",0,0)
      AddGadgetItem(1,-1,"ABC Test 123",0,0)
      AddGadgetItem(1,-1,"Test",0,0)
     
      CloseGadgetList()
     
      ItemTotal = SendMessage_(GadgetID(1),#TCM_GETITEMCOUNT,0,0)
     
      TC_ITEM.TC_ITEM
      TC_ITEM\Mask=#TCIF_TEXT
      TC_ITEM\pszText=@String$
      TC_ITEM\cchTextMax=255
     
      For a=1 To ItemTotal
        SendMessage_(GadgetID(1),#TCM_GETITEM,a-1,@TC_ITEM)
        Debug String$
       
      Next
     
      Repeat
        EventID=WaitWindowEvent()
        If EventID = #PB_Event_CloseWindow
          End
        EndIf
      ForEver
    EndIf
 




8. Изменить высоту вкладок


Код:
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
 If OpenWindow(0,0,0,500,250,"Window",#PB_Window_SystemMenu|#PB_Window_ScreenCentered)
      PanelGadget(1,10,10,480,230)
        For a=1 To 5
          AddGadgetItem(1,-1,"Paneltab "+Str(a),0,0)
        Next
      CloseGadgetList()
     
      PokeW(@lparam+2,50)
      SendMessage_(GadgetID(1),#TCM_SETITEMSIZE,0,lparam)
      SetGadgetState(1,0)
    Repeat : Until WaitWindowEvent() = #PB_Event_CloseWindow
    EndIf
 
 
 


9. Отключить подсветку вкладки при наведении курсора


Код:
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
  EnableExplicit
 
    Define a
    Define EventID
 
    If OpenWindow(0, 0, 0, 500, 400, "Window", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
      If PanelGadget(1, 10, 10, WindowWidth(0)-20, WindowHeight(0)-20)
        For a=1 To 10
          AddGadgetItem(1, -1, "Item " + Str(a), 0, 0)
        Next
       
        CloseGadgetList()
      EndIf
     
      SetWindowLongPtr_(GadgetID(1), #GWL_STYLE, GetWindowLongPtr_(GadgetID(1), #GWL_STYLE) &~ #TCS_HOTTRACK)
      SetGadgetState(1, 0)
     
      Repeat
        EventID = WaitWindowEvent()
        If EventID = #PB_Event_CloseWindow
          End
        EndIf
      ForEver
    EndIf





10. Вкладки в несколько строк


Код:
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
 EnableExplicit
 
    Define EventID
    Define a
 
    If OpenWindow(0, 0, 0, 500, 400, "Window", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
      If PanelGadget(1, 10, 10, WindowWidth(0)-20, WindowHeight(0)-20)
        For a=1 To 10
          AddGadgetItem(1, -1, "Item " + Str(a), 0, 0)
        Next
       
        CloseGadgetList()
      EndIf
     
      SetWindowLongPtr_(GadgetID(1), #GWL_STYLE, GetWindowLongPtr_(GadgetID(1), #GWL_STYLE) | #TCS_MULTILINE)
      SendMessage_(GadgetID(1), #TCM_SETMINTABWIDTH, 0, 100)
      SetGadgetState(1, 0)
     
      Repeat
        EventID = WaitWindowEvent()
        If EventID = #PB_Event_CloseWindow
          End
        EndIf
      ForEver
    EndIf





11. Операции с вкладками


Код:
1
2
3
4
5
 SendMessage_(GadgetID(1),#TCM_SETCURSEL,1,0) ;Установить вкладку
    SendMessage_(GadgetID(1),#TCM_DELETEITEM,1,0) ;Удалить вкладку
    ;Номер вкладки - 3 параметр
 
 



12. Вкладки снизу


Код:
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
   EnableExplicit
 
    Define i
    Define pgStatic
 
    If OpenWindow(0,0,0,500,250,"Window",#PB_Window_SystemMenu|#PB_Window_ScreenCentered)
      PanelGadget(1,10,10,480,230)
     
      For i=1 To 5
        AddGadgetItem (1,-1,"Panel "+Str(i),0,0)
      Next
     
      SetWindowLongPtr_(GadgetID(1),#GWL_STYLE,GetWindowLongPtr_(GadgetID(1),#GWL_STYLE)|#TCS_BOTTOM)
     
      CloseGadgetList()
     
      Repeat
        For i = 1 To CountGadgetItems(1)
          pgStatic = FindWindowEx_(GadgetID(1),pgStatic,"Static", 0)
          MoveWindow_(pgStatic,0,0,260,180,1)
        Next i
      Until WaitWindowEvent() = #PB_Event_CloseWindow
    EndIf
 
 



13. Изменить цвет фона и текста вкладки


Код:
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
 ;Autor: Sparkie
 
    EnableExplicit
 
    Define EventID
    Global oldCallback
    Global greenBrush = CreateSolidBrush_(#Green)
    Global defaultBrush = CreateSolidBrush_(GetSysColor_(#COLOR_3DFACE))
 
    Procedure myPGcallback(hwnd, msg, wParam, lParam)
      Protected result
      Protected *PGdis.DRAWITEMSTRUCT
      Protected tabText$
     
      result = CallWindowProc_(oldCallback, hwnd, msg, wParam, lParam)
      Select msg
        Case #WM_DRAWITEM
          *PGdis.DRAWITEMSTRUCT = lParam
          If *PGdis\CtlType = #ODT_TAB
            Select *PGdis\itemID
              Case 0, 2
                tabText$ = GetGadgetItemText(1, *PGdis\itemID, 0)
                FillRect_(*PGdis\hdc, *PGdis\rcItem, greenBrush)
                SetTextColor_(*PGdis\hdc, #Red)
                SetBkMode_(*PGdis\hdc, #TRANSPARENT)
                DrawText_(*PGdis\hdc, tabText$, Len(tabText$), *PGdis\rcItem, #DT_CENTER | #DT_SINGLELINE | #DT_VCENTER | #DT_NOCLIP)
              Default
                tabText$ = GetGadgetItemText(1, *PGdis\itemID, 0)
                FillRect_(*PGdis\hdc, *PGdis\rcItem, defaultBrush)
                SetTextColor_(*PGdis\hdc, #Blue)
                SetBkMode_(*PGdis\hdc, #TRANSPARENT)
                DrawText_(*PGdis\hdc, tabText$, Len(tabText$), *PGdis\rcItem, #DT_CENTER | #DT_SINGLELINE | #DT_VCENTER | #DT_NOCLIP)
            EndSelect
          EndIf
      EndSelect
      ProcedureReturn result
    EndProcedure
 
    If OpenWindow(0, 0, 0, 500, 400, "Window", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
      If PanelGadget(1, 10, 10, WindowWidth(0)-20, WindowHeight(0)-20)
        AddGadgetItem(1, -1, "Tab 1", 0, 0)
        AddGadgetItem(1, -1, "Tab 2", 0, 0)
        AddGadgetItem(1, -1, "Tab 3", 0, 0)
       
        CloseGadgetList()
      EndIf
     
      SetWindowLongPtr_(GadgetID(1), #GWL_STYLE, GetWindowLongPtr_(GadgetID(1), #GWL_STYLE) | #TCS_OWNERDRAWFIXED)
      oldCallback = SetWindowLongPtr_(GetParent_(GadgetID(1)), #GWL_WNDPROC, @myPGcallback())
     
      Repeat
        EventID = WaitWindowEvent()
        If EventID = #PB_Event_CloseWindow
          DeleteObject_(greenBrush)
          DeleteObject_(defaultBrush)
          End
        EndIf
      ForEver
    EndIf





14. Вкладки по ширине


Код:
1
2
3
4
5
6
7
8
9
10
11
 If OpenWindow(0,0,0,500,250,"Window",#PB_Window_SystemMenu|#PB_Window_ScreenCentered)
      PanelGadget(1,10,10,480,230)
        For a=1 To 3
          AddGadgetItem(1,-1,"Panel "+Str(a))
        Next
      CloseGadgetList()
     
      SetWindowLongPtr_(GadgetID(1),#GWL_STYLE,GetWindowLongPtr_(GadgetID(1),#GWL_STYLE)|#TCS_FIXEDWIDTH)
      SendMessage_(GadgetID(1),#TCM_SETITEMSIZE,0,(GadgetWidth(1)/CountGadgetItems(1))-2)
    Repeat : Until WaitWindowEvent() = #PB_Event_CloseWindow
    EndIf



Прислал Никита Однороб

_________________
read-only


Вернуться наверх
 Профиль  
 
Показать сообщения за:  Сортировать по:  
Начать новую тему Ответить на тему  [ Сообщений: 23 ]  На страницу Пред.  1, 2

Часовой пояс: UTC + 3 часа


Кто сейчас на форуме

Сейчас этот форум просматривают: нет зарегистрированных пользователей и гости: 1


Вы не можете начинать темы
Вы не можете отвечать на сообщения
Вы не можете редактировать свои сообщения
Вы не можете удалять свои сообщения
Вы не можете добавлять вложения

Найти:
Перейти:  
Создано на основе phpBB® Forum Software © phpBB Group (блог о phpBB)
Сборка создана CMSart Studio
Русская поддержка phpBB