purebasic.info

PureBasic forum
Текущее время: Пн дек 10, 2018 2:07 pm

Часовой пояс: UTC + 3 часа




Начать новую тему Ответить на тему  [ Сообщений: 3 ] 
Автор Сообщение
 Заголовок сообщения: Загрузка процессора
СообщениеДобавлено: Пн дек 02, 2013 9:51 am 
Не в сети
доцент

Зарегистрирован: Сб июл 13, 2013 3:39 pm
Сообщений: 46
Благодарил (а): 10 раз.
Поблагодарили: 3 раз.
Пункты репутации: 0
Получаем загрузку процессора, не зависимо от архитектуры процессора и разрядности системы
Пример с прогресс баром

Код:
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
 
; ------------------------------------------------------------
;                           Cpu test
;
;     Author:  (c)15:42 26-11-13 Walt ( PB 5.11 )
;     OS: Windows
;     Cpu test
;    
; ------------------------------------------------------------
 
Enumeration
  #Window_0
  #Text
  #Font
  #Progress
  #Progress_2
  #kernelLib
  #Gradier
  #NumGrad
EndEnumeration
 
OpenLibrary(#kernelLib,"kernel32.dll")
Prototype GetSystemTimes(*lpIdleTime, *lpKernelTime, *lpUserTime )
Global GetSystemTimes.GetSystemTimes = GetFunction(#kernelLib,"GetSystemTimes")
 
 
Procedure main()
  Static FirstRun = #True
  Static Dim StartTimes(2), Dim EndTimes(2)
  Static CPU_Kernel.FILETIME, CPU_User.FILETIME, CPU_Idle.FILETIME
 
  GetSystemTimes(@CPU_Idle, @CPU_Kernel, @CPU_User)
  EndTimes(0) = (CPU_Kernel\dwLowDateTime + CPU_User\dwLowDateTime)
  EndTimes(1) = CPU_Idle\dwLowDateTime
 
  If FirstRun
    StartTimes(1) = EndTimes(1)
    StartTimes(0) = EndTimes(0)
    FirstRun = #False
    ProcedureReturn
  EndIf
 
  Idle_Time = EndTimes(1) - StartTimes(1)
 
  If Idle_Time > 0  
    Total_Time = EndTimes(0) - StartTimes(0)
    CPU_Percent.f = ((Total_Time - Idle_Time) / Total_Time) * 100
    SetGadgetState(#Progress_2, CPU_Percent) : SetGadgetState(#Progress, CPU_Percent)
   
    Text.s=Left(StrF(CPU_Percent), FindString(StrF(CPU_Percent), ".", 1)+1) +" %"
    SetGadgetText(#Text, Text)
   
    hDC = GetDC_(GadgetID(#Progress_2))
    If hDC
      SetBkMode_(hDC, #TRANSPARENT)
      SetTextColor_(hDC,RGB(158, 0, 158))
      TextOut_(hDC, 110, 8, @Text, Len(Text))
      ReleaseDC_(hwnd, hDC)
    EndIf
  EndIf
  ;StartTimes = EndTimes
  StartTimes(1) = EndTimes(1)
  StartTimes(0) = EndTimes(0)
 
EndProcedure
 
 
;{------------------------------------------------------
OpenWindow (#Window_0,  0,  0,  270,  220,  "Cpu test",  #PB_Window_ScreenCentered | #PB_Window_Tool | #PB_Window_MaximizeGadget)
SetWindowColor(#Window_0,RGB(58, 58, 58))
TextGadget(#NumGrad, 5, 10, 265, 15, "1.%"+Space(34)+"50.%"+Space(32)+"99.%")
SetGadgetColor(#NumGrad,#PB_Gadget_BackColor,RGB(58, 58, 58))
SetGadgetColor(#NumGrad,#PB_Gadget_FrontColor,RGB(255, 255, 255))
TextGadget(#Gradier, 5, 25, 260, 15, Chr($25bc)+Space(37)+Chr($25bc)+Space(37)+Chr($25bc))
SetGadgetColor(#Gradier,#PB_Gadget_BackColor,RGB(58, 58, 58))
SetGadgetColor(#Gradier,#PB_Gadget_FrontColor,RGB(205, 205, 205))
TextGadget(#Text, 5, 75, 260, 55, "0 %", #PB_Text_Center)
SetGadgetFont(#Text,LoadFont(#Font, "Comic Sans MS", 34, #PB_Font_Bold | #PB_Font_HighQuality))
SetGadgetColor(#Text,#PB_Gadget_BackColor,RGB(58, 58, 58))
SetGadgetColor(#Text,#PB_Gadget_FrontColor,RGB(184, 0, 0))
ProgressBarGadget(#Progress,  10, 40, 250,  30, 0, 100)
SetWindowTheme_(GadgetID(#Progress),"0","0") ; Отключает тему для элемента
SendMessage_(GadgetID(#Progress), $0410, 2,0)
ProgressBarGadget(#Progress_2,  10, 150, 250,  30, 0, 100)
SendMessage_(GadgetID(#Progress_2), $0410, 2,0)
SetTimer_(WindowID(#Window_0), 1,600, @main())
;}------------------------------------------------------
Repeat : Until WaitWindowEvent() = #PB_Event_CloseWindow
KillTimer_(WindowID(#Window_0),1)
CloseLibrary(#kernelLib)



Более красивый пример с GDI+ :wink:

Код:
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
 
; ------------------------------------------------------------
;                           Cpu test
;
;     Author:  (c)15:42 26-11-13 Walt ( PB 5.11 )
;     OS: Windows
;     Cpu test
;    
; ------------------------------------------------------------
Enumeration
  #Window_0
  #GDIPlus
  #kernelLib
EndEnumeration
 
;=============================================
;{ Structure
Structure GDIPSTARTUPINPUT
  Version.l
  *Callback
  NoThread.b
  NoCodecs.b
EndStructure
 
Structure PointF
  x.f
  y.f
EndStructure
 
Structure ULONG_PTR
  Data.l
EndStructure
 
Structure RECT_F
  X.f
  Y.f
  Width.f
  Height.f
EndStructure
 
Structure POINT_F
  X.f
  Y.f
EndStructure
;}
 
Global hBrush, hBrush2, hBrush3, hGraphics, hFontFamily, hFont, LineBrush, hBackbufferBmp, hBackbufferGra
Global Text_pos.RECT_F
 
;{ Prototype
;============================================= kernel32
OpenLibrary(#kernelLib,"kernel32.dll")
Prototype GetSystemTimes(*lpIdleTime, *lpKernelTime, *lpUserTime )
Global GetSystemTimes.GetSystemTimes = GetFunction(#kernelLib,"GetSystemTimes")
;============================================= GDIPlus
OpenLibrary(#GDIPlus,"GDIPlus.dll")
Prototype GdiplusStartup(*struct, *ulongptr,*ptr)
Global GdiplusStartup.GdiplusStartup = GetFunction(#GDIPlus,"GdiplusStartup")
;~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
Prototype GdipCreateFromHWND(hwnd.l, *ptr)
Global GdipCreateFromHWND.GdipCreateFromHWND = GetFunction(#GDIPlus,"GdipCreateFromHWND")
;~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
Prototype GdipSetLineLinearBlend(hLineGradientBrush, nFocus.f, nScale.f=1)
Global GdipSetLineLinearBlend.GdipSetLineLinearBlend = GetFunction(#GDIPlus,"GdipSetLineLinearBlend")
;~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
Prototype GdipFillRectangleI(hGraphics, hBrush , iX, iY, iWidth, iHeight)
Global GdipFillRectangleI.GdipFillRectangleI = GetFunction(#GDIPlus,"GdipFillRectangleI")
;~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
Prototype GdipCreateLineBrush(*pPointF1, *pPointF2, iARGBClr1, iARGBClr2, iWrapMode, *ptr=0)
Global GdipCreateLineBrush.GdipCreateLineBrush = GetFunction(#GDIPlus,"GdipCreateLineBrush")
;~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
Prototype GdipDeleteBrush(hBrush)
Global GdipDeleteBrush.GdipDeleteBrush = GetFunction(#GDIPlus,"GdipDeleteBrush")
;~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
Prototype GdipDeleteGraphics(hBrush)
Global GdipDeleteGraphics.GdipDeleteGraphics = GetFunction(#GDIPlus,"GdipDeleteGraphics")
;~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
Prototype GdiplusShutdown(*giGDIPToken)
Global GdiplusShutdown.GdiplusShutdown = GetFunction(#GDIPlus,"GdiplusShutdown")
;~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
Prototype GdipFillPieI(handleGraphics, handleBrush, intX, intY, intW, intH, FloatStartAngle.f, FSweepAngle.f)
Global GdipFillPieI.GdipFillPieI = GetFunction(#GDIPlus,"GdipFillPieI")
;~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
Prototype GdipCreateSolidFill(iARGB.l = $FF000000, *ptr=0)
GdipCreateSolidFill.GdipCreateSolidFill = GetFunction(#GDIPlus,"GdipCreateSolidFill")
;~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
Prototype GdipGraphicsClear(hGraphics, iARGB = $FF000000)
Global GdipGraphicsClear.GdipGraphicsClear = GetFunction(#GDIPlus,"GdipGraphicsClear")
;~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
Prototype GdipCreateFontFamilyFromName(sFamily.p-unicode , ptr=0, *handle=0)
Global GdipCreateFontFamilyFromName.GdipCreateFontFamilyFromName = GetFunction(#GDIPlus,"GdipCreateFontFamilyFromName")
;~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
Prototype GdipCreateFont(hFamily, fSize.f, iStyle=0, iUnit=3, *ptr=0)
Global GdipCreateFont.GdipCreateFont = GetFunction(#GDIPlus,"GdipCreateFont")
;~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
Prototype GdipDrawString(hGraphics, sString.p-unicode, minusone, hFont, *tLayout, hFormat, hBrush)
Global GdipDrawString.GdipDrawString = GetFunction(#GDIPlus,"GdipDrawString")
;~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
Prototype GdipDeleteFontFamily(hFamily)
Global GdipDeleteFontFamily.GdipDeleteFontFamily = GetFunction(#GDIPlus,"GdipDeleteFontFamily")
;~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
Prototype GdipDeleteFont(hFont)
Global GdipDeleteFont.GdipDeleteFont = GetFunction(#GDIPlus,"GdipDeleteFont")
;~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
Prototype GdipSetSmoothingMode(hGraphics, iSmooth)
Global GdipSetSmoothingMode.GdipSetSmoothingMode = GetFunction(#GDIPlus,"GdipSetSmoothingMode")
;~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
Prototype GdipCreateTexture(*hImage, iWrapMode, *ptr=0)
Global GdipCreateTexture.GdipCreateTexture = GetFunction(#GDIPlus,"GdipCreateTexture")
;~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
; Prototype GdipLoadImageFromFileICM(sFileName.p-unicode, *ptr=0)
; Global GdipLoadImageFromFileICM.GdipLoadImageFromFileICM = GetFunction(#GDIPlus,"GdipLoadImageFromFileICM")
;~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
Prototype GdipCreateBitmapFromHBITMAP(hBmp, hPal=0, *ptr=0)
Global GdipCreateBitmapFromHBITMAP.GdipCreateBitmapFromHBITMAP = GetFunction(#GDIPlus,"GdipCreateBitmapFromHBITMAP")
 
Prototype GdipCreateBitmapFromGraphics(int, int2, handle, *ptr)
Global GdipCreateBitmapFromGraphics.GdipCreateBitmapFromGraphics = GetFunction(#GDIPlus,"GdipCreateBitmapFromGraphics")
 
Prototype GdipGetImageGraphicsContext(handle, *ptr)
Global GdipGetImageGraphicsContext.GdipGetImageGraphicsContext = GetFunction(#GDIPlus,"GdipGetImageGraphicsContext")
 
Prototype GdipDrawImageI(handleGraphics, hImage, intX, intY)
Global GdipDrawImageI.GdipDrawImageI = GetFunction(#GDIPlus,"GdipDrawImageI")
 
;}=============================================
 
Procedure main(hwnd, msg, wParam, lParam)
  Static FirstRun = #True
  Static Dim StartTimes(2), Dim EndTimes(2)
  Static CPU_Kernel.FILETIME, CPU_User.FILETIME, CPU_Idle.FILETIME, RECT_L.RECT
  GetSystemTimes(@CPU_Idle, @CPU_Kernel, @CPU_User)
  EndTimes(0) = (CPU_Kernel\dwLowDateTime + CPU_User\dwLowDateTime)
  EndTimes(1) = CPU_Idle\dwLowDateTime
 
  If FirstRun
    StartTimes(1) = EndTimes(1)
    StartTimes(0) = EndTimes(0)
    FirstRun = #False
    ProcedureReturn
  EndIf
 
  Idle_Time = EndTimes(1) - StartTimes(1)
 
  If Idle_Time > 0  
    Total_Time = EndTimes(0) - StartTimes(0)
    CPU_Percent.f = ((Total_Time - Idle_Time) / Total_Time) * 100
;     Text.s=Left(StrF(CPU_Percent), FindString(StrF(CPU_Percent), ".", 1)+1) +" %"
    Text.s=Str(Int(CPU_Percent)) +" %"
    GdipGraphicsClear(hBackbufferGra)
    GdipFillRectangleI(hBackbufferGra, LineBrush,0 ,0, 200, 200)
    GdipFillPieI(hBackbufferGra,hBrush3,20, 20, 150, 150, 0, 360)
    GdipFillPieI(hBackbufferGra,hBrush2,30, 30, 130, 130, -200, 220)
    GdipFillPieI(hBackbufferGra,hBrush,30, 30, 130, 130, -200, Int(CPU_Percent*2))
    GdipFillPieI(hBackbufferGra,hBrush3,80, 90, 30, 30, 0, 360)
    Text_pos\x=65-(Len(Text)*2)
     GdipFillRectangleI(hBackbufferGra, LineBrush,55 ,125, 80, 25)
     GdipDrawString(hBackbufferGra, Text, -1, hFont ,@Text_pos,0, hBrush)
     GdipDrawImageI(hGraphics, hBackbufferBmp, 0 , 0)
  EndIf
 
  StartTimes(1) = EndTimes(1)
  StartTimes(0) = EndTimes(0)
 
EndProcedure
 
Procedure CreateImage_bk()
 CreateImage(0, 3, 3, 24)
  StartDrawing(ImageOutput(0))
  Box(0, 0, 3, 3, 0)
  Plot(1,1, RGB(71, 71, 71))
  Plot( 1,2, RGB(71, 71, 71))
  Plot( 2,1, RGB(71, 71, 71))
  Plot( 0,0, RGB(71, 71, 71))
  Plot( 2,2, RGB(81, 81, 81))
 ; Plot( 0,2, RGB(81, 81, 81))
 ; Plot( 2,0, RGB(81, 81, 81))
  StopDrawing()
 ProcedureReturn ImageID(0)
EndProcedure
 
;{------------------------------------------------------
OpenWindow (#Window_0,  0,  0,  200,  200,  "Cpu test",  #PB_Window_ScreenCentered | #PB_Window_Tool | #PB_Window_MaximizeGadget)
GDIPSTARTUPINPUT.GDIPSTARTUPINPUT
ULONG_PTR.ULONG_PTR
GDIPSTARTUPINPUT\Version = 1
Text_pos\y = 120
pPoint1.POINT_F
pPoint2.POINT_F
pPoint2\Y=200
 
GdiplusStartup(@ULONG_PTR, @GDIPSTARTUPINPUT, 0)
GdipCreateFromHWND(WindowID(#Window_0),@hGraphics)
GdipCreateFontFamilyFromName("Times New Roman",0,@hFontFamily)
GdipCreateFont(hFontFamily,24 ,0 ,3, @hFont)
GdipCreateLineBrush(@pPoint1, @pPoint2, $FF3F3F3F, $FF101010,1, @LineBrush)
GdipSetLineLinearBlend(LineBrush, 0.0, 1)
GdipCreateSolidFill($FFFF4F2D,@hBrush) ; Red
;GdipCreateSolidFill($FF1E9024,@hBrush) ;Green
GdipCreateSolidFill($FFADADAD,@hBrush2)
GdipCreateBitmapFromHBITMAP(CreateImage_bk() , 0,  @img)
GdipCreateTexture(img, 0 ,@hBrush3)
GdipCreateBitmapFromGraphics(200, 200, hGraphics, @hBackbufferBmp)
GdipGetImageGraphicsContext(hBackbufferBmp, @hBackbufferGra)
GdipSetSmoothingMode(hBackbufferGra, 5)
SetTimer_(WindowID(#Window_0), 1,1000, @main())
;}------------------------------------------------------
Repeat : Until WaitWindowEvent() = #PB_Event_CloseWindow
KillTimer_(WindowID(#Window_0),1)
GdipDeleteBrush(hBrush)
GdipDeleteBrush(hBrush2)
GdipDeleteBrush(hBrush3)
GdipDeleteFontFamily(hFontFamily)
GdipDeleteFont(hFont)
GdipDeleteGraphics(hGraphics)
GdiplusShutdown(@ULONG_PTR)
CloseLibrary(#kernelLib) : CloseLibrary(#GDIPlus)
 



Вернуться наверх
 Профиль  
 
 Заголовок сообщения: Re: Загрузка процессора
СообщениеДобавлено: Пн дек 02, 2013 12:02 pm 
Не в сети
PureBasic Coder
Аватар пользователя

Зарегистрирован: Чт ноя 10, 2011 10:50 am
Сообщений: 4049
Откуда: Ростов-на-Дону
Благодарил (а): 70 раз.
Поблагодарили: 81 раз.
Пункты репутации: 24
Спасибо за код! Правда, немного показатели разнятся, я больше Диспетчеру верю :) Но это не очень часто бывает, в основном цифры одинаковые.
Изображение

_________________
Пурик - лучший язык программирования


Вернуться наверх
 Профиль  
 
 Заголовок сообщения: Re: Загрузка процессора
СообщениеДобавлено: Пн дек 02, 2013 12:29 pm 
Не в сети
доцент

Зарегистрирован: Сб июл 13, 2013 3:39 pm
Сообщений: 46
Благодарил (а): 10 раз.
Поблагодарили: 3 раз.
Пункты репутации: 0
Никита Однороб писал(а):
Спасибо за код! Правда, немного показатели разнятся, я больше Диспетчеру верю :) Но это не очень часто бывает, в основном цифры одинаковые.

Я вот думаю это из-за разности интервалов обновления, и мне кажется, диспетчер задач как-то округляет результаты измерения за некоторый промежуток времени
Изображение


Вернуться наверх
 Профиль  
 
Показать сообщения за:  Сортировать по:  
Начать новую тему Ответить на тему  [ Сообщений: 3 ] 

Часовой пояс: UTC + 3 часа


Кто сейчас на форуме

Сейчас этот форум просматривают: нет зарегистрированных пользователей и гости: 3


Вы не можете начинать темы
Вы не можете отвечать на сообщения
Вы не можете редактировать свои сообщения
Вы не можете удалять свои сообщения
Вы не можете добавлять вложения

Найти:
Перейти:  
Создано на основе phpBB® Forum Software © phpBB Group (блог о phpBB)
Сборка создана CMSart Studio
Русская поддержка phpBB