purebasic.info

PureBasic forum
Текущее время: Пн сен 16, 2019 1:30 am

Часовой пояс: UTC + 3 часа




Начать новую тему Ответить на тему  [ 1 сообщение ] 
Автор Сообщение
 Заголовок сообщения: Логер (модуль)
СообщениеДобавлено: Чт сен 12, 2019 6:43 am 
Не в сети
профессор

Зарегистрирован: Чт сен 22, 2011 6:21 pm
Сообщений: 289
Благодарил (а): 41 раз.
Поблагодарили: 28 раз.
Пункты репутации: 0
Написано под впечатлением от Log4j
Основная задача - минимальная задержка основного потока при логировании.
Сообщения ставятся в очередь, и обрабатываются в отдельном потоке с приоритетом Idle.
Логирует в файл (всегда) и в консоль (опционально)
При каждом старте лог-файл пере создается, а старый пакуется в zip архив (с датой в названии)
При переходе через 00:00 лог-файл пере создается.
Старые архивы удаляются (количество оставшихся задается при инициализации "LogRotateN")
Пример использования и проверка быстродействия в конце модуля.
LogSystem.pbi:
Код:
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
;*********************************
; Module:   LogSystem
; Author:   void
; Compiler: PB546
; cashed login engine, for logs to console and file
; [x] - Thread Safe
;*********************************
CompilerIf Not #PB_Compiler_Thread
  CompilerError "ThreadSafe is reqired!!!"
CompilerEndIf
 
Enumeration LogLevels
  #INFO
  #WARN
  #ERRO
  #FATA
  #UNDEFINE
EndEnumeration
 
DeclareModule LogSystem
  EnableExplicit
  UseZipPacker()
 
  Structure LogList
    LogMessage$
    LogTime.i
    LogLevel.i
  EndStructure
 
  Structure LogVar
    LogLevel.i
    LogConsoleNum.i
    LogFileName$
    LogFileNum.i
    LogRotateN.i
    LogWorkerThr.i
    LogMutex.i
    LogSemaphore.i
    List LogList.LogList()
  EndStructure
 
  Enumeration LogLevels
    #INFO
    #WARN
    #ERRO
    #FATA
    #UNDEFINE
  EndEnumeration
 
  Declare Init(*LogVar.LogVar, LogFileName$, LogLevel = #INFO, LogConsoleNum = 0, LogRotateN = 5)
  Declare Write(*LogVar.LogVar, LogMessage$, LogLevel = #INFO)
  Declare Free(*LogVar.LogVar)
 
EndDeclareModule
;*********************************
Module LogSystem
 
  Procedure FatalError(ErrorMessage$)
    MessageRequester("FATAL ERROR", ErrorMessage$)
    End
  EndProcedure
 
  Procedure RotateOpenLog(*LogVar.LogVar)
    #TMPNAME$ = "tmp.zip"
    #ZIPMASK$ = "_????-??-??.zip"
    Protected PakName$, Pak, PackedFilename$, Dir, PakTmp, TmpFileName$, *Buf, Size, FileDate
    If *LogVar\LogFileNum ;если файл уже открыт - закрываем
      FlushFileBuffers(*LogVar\LogFileNum)
      CloseFile(*LogVar\LogFileNum)
    EndIf
    If FileSize(*LogVar\LogFileName$) > 0 ;файл уже существует - пакуем в архив
      FileDate = GetFileDate(*LogVar\LogFileName$, #PB_Date_Modified)
      PakName$ = GetFilePart(*LogVar\LogFileName$) + FormatDate("_%yyyy-%mm-%dd.zip", FileDate)
      PackedFilename$ = FormatDate("%hh.%ii.%ss_", FileDate) + GetFilePart(*LogVar\LogFileName$)
      If FileSize(PakName$) > 0
        RenameFile(PakName$, #TMPNAME$)
        PakTmp = OpenPack(#PB_Any, #TMPNAME$, #PB_PackerPlugin_Zip)
        Pak = CreatePack(#PB_Any, PakName$, #PB_PackerPlugin_Zip)
        ExaminePack(PakTmp)
        While NextPackEntry(PakTmp)
          If PackEntryType(PakTmp) = #PB_Packer_File
            TmpFileName$ = PackEntryName(PakTmp)
            Size = PackEntrySize(PakTmp)
            *Buf = AllocateMemory(Size)
            If UncompressPackMemory(PakTmp, *Buf, Size) > 0
              AddPackMemory(Pak, *Buf, Size, TmpFileName$)
            EndIf
            FreeMemory(*Buf)
          EndIf
        Wend
        ClosePack(PakTmp)
        DeleteFile(#TMPNAME$, #PB_FileSystem_Force)
      Else
        Pak = CreatePack(#PB_Any, PakName$, #PB_PackerPlugin_Zip)
      EndIf
      AddPackFile(Pak, *LogVar\LogFileName$, PackedFilename$)
      ClosePack(Pak)
      DeleteFile(*LogVar\LogFileName$, #PB_FileSystem_Force)
    EndIf
    If *LogVar\LogRotateN ;удаление старых архивов (ротация)
      Size = 0
      Dir = ExamineDirectory(#PB_Any, "", GetFilePart(*LogVar\LogFileName$) + #ZIPMASK$)
      If Dir
        While NextDirectoryEntry(Dir)
          Size + 1
        Wend
        FinishDirectory(Dir)
      EndIf
      Size - *LogVar\LogRotateN
      If Size > 0
        Dir = ExamineDirectory(#PB_Any, "", GetFilePart(*LogVar\LogFileName$) + #ZIPMASK$)
        If Dir
          While NextDirectoryEntry(Dir)
            DeleteFile(DirectoryEntryName(Dir), #PB_FileSystem_Force)
            Size - 1
            If Not Size
              Break
            EndIf
          Wend
          FinishDirectory(Dir)
        EndIf      
      EndIf
    EndIf
    ;создание нового файла лога
    *LogVar\LogFileNum = OpenFile(#PB_Any, *LogVar\LogFileName$, #PB_File_SharedRead | #PB_File_SharedWrite)
    If Not *LogVar\LogFileNum
      FatalError("LogSystem: don't create log file: " + *LogVar\LogFileName$)
    EndIf
  EndProcedure  
 
  Procedure LogWorkerThr(*LogVar.LogVar)
    Protected LogLevel, OldLogLevel = #UNDEFINE, LogLevel$, LogTime, LogTime$, OldLogTime, LogMessage$
    Protected LogDay = Day(Date())
    Repeat
      WaitSemaphore(*LogVar\LogSemaphore)
     
      If Not ListSize(*LogVar\LogList())
        Break
      EndIf
     
      LockMutex(*LogVar\LogMutex)
      FirstElement(*LogVar\LogList())
      LogMessage$ = *LogVar\LogList()\LogMessage$
      LogTime     = *LogVar\LogList()\LogTime
      LogLevel    = *LogVar\LogList()\LogLevel
      DeleteElement(*LogVar\LogList())
      UnlockMutex(*LogVar\LogMutex)
     
      If OldLogTime <> LogTime ;кэшируем пересоздание строки с датой/временем
        OldLogTime  = LogTime
        LogTime$    = FormatDate("%yyyy-%mm-%dd %hh:%ii:%ss ", LogTime)
        If LogDay <> Day(LogTime)
          LogDay = Day(LogTime)
          RotateOpenLog(*LogVar)
        EndIf  
      EndIf
     
      If OldLogLevel <> LogLevel ;кэшируем пересоздание строки с уровнем важности
        OldLogLevel = LogLevel
        Select LogLevel
          Case #INFO
            LogLevel$ = "[INFO] "
          Case #WARN
            LogLevel$ = "[WARN] "
          Case #ERRO
            LogLevel$ = "[ERRO] "
          Default
            LogLevel$ = "[FATA] "
        EndSelect
      EndIf
     
      If *LogVar\LogConsoleNum
        Print (LogTime$)
        Print (LogLevel$)
        PrintN(LogMessage$)
      EndIf
     
      WriteString (*LogVar\LogFileNum, LogTime$, #PB_UTF8)
      WriteString (*LogVar\LogFileNum, LogLevel$, #PB_UTF8)
      WriteStringN(*LogVar\LogFileNum, LogMessage$, #PB_UTF8)
     
    ForEver
  EndProcedure  
 
  Procedure Init(*LogVar.LogVar, LogFileName$, LogLevel = #INFO, LogConsoleNum = 0, LogRotateN = 5)
   
    If *LogVar\LogFileNum Or *LogVar\LogMutex Or *LogVar\LogSemaphore Or *LogVar\LogWorkerThr
      FatalError("LogSystem: already initialised")
    EndIf
   
    *LogVar\LogLevel      = LogLevel
    *LogVar\LogConsoleNum = LogConsoleNum
    *LogVar\LogFileName$  = LogFileName$
    *LogVar\LogRotateN    = LogRotateN
   
    RotateOpenLog(*LogVar)
   
    NewList *LogVar\LogList()
   
    *LogVar\LogMutex = CreateMutex()
    If *LogVar\LogMutex = 0
      FatalError("LogSystem: don't create mutex")
    EndIf
   
    *LogVar\LogSemaphore = CreateSemaphore()
    If *LogVar\LogSemaphore = 0
      FatalError("LogSystem: don't create semaphore")
    EndIf
   
    *LogVar\LogWorkerThr = CreateThread(@LogWorkerThr(), *LogVar)
    If *LogVar\LogWorkerThr = 0
      FatalError("LogSystem: don't create worker thread")
    EndIf
   
    ThreadPriority(*LogVar\LogWorkerThr, 1)
   
    Write(*LogVar, "LogSystem: Start.", #WARN)
  EndProcedure
 
  Procedure Write(*LogVar.LogVar, LogMessage$, LogLevel = #INFO)
    If LogLevel >= *LogVar\LogLevel
      LockMutex(*LogVar\LogMutex)
      LastElement(*LogVar\LogList())
      AddElement(*LogVar\LogList())
      *LogVar\LogList()\LogMessage$  = LogMessage$
      *LogVar\LogList()\LogTime      = Date()
      *LogVar\LogList()\LogLevel     = LogLevel
      UnlockMutex(*LogVar\LogMutex)
      SignalSemaphore(*LogVar\LogSemaphore)
      If LogLevel >= #FATA
        Free(*LogVar)
        FatalError(LogMessage$)
      EndIf
    EndIf  
  EndProcedure
 
  Procedure Free(*LogVar.LogVar)
    Write(*LogVar, "LogSystem: End.", #WARN)
    SignalSemaphore(*LogVar\LogSemaphore)
    WaitThread(*LogVar\LogWorkerThr)
    *LogVar\LogWorkerThr = 0
    FreeSemaphore(*LogVar\LogSemaphore)
    *LogVar\LogSemaphore = 0
    FreeMutex(*LogVar\LogMutex)
    *LogVar\LogMutex     = 0
    CloseFile(*LogVar\LogFileNum)
    *LogVar\LogFileNum   = 0
  EndProcedure
 
EndModule
 
;WARNING!!!
;для короткого написания, переменная параметров логера должна называться "LogVar"
;пример "Define LogVar.LogSystem::LogVar"
UndefineMacro Logs
Macro Logs(LogMessage, LogLevel=0, LogVar=LogVar)
  LogSystem::Write(LogVar, LogMessage, LogLevel)
EndMacro
;*********************************
 
;Test Module
CompilerIf #PB_Compiler_IsMainFile
 
  Console = OpenConsole("Test Logs")
  Define LogVar.LogSystem::LogVar
  LogSystem::Init(LogVar, "Test.log", 0, Console)
 
  ;{ C Использованием модуля
  DisableDebugger
  starttime = ElapsedMilliseconds()
  For i = 1 To 10000
    Logs("Test #INFO " + Str(i), #INFO)
    Logs("Test #WARN " + Str(i), #WARN)
    Logs("Test #ERRO " + Str(i), #ERRO)
  Next
  endtime = ElapsedMilliseconds()
  Logs("Time to 30000 loglines: " + Str(endtime - starttime) + "ms.", #WARN)
  EnableDebugger
  Debug "Time with module " + Str(endtime - starttime)
  LogSystem::Free(LogVar)
  ;}
 
  ;{ Без использования модуля
  DisableDebugger
  LogFile   = CreateFile(#PB_Any, "Test1.log", #PB_File_SharedRead)
  starttime = ElapsedMilliseconds()  
  For i = 1 To 10000
    ;Logs::Write("Test #INFO "+Str(i),Logs::#INFO)
    PrintN(FormatDate("%yyyy-%mm-%dd %hh:%ii:%ss ",Date()) + "[INFO] " + "Test #INFO " + Str(i))
    WriteStringN(LogFile, FormatDate("%yyyy-%mm-%dd %hh:%ii:%ss ",Date()) + "[INFO] " + "Test #INFO " + Str(i))
    ;Logs::Write("Test #WARNING "+Str(i),Logs::#WARNING)
    PrintN(FormatDate("%yyyy-%mm-%dd %hh:%ii:%ss ",Date()) + "[WARN] " + "Test #WARN " + Str(i))
    WriteStringN(LogFile, FormatDate("%yyyy-%mm-%dd %hh:%ii:%ss ",Date()) + "[WARN] " + "Test #WARN " + Str(i))  
    ;Logs::Write("Test #ERRORE "+Str(i),Logs::#ERRORE)
    PrintN(FormatDate("%yyyy-%mm-%dd %hh:%ii:%ss ",Date()) + "[ERRO] " + "Test #ERRO " + Str(i))
    WriteStringN(LogFile, FormatDate("%yyyy-%mm-%dd %hh:%ii:%ss ",Date()) + "[ERRO] " + "Test #ERRO " + Str(i))
  Next
  endtime = ElapsedMilliseconds()
  ;Logs::Write("Time 30000 loglines: "+Str(endtime-starttime)+"ms.",Logs::#ERRORE)
  PrintN(FormatDate("%yyyy-%mm-%dd %hh:%ii:%ss ",Date()) + "[WARN] " + "Time 300000 loglines: " + Str(endtime-starttime) + "ms.")
  WriteStringN(LogFile, FormatDate("%yyyy-%mm-%dd %hh:%ii:%ss ", Date()) + "[WARN] " + "Time to 300000 loglines: " + Str(endtime - starttime) + "ms.")
  CloseFile(LogFile)
  EnableDebugger
  Debug "Time without module " + Str(endtime - starttime)
  Delay(10000)
  ;}
 
CompilerEndIf
 


зы.количество и названия уровней логирования - настраиваем на свой вкус.
Критика и предложения - приветствуются.


Вернуться наверх
 Профиль  
 
Показать сообщения за:  Сортировать по:  
Начать новую тему Ответить на тему  [ 1 сообщение ] 

Часовой пояс: UTC + 3 часа


Кто сейчас на форуме

Сейчас этот форум просматривают: нет зарегистрированных пользователей и гости: 2


Вы не можете начинать темы
Вы не можете отвечать на сообщения
Вы не можете редактировать свои сообщения
Вы не можете удалять свои сообщения
Вы не можете добавлять вложения

Найти:
Перейти:  
cron
Создано на основе phpBB® Forum Software © phpBB Group (блог о phpBB)
Сборка создана CMSart Studio
Русская поддержка phpBB