purebasic.info

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303

;*********************************
; Module:   PunyCode
; Author:   void
; Compiler: PB531
; Ver:      001
; PunyCode encode\decode
; Compyle options -> Unicode
;*********************************
DeclareModule PUNYCODE
  EnableExplicit
  
  ;**
  ;* Punycodes a unicode string.
  ;*
  ;* @param input Unicode string.
  ;* @return Punycoded string.
  ;**  
  Declare.s encode(input$)
  
  ;**
  ;* Decode a punycoded string.
  ;*
  ;* @param input Punycode string
  ;* @return Unicode string.
  ;**
  Declare.s decode(input$)
  
EndDeclareModule
Module PUNYCODE
  EnableExplicit
  
  ;{ Constants
  #TMIN         = 1
  #TMAX         = 26
  #BASE         = 36
  #INITIAL_N    = 128
  #INITIAL_BIAS = 72
  #DAMP         = 700
  #SKEW         = 38
  #DELIMITER$   = "-"
  #MAX_VALUE    = 2147483647
  ;}
  
  ;{ Tools
  
  Procedure.l adapt(delta.l, numpoints.l, first.l)
    If first
      delta / #DAMP
    Else
      delta / 2
    EndIf
    
    delta + (delta / numpoints)
    
    Protected k.l = 0
    While (delta > ((#BASE - #TMIN) * #TMAX) / 2)
      delta / (#BASE - #TMIN)
      k + #BASE
    Wend
    
    ProcedureReturn k + ((#BASE - #TMIN + 1) * delta) / (delta + #SKEW)
  EndProcedure
  
  Procedure.l isBasic(char$)
    ProcedureReturn Bool(Asc(char$) < $80)
  EndProcedure
  
  Procedure.s digit2codepoint(d.l)
    If (d < 26)
      ; 0..25 : &#39;a&#39;..&#39;z&#39;
      ProcedureReturn Chr(d + &#39;a&#39;)
    ElseIf (d < 36)
      ; 26..35 : &#39;0&#39;..&#39;9&#39;
      ProcedureReturn Chr(d - 26 + &#39;0&#39;)
    Else
      Debug"BAD_INPUT"
      CallDebugger
    EndIf
  EndProcedure
  
  Procedure.l codepoint2digit(c.l)
    If (c - &#39;0&#39; < 10)
      ; &#39;0&#39;..&#39;9&#39; : 26..35
      ProcedureReturn c - &#39;0&#39; + 26
    ElseIf (c - &#39;a&#39; < 26)
      ; &#39;a&#39;..&#39;z&#39; : 0..25
      ProcedureReturn c - &#39;a&#39;
    Else
      Debug"BAD_INPUT"
      CallDebugger
    EndIf
  EndProcedure
  
  ;}
  
  ;{ Main
  
  ;**
  ;* Punycodes a unicode string.
  ;*
  ;* @param input Unicode string.
  ;* @return Punycoded string.
  ;**
  Procedure.s encode(input$)
    
    Protected n.l       = #INITIAL_N
    Protected delta.l   = 0
    Protected bias.l    = #INITIAL_BIAS
    Protected output$   = ""
    
    ; Copy all basic code points To the output
    Protected b.l, i.l
    For i=1 To Len(input$)
      Protected char$ = Mid(input$, i, 1)
      If isBasic(char$)
        output$ + char$
        b + 1
      EndIf
    Next
    
    ; Append delimiter
    If b > 0
      output$ + #DELIMITER$
    EndIf
    
    Protected h.l = b
    While h < Len(input$)
      Protected m.l = #MAX_VALUE
      
      ; Find the minimum code point >= n
      For i=1 To Len(input$)
        Protected cmin.l = Asc(Mid(input$, i, 1))
        If (cmin >= n And cmin < m)
          m = cmin
        EndIf
      Next
      
      If (m - n > (#MAX_VALUE - delta) / (h + 1))
        Debug "OVERFLOW"
        CallDebugger
        ProcedureReturn ""
      EndIf
      delta + (m - n) * (h + 1)
      n = m
      Protected j.l
      For j=1 To Len(input$)
        Protected c.l = Asc(Mid(input$, j, 1))
        If (c < n)
          delta + 1
          If delta = 0
            Debug "OVERFLOW"
            CallDebugger
            ProcedureReturn ""
          EndIf
        EndIf
        If (c = n)
          Protected q.l, k.l
          q = delta
          For k = #BASE To #MAX_VALUE Step #BASE
            Protected t.l
            If (k <= bias)
              t = #TMIN
            ElseIf (k >= bias + #TMAX)
              t = #TMAX
            Else
              t = k - bias
            EndIf
            If (q < t)
              Break
            EndIf
            output$ + digit2codepoint(t + (q - t) % (#BASE - t))
            q = (q - t) / (#BASE - t)
          Next
          
          output$ + digit2codepoint(q)
          bias = adapt(delta, h + 1, Bool(h = b))
          delta = 0
          h + 1
        EndIf
      Next
      
      delta + 1
      n + 1
    Wend
    
    ProcedureReturn output$
  EndProcedure
  
  ;**
  ;* Decode a punycoded string.
  ;*
  ;* @param input Punycode string
  ;* @return Unicode string.
  ;**
  Procedure.s decode(input$)
    Protected n.l     = #INITIAL_N
    Protected i.l     = 0
    Protected bias.l  = #INITIAL_BIAS
    Protected output$ = ""
    Protected j.l, d.l, dc.l
    
    dc = CountString(input$,#DELIMITER$)
    For j = 1 To dc
      d = FindString(input$,#DELIMITER$,d+1,#PB_String_NoCase)
    Next
    d-1
    If d > 0
      For j = 1 To d
        Protected char$ = Mid(input$,j,1)
        If Not isBasic(char$)
          Debug "BAD_INPUT"
          CallDebugger
          ProcedureReturn ""
        EndIf
        output$ + char$
      Next
      d + 1
    Else
      d = 0
    EndIf
    
    While d < Len(input$)
      Protected oldi.l = i
      Protected w.l    = 1
      Protected k.l
      For k = #BASE To #MAX_VALUE Step #BASE
        If (d = Len(input$))
          Debug "BAD_INPUT"
          CallDebugger
          ProcedureReturn ""
        EndIf
        Protected c.l = Asc(Mid(input$,d+1,1))
        d + 1
        Protected digit.l = codepoint2digit(c)
        If (digit > (#MAX_VALUE - i) / w)
          Debug "OVERFLOW"
          CallDebugger
          ProcedureReturn ""
        EndIf
        
        i + digit * w
        
        Protected t.l
        If (k <= bias)
          t = #TMIN
        ElseIf (k >= bias + #TMAX)
          t = #TMAX
        Else
          t = k - bias;
        EndIf
        If (digit < t)
          Break;
        EndIf
        w * (#BASE - t);        
      Next
      
      bias = adapt(i-oldi, Len(output$)+1, Bool(oldi=0));
      
      If (i / (Len(output$) + 1) > #MAX_VALUE - n)
        Debug "OVERFLOW"
        CallDebugger
        ProcedureReturn ""
      EndIf
      
      n + i / (Len(output$) + 1)
      i % (Len(output$) + 1)
      output$ = InsertString(output$,Chr(n),i+1)
      i+1
    Wend
    
    ProcedureReturn output$
  EndProcedure
  
  ;}
  
EndModule
;Test Module
CompilerIf #PB_Compiler_IsMainFile
  CompilerIf Not #PB_Compiler_Unicode
    Debug "WARNING!!! Unicode options isn&#39;t set."
    End
  CompilerEndIf  
  
  ;{ Test
  Define a$, b$, c$
  a$="почемужеонинеговорятпорусски"
  b$=PUNYCODE::encode(a$)
  c$=PUNYCODE::decode(b$)
  Debug a$
  Debug b$
  Debug "b1abfaaepdrnnbgefbadotcwatmq2g4l"
  Debug c$
  
  a$="ttt-почемужеонинеговорятпорусски-www"
  b$=PUNYCODE::encode(a$)
  c$=PUNYCODE::decode(b$)
  Debug a$
  Debug b$
  Debug c$
  ;}
  
CompilerEndIf